How to get Repeatability, Reproducibility and Gauge R&R Variation values for each parameter in a table post Gauge R&R analysis via JSL?

[#1]

I am conducting Gauge R&R analysis for several (~100) measured parameters. My data table with parts, operatorID/Inspector and repeats has spec limits values saved into the measured parameters columns. 

Interactively doing the Gauge R&R analysis process as shown at time 1.38 mins as in this video is inefficient and incontinent when the parameters are ~100. 

https://community.jmp.com/t5/Statistical-Thinking-for/Conducting-a-Gauge-R-amp-R-Analysis/ta-p/27189... 

I would like to automate the process and get the the Repeatability, Reproducibility and Gauge R&R Variation values in a data table.

How to do this via JSL?

[#2]

There are quite a many ways of doing this, below is fairly simple example of one possible way

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

var = dt << Variability Chart(
	Y(:NPN1, :PNP1, PNP2),
	Model("Main Effect"),
	X(:SITE),
	Variability Analysis(:NPN1, "Gauge R&R Report"n(1)),
	Variability Analysis(:PNP1, "Gauge R&R Report"n(1))	
);

if you have one-sided specifications be sure to check that the variables before and after those work correctly. There was a bug at some JMP version which did use wrong limits if you had one-sided somewhere in between the execution and you relied on spec limits column property (this might be fixed in JMP17, not sure. I use different method nowadays).

[#3]

@jthi Thanks, I have both LSL and USL for each measured parameter.

What you have posted is, if I understand correctly, the initial analysis part.

I want to automate the next stage which is getting the Repeatability, Reproducibility and Gauge R&R Variation values (marked with red arrows) for each measured in a new data table. 

In the video I linked before, this is done post 1.38 mins into the video and is done manually.

How to automate this part via JSL?

[#4]

You right click on the Gauge R&R table and create a table from it by using Make Combined Data Table

From the resulting table's table script you can get an idea how to automate it (get a reference to table box and use Make Combined Data Table message)

Start automating with only few columns and when you get it working expand to more.

[#5]

@jthi Thanks. While I wait for understand how to automate this "OK" step for each measured parameter

If I try the following from above in my JM 16.2.0,

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

var = dt << Variability Chart(
	Y(:NPN1, :PNP1, PNP2),
	Model("Main Effect"),
	X(:SITE),
	Variability Analysis(:NPN1, "Gauge R&R Report"n(1)),
	Variability Analysis(:PNP1, "Gauge R&R Report"n(1))	
);
Wait (0);

rpt ["Variability Gauge", "Variability Gauge Analysis for PNP1", "Gauge R&R", Table Box[1]] <<Make Combined Data Table;
rpt << Close Window;

I get an error

Name Unresolved: rpt in access or evaluation of 'rpt' , rpt/*###*/

most likely as I haven't defined rpt. The following with script copied from JMP also throws an error 

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

platform = dt << Variability Chart(
	Y(:NPN1, :PNP1, PNP2),
	Model("Main Effect"),
	X(:SITE),
	Variability Analysis(:NPN1, "Gauge R&R Report"n(1)),
	Variability Analysis(:PNP1, "Gauge R&R Report"n(1))	
);
Wait (0);

//rpt ["Variability Gauge", "Variability Gauge Analysis for PNP1", "Gauge R&R", Table Box[1]] <<Make Combined Data Table;
//rpt << Close Window;

Report( platform[1] )[Outline Box( "Gauge R&R" )][Table Box( 1 )] <<
Make Combined Data Table;
Report( platform[1] ) << Close Window;

I need some help to proceed.

[#6]

I wouldn't worry about getting the table box if you cannot get gage results (worry about table box later). I don't remember anymore how I did gage scripting in earlier JMP versions (JMP14, 15 and 16), but most likely I did them one by one as it most likely faster if you are only interested in the results and not in the plots. This seemed to work in JMP16.2

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

var = dt << Variability Chart(
	Y(:NPN1, :PNP1),
	Model("Main Effect"),
	X(:SITE),
	Historical Sigma(0)
);
var << "Gauge R&R"n();

[#7]

@jthi Thanks. This script works in my JMP 16.2 and does not ask me to verify Gauge specifications. Looking at the script for "Make Combined Data Table" for :NPN1, while for I see

Names Default To Here( 1 );
platform = Data Table( "Semiconductor Capability" ) <<
Variability Chart(
	Y( :NPN1 ),
	X( :SITE ),
	Model( "Main Effect" ),
	Historical Sigma( 0 ),
	"Gauge R&R"n( 6, 27.48 ),
	"Gauge R&R Report"n( 1 )
);
Wait( 0 );
Report( platform[1] )[Outline Box( "Gauge R&R" )][Table Box( 1 )] <<
Make Combined Data Table;
Report( platform[1] ) << Close Window;

while for :PNP1, I see 

Names Default To Here( 1 );
platform = Data Table( "Semiconductor Capability" ) <<
Variability Chart(
	Y( :PNP1 ),
	X( :SITE ),
	Model( "Main Effect" ),
	Historical Sigma( 0 ),
	"Gauge R&R"n( 6, 265.26 ),
	"Gauge R&R Report"n( 1 )
);
Wait( 0 );
Report( platform[1] )[Outline Box( "Gauge R&R" )][Table Box( 1 )] <<
Make Combined Data Table;
Report( platform[1] ) << Close Window;

The question now is how to loop through all the parameters for which GR&R is run and concatenate the "Combined Data Table" generated for each parameter.

Clearly, the spec limits in this line 

"Gauge R&R"n( _LSL_, _USL_ )

need to come from the data table for each parameter.

I have never done this but I will try on my side, but some direction would be very useful.

[#8 · Accepted solution]

I'm not sure which scripts you are currently talking about. This should use spec limits from column properties (except for the possible bug I did mention earlier which might be present in JMP16)

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

var = dt << Variability Chart(
	Y(:NPN1, :PNP1),
	Model("Main Effect"),
	X(:SITE),
	Historical Sigma(0)
);
var << "Gauge R&R"n();

If(N Items(var) > 1,
	result_ref = Report(var[1])[OutlineBox("Gauge R&R")];
,
	result_ref = Report(var)[OutlineBox("Gauge R&R")];
);

dt_result = result_ref[TableBox(1)] << Make Combined Data Table;

show(Column(dt, "NPN1") << Get Property("Spec Limits"));
show(Column(dt, "PNP1") << Get Property("Spec Limits"));

[#9]

@jthi In this code, how to correctly loop through all the measured variables (~100) in my data table?

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

var = dt << Variability Chart(
	Y(:NPN1, :PNP1, PNP2),
	Model("Main Effect"),
	X(:SITE),
	Variability Analysis(:NPN1, "Gauge R&R Report"n(1)),
	Variability Analysis(:PNP1, "Gauge R&R Report"n(1))	
);

~ 

[#10]

Build list of columns of interest and then send Gauge R&R Report message

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

var = dt << Variability Chart(
	Y(:NPN1, :PNP1),
	Model("Main Effect"),
	X(:SITE)
);

var << "Gauge R&R Report"n(1);