JSL: Layout( ‘Arrange in Rows’) is lost during jounalizing by scripting

[#1]

Dear JMP Community,

I stumbled across the following issue while scripting (example attached):

• If I use the following script, “jrn1 << Journal;” results in the transfer to the journal, but without “Group Options( Layout( ‘Arrange in Rows’, N Across( 2 ) ) ),”.
• If I use the manual option (Edit >> Journal or Crtl + J), the two-column layout is retained.

Is there another “journal syntax” that retains the layout that I am not aware of or is this a bug?

Do I have another option than formatting the journal layout via “H List Box ()”?

Best,

Steffi

kin1 = current data table();

jrn1 = kin1 << Bivariate(
	Y( :response ),
	X( :time),
	Size(400, 325),
	Fit Each Value( {Line Color( {212, 73, 88} )} ),
	By( :ID ),
	Group Options( Layout( "Arrange in Rows", N Across( 2 ) ) ),
);
Current Report()[OutlineBox(1)] << setTitle("Kinetics"); //Adjust the header retroperspectively 
jrn1 << Journal;

jrn 

[#2 · Accepted solution]

jrn1 will contain multiple references of bivariate platform, you want to only use one of them (or rather even higher level). You can modify your script like this for example

Names Default To Here(1);

kin1 = Current Data Table();
jrn1 = kin1 << Bivariate(
	Y(:response),
	X(:time),
	Size(400, 325),
	Fit Each Value({Line Color({212, 73, 88})}),
	By(:ID),
	Group Options(Layout("Arrange in Rows", N Across(2))),

);
Current Report()[Outline Box(1)] << setTitle("Kinetics"); //Adjust the header retroperspectively 
(jrn1[1] << Top Parent)<< Journal;

[#3]

Save Journal overwrites graphs of Fit Group is similar post as this but If I remember correctly there is one even better method BUT it is extremely difficult to find or remember... if I manage to find it, I will edit this response.

Edit: Finally managed to find it. It is extremely difficult (in my opinion) to find but here it is: use Return Group(1) on Group Options (I have added this to my personal tips&tricks file so hopefully I will find it easier next time someone has similar problem)

Names Default To Here(1);

kin1 = Current Data Table();
jrn1 = kin1 << Bivariate(
	Y(:response),
	X(:time),
	Size(400, 325),
	Fit Each Value({Line Color({212, 73, 88})}),
	By(:ID),
	Group Options(Layout("Arrange in Rows", N Across(2)), Return Group(1)),

);
Current Report()[Outline Box(1)] << setTitle("Kinetics"); //Adjust the header retroperspectively 
jrn1 << Journal;

Names Default To Here(1);
Open Help(
	"Scripting Index",
	Search(
		Term("Group Options"),
		Match(
				{"Contains Terms",
				"Match All Terms",
				"Ignore Case"}
		)
	),
	IndexContext(
		Category("All Categories"),
		Object("Search results"),
		Method("Group Options")
	)
);