Your reponses and question appear to me that you are not understanding how JMP handles date values. JMP handles dates and times, using a numeric value which is equal to the number of seconds since Midnight, January 1st, 1904. The way that JMP converts this into one of the displays of 09Feb2015, or 02/09/2015, etc. is to set a JMP format on the column that has the numeric values.
Therefore, if you have a character column, called "Date", with the values like "25.04.15", and you want to convert that into a JMP Date value, you can create a new column and if you apply the following formula,
Date DMY(
Num( Left( Char( :Date ), 2 ) ),
Num( Substr( Char( :Date ), 4, 2 ) ),
Num( "20" || Right( Char( :Date ), 2 ) )
)
it will take the character value of "25.04.15" and convert it into 3512764800. This is the number of seconds from Midnight January 1st, 1904 until Midnight, April, 25th, 2015. Now what is missing, is that you don't want the data displayed in the number of seconds. What you want, is for the value to be displayed in the data table, and on your reports in 2015-04-25. To do this, you just set the format for the column to "yyyy-mm-dd". The advantage of storing dates in this numeric form is that one can then order the data by date, and can do addition and subtraction on the values, or even calculate the mean date etc.
Below is a little script that when you run it, it will create a data table with a single character column that has the structure of dd.mm.yy. The script then creates a numeric JMP Date column changing the display structure to yyyy-mm-dd. The stript then goes on and creates a character column, which manipulates the character Date columns value into a new character string of the structure "yyy-mm-dd".
Names Default To Here( 1 );
// Create a beginning data table
dt = New Table( "Dates",
New Column( "Date",
Character,
ordinal,
Values( {"25.04.15", "22.09.15", "03.11.15"} )
)
);
// Create a new numeric column that contains a JMP date value
// and tell JMP to format the numeric value using a
// yyy-mm-dd structure
dt << New Column( "Numeric Date",
formula(
Date DMY(
Num( Left( Char( :Date ), 2 ) ),
Num( Substr( Char( :Date ), 4, 2 ) ),
Num( "20" || Right( Char( :Date ), 2 ) )
)
),
format("yyyy-mm-dd")
);
// Create a new character column that rearanges the data from
// from the character column "Date"
dt << New Column( "Character Date",
character,
formula(
"20" || Right( Char( :Date ), 2 ) || "-" ||
Substr( Char( :Date ), 4, 2 ) || "-" || Left( Char( :Date ), 2 )
)
);
Jim
