Aligning graphs from graph builder horizontally in journal - JMP17

[#1]

Hi I am looking to have graphs from graph builder side by side in a journal. Currently graphs are vertically arranged in journal.

Below is my script:

new = new window("final", << journal,
	vb = V List Box(

        ob = Outline Box( "OWL vs KESTREL_RX_SENSITIVITY",
        	outline box(" QFN BAND 0")
        );
         
	)
);


dt1_band0 = open("C:\Users\NXF90574\Documents\NXP\VIshal\OWL_Kestrel_dvt2\DATA\DATA UPDATE\Subset of Subset of Subset of Owl_Kestrel_Dvt2_Test_names_TTT_NTV_band0.jmp");
dt1_band0_table = open("C:\Users\NXF90574\Documents\NXP\VIshal\OWL_Kestrel_dvt2\DATA\DATA UPDATE\band0_wfm.jmp");


for (
i = 1, i<=Nrows(dt1_band0_table), i++ ,

dt1_band0 << Select where(contains( :wfmFile , dt1_band0_table:wfmFile[i]) );
dt1_subset = dt1_band0 << subset (Output table("Owl_Kestrel_band0_subset.jmp"), Selected Rows( 1 ), selected columns( 0 ));


dt1_subset_graph = dt1_subset<< Graph Builder(
	Size( 1115, 553 ),
	Variables(
		X( :rxChnl ),
		Y( :Sens_2 ),
		Group X( :VDD1 ),
		Group Y( :Temp ),
		Overlay( :Silicon )
	),
	Elements( Line( X, Y, Legend( 12 ) ) ),
	SendToReport(
		Dispatch( {}, "rxChnl", ScaleBox, {Label Row( Show Major Grid( 1 ) )} ),
		Dispatch(
			{},
			"Sens_2",
			ScaleBox,
			{Format( "Best", 12 ),
			Inc( 1 ), Minor Ticks( 0 ), Label Row(
				{Show Major Grid( 1 ), Show Minor Grid( 1 ), Show Minor Labels( 0 )}
			)}
		),
		
		Dispatch(
			{},
			"graph title",
			TextEditBox,
			{Set Text( "Sensitivity vs. rxChnl" )}
		),
		Dispatch( {}, "Y title", TextEditBox, {Set Text( "Sensitivity" )} )
		
	)
	
);	

jrn2 = New Window( "j2", <<Journal,

    vb = V List Box(

        ob = Outline Box( dt1_band0_table:wfmFile[i]);
);

);

jrn2 << Append( V List Box( (dt1_subset_graph  << Report) << Clone Box));

//jrn2 << Save pdf ("C:\Users\NXF90574\Documents\NXP\VIshal\trial\1mbps.pdf");

new <<append (jrn2);


);

dt1_band0 << save as("C:\Users\NXF90574\Documents\NXP\VIshal\OWL_Kestrel_dvt2\DATA\DATA UPDATE\Subset of Subset of Subset of Owl_Kestrel_Dvt2_Test_names_TTT_NTV_band0.jmp");

close all(data tables, nosave);

new << Save Journal("C:\Users\NXF90574\Documents\NXP\VIshal\OWL_Kestrel_dvt2\DATA\DATA UPDATE\final_band0_corners.jrn");

close all(journals, nosave):

The main data table I am using is dt1_band0

I am running a for loop by looping for different column values from a column in data tabledt1_band0_table

I have created a journal "new " - every time a graph is generated within for loop its getting added to a journal "jrn2"

In the end I am appending "jrn2" to "new"

my final journal saved as pdf looks like this:

This is one page of my pdf

I would like to have these graphs side by side instead of vertically aligned

[#2]

Try using H List Box() (Or Lineup Box()) instead of V List Box(). This can also be a good read Construct Display Boxes for New Windows (jmp.com)

[#3]

Hello,

Here below an example with horizontally aligned graphs using the command H List Box().  H List Box helps you to organize horizontally your elements, whereas V List box it is vertically. You can also use the command Line up Box to organize in columns or the commands V Split Box / H Split Box if you want to specify also the proportions taken by each graphs in the journal space

dt1 = Open( "$SAMPLE_DATA/Big Class.jmp" );
dt2 = Open( "$SAMPLE_DATA/Big Class Families.jmp" );

	
jrn = New Window( "Journal",
	<<Journal, 

	Outline Box( "Horizontally aligned graphs",
		H List Box(
			dt1 << Graph Builder( Show Control Panel( 0 ), Variables( X( :height ), Y( :weight ) ), Elements( Points( X, Y ), Smoother( X, Y ) ) ),
			dt2 << Graph Builder(
				Show Control Panel( 0 ),
				Variables( X( :height ), Y( :weight ) ),
				Elements( Points( X, Y, Legend( 4 ) ), Line Of Fit( X, Y, Legend( 6 ) ) )
			);

		)
	)
);

[#4]

As H List Box and V List Box are actually the same object, just with a different option, you can later chance the Llayout by sending the message
Horizontal(1) to the display box.