報告來自 LSMeans Differences Student's t 的數據

[#1]

大家好，

我正在嘗試使用 LSMeans Differences Student's 表中的具體數據製作報告：

我想要一張具有以下格式之一的表格：

遺憾的是，我無法讓它正確列印平均值，也無法從更大的表中獲取數據。我得到以下內容

我嘗試了以下程式碼，其中我將“17”更改為 1-30 之間的數字，但沒有任何效果 - 17 用於不同的輪廓框：

sd = Open( "test_table.jmp" );Fitmod = Fit Model(Y( :"Test value"n ),Effects( :Person ),Random Effects( :Day[:Person] ),NoBounds( 0 ),Personality( "Standard Least Squares" ),Method( "REML" ),Emphasis( "Effect Leverage" ),Run(:"Test value"n << {Summary of Fit( 1 ),Analysis of Variance( 0 ), Parameter Estimates( 1 ), Scaled Estimates( 0 ),Plot Actual by Predicted( 1 ), Plot Regression( 0 ),Plot Residual by Predicted( 1 ), Plot Studentized Residuals( 0 ),Plot Effect Leverage( 1 ), Plot Residual by Normal Quantiles( 0 ),{:Person << {LSMeans Student's t( 0.05 )}}}),Where( :ID == "A1" ),SendToReport(Dispatch({"Test value ID=A1"},"Whole Model",OutlineBox,{Close( 1 )}),Dispatch({"Test value ID=A1", "Person"},"Leverage Plot",OutlineBox,{Close( 1 )})));report(Fitmod) [Outline Box( 2 )] << Close( 0 );reportFitmod = Fitmod << Report;sumfit = reportFitmod[Outline Box( 17 )][Number Col Box( 1 )] << Get as Matrix; 

meandiff = sumfit[1];
lowerCL = sumfit[3];
upperCL = sumfit[4];term = reportFitmod[Outline Box( 13 )][String Col Box( 1 )] << Get();est = reportFitmod[Outline Box( 13 )][Number Col Box( 1 )] << Get as Matrix;dvalues = [];dvalues = meandiff |/ lowerCL |/ upperCL ;sfactor = term[2];dlg = New Window( "Custom Report",Outline Box( "Selected Values",Lineup Box( N Col( 2 ),Text Box( "Factor of Interest: " ),Text Box( sfactor ), ),tb = Table Box(String Col Box( " ",{"Mean difference: ", "Upper limit: ", "Lower limit: "}),Spacer Box( Size( 30, 30 ) ),,Spacer Box( Size( 0, 30 ) ),,Table Box(CloneTerm,Spacer Box( Size( 10, 0 ) ),,Number Col Box( "Estimate", est ),Spacer Box( Size( 10, 0 ) ),,Number Col Box( "Mean difference", meandiff))));tb << Set Shade Headings( 0 ); // Turn off shaded table headings.tb << Set Heading Column Borders( 0 ); // Turn off table column borders.

如何從更大的表中報告數據？

此致

[#2]

歡迎來到 JMP 社群。

我認為您附加的資料表和您附加的腳本之間存在混淆。腳本中對要分析的列的參考與附加資料表中的列不符。

如果您可以提供正確的附件，我相信社區將能夠幫助您的努力。

[#3]

親愛的吉姆，

我為混淆表示歉意。謝謝你讓我知道。我現在已附上正確的腳本。

朱莉

[#4 · Accepted solution]

這可能會幫助您獲得最終產品。它產生

Names Default To Here( 1 );
sd = //Open( "test_table.jmp" );
Data Table( "test_table" );
Fitmod = Fit Model(
	Y( :"Test value"n ),
	Effects( :Person ),
	Random Effects( :Day[:Person] ),
	NoBounds( 0 ),
	Personality( "Standard Least Squares" ),
	Method( "REML" ),
	Emphasis( "Effect Leverage" ),
	Run(
		:"Test value"n << {Summary of Fit( 1 ), Analysis of Variance( 0 ), Parameter Estimates( 1 ), Scaled Estimates( 0 ),
		Plot Actual by Predicted( 1 ), Plot Regression( 0 ), Plot Residual by Predicted( 1 ), Plot Studentized Residuals( 0 ),
		Plot Effect Leverage( 1 ), Plot Residual by Normal Quantiles( 0 ), {:Person << {LSMeans Student's t( 0.05 )}}}
	),
	Where( :ID == "A1" ),
	SendToReport(
		Dispatch( {"Test value ID=A1"}, "Whole Model", OutlineBox, {Close( 1 )} ),
		Dispatch( {"Test value ID=A1", "Person"}, "Leverage Plot", OutlineBox, {Close( 1 )} )
	)
);
Report( Fitmod )[Outline Box( 2 )] << Close( 0 );
reportFitmod = Fitmod << Report;
sumfit = reportFitmod[Outline Box( "Least Squares Means Table" )][Number Col Box( 1 )] << Get as Matrix; 
// Get data from CrossTab table
crossTab = reportFitmod[Outline Box( "LSMeans Differences Student's t" )][CrosstabBox( 1 )] << get as matrix;
// Get Where clause variable
whereCol = Word( 2, ((reportFitmod << parent)[Text Box( 1 )]) << get text, ":=)" );
whereVal = {};
Eval( Parse( "insert into(whereVal," || Word( 2, ((reportFitmod << parent)[Text Box( 1 )]) << get text, "=)" ) || ");" ) );
meandiff = Round( Abs( crossTab[1, 2] ), 4 );
lowerCL = Round( Abs( crossTab[3, 2] ), 3 );
upperCL = Round( Abs( crossTab[4, 2] ), 3 );
term = reportFitmod[Outline Box( "Least Squares Means Table" )][String Col Box( 1 )] << Get();
est = reportFitmod[Outline Box( "Least Squares Means Table" )][Number Col Box( 1 )] << Get as Matrix;
testValue = {};
Insert Into( testValue, (Substr( reportFitmod[Outline Box( 1 )] << get title, 10 )) );
dif = {};
Insert Into( dif, Char( meandiff ) || " [" || Char( lowerCL ) || ";" || Char( upperCL ) || "]" );

dlg = New Window( "Custom Report",
	Outline Box( "Selected Values",
		Lineup Box( N Col( 2 ), Text Box( "Factor of Interest: " ), Text Box( sfactor ) ),
		Spacer Box( size( 0, 10 ) ),
		tb = Table Box(
			String Col Box( "Test Value", testvalue ),
			String Col Box( whereCol, whereVal ),
			Number Col Box( "Mean, " || term[1], sumfit[1] ),
			Number Col Box( "Mean, " || term[2], sumfit[2] ),
			String Col Box( "Difference in mean and CI", dif )
			
		)
	)

);
tb << Set Shade Headings( 0 ); // Turn off shaded table headings.
tb << Set Column Borders( 1 ); // Turn off table column borders.
tb << Set row Borders( 1 );
tb << border( 1 );

 

[#5]

嗨吉姆，

如果有多個 ID 來產生包含所有不同元素的表，則應該如何更改腳本？可以為此實現一個循環嗎？

此致，

朱莉

[#6]

我已經修改了 JSL，使其能夠處理多個層級的 ID。

Names Default To Here( 1 );
sd = //Open( "test_table.jmp" );
Data Table( "test_table " );
Fitmod = Fit Model(
	Y( :"Test value"n ),
	Effects( :Person ),
	Random Effects( :Day[:Person] ),
	NoBounds( 0 ),
	Personality( "Standard Least Squares" ),
	Method( "REML" ),
	Emphasis( "Effect Leverage" ),
	Run(
		:"Test value"n << {Summary of Fit( 1 ), Analysis of Variance( 0 ), Parameter Estimates( 1 ),
		Scaled Estimates( 0 ), Plot Actual by Predicted( 1 ), Plot Regression( 0 ),
		Plot Residual by Predicted( 1 ), Plot Studentized Residuals( 0 ), Plot Effect Leverage( 1 ),
		Plot Residual by Normal Quantiles( 0 ), {:Person << {LSMeans Student's t( 0.05 )}}}
	),
	by( :ID ),
	SendToReport(
		Dispatch( {"Test value ID=A1"}, "Whole Model", OutlineBox, {Close( 1 )} ),
		Dispatch( {"Test value ID=A1", "Person"}, "Leverage Plot", OutlineBox, {Close( 1 )} )
	)
);

// Set the lists for the storage of the data from the by groups
whereVal = testValue = dif = sumfit1 = sumfit2 = {};

// Loop across each by group and gather the data
For Each( {rpt, group}, Fitmod, 
	// Point to the current report
	reportFitmod = Fitmod[group] << Report;
	
	// Get the means for the 2 levels
	sumfit = reportFitmod[Outline Box( "Least Squares Means Table" )][Number Col Box( 1 )] << Get as Matrix;
	Insert Into( sumfit1, sumfit[1] );
	Insert Into( sumfit2, sumfit[2] );
	term = reportFitmod[Outline Box( "Least Squares Means Table" )][String Col Box( 1 )] << Get();
	
	// Get By Group column
	whereCol = Word( 1, (reportFitmod[Outline Box( 1 )] << get title), "=)" );
	Insert Into( whereVal, Word( 2, (reportFitmod[Outline Box( 1 )] << get title), "=)" ) );
		
	// Get data from CrossTab table
	crossTab = reportFitmod[Outline Box( "LSMeans Differences Student's t" )][CrosstabBox( 1 )] <<
	get as matrix;
	meandiff = Round( Abs( crossTab[1, 2] ), 4 );
	lowerCL = Round( Abs( crossTab[3, 2] ), 3 );
	upperCL = Round( Abs( crossTab[4, 2] ), 3 );
	
	// Get the Response variable name
	Insert Into( testValue, (Substr( (reportFitmod << topparent)[Outline Box( 1 )] << get title, 10 )) );

	// Create the Differeence in mean and CL string
	Insert Into( dif, Char( meandiff ) || " [" || Char( lowerCL ) || ";" || Char( upperCL ) || "]" );
);

// Create the table
dlg = New Window( "Custom Report",
	Outline Box( "Selected Values",
		Lineup Box( N Col( 2 ), Text Box( "Factor of Interest: " ), Text Box( term[1] ) ),
		Spacer Box( size( 0, 10 ) ),
		tb = Table Box(
			String Col Box( "Test Value", testvalue ),
			String Col Box( whereCol, whereVal ),
			Number Col Box( "Mean, " || term[1], sumfit1 ),
			Number Col Box( "Mean, " || term[2], sumfit2 ),
			String Col Box( "Difference in mean and CI", dif )
			
		)
	)

);
tb << Set Shade Headings( 0 ); // Turn off shaded table headings.
tb << Set Column Borders( 1 ); // Turn off table column borders.
tb << Set row Borders( 1 );
tb << border( 1 );

你現在的工作是研究腳本，了解它的作用。該腳本適用於您指定的範例資料表和擬合模型。但是，具有不同欄位和不同擬合模型執行的不同資料表可能不適用於產生報告輸出的 JSL。您需要具備足夠的知識才能修改腳本以滿足您的需求。

腳本指南和腳本索引是很好的參考，可在 JMP 的「幫助」下拉式選單下找到。

當然，JMP 討論社群將幫助您學習腳本。

[#7]

感謝您令人印象深刻的工作！

我嘗試運行該腳本，但出現錯誤。我嘗試瀏覽舊案例並谷歌搜尋 For Each 函數和錯誤，並嘗試修改腳本但無濟於事。我的版本是 16，這會對腳本造成問題嗎？

我相信該錯誤源於 {rpt, group}，因為我嘗試刪除 For Each 中的所有內容，但仍然收到此錯誤。

大部分我都能理解，但是我們從哪裡得到這個rpt以及它是如何使用的呢？它只在 For Each( {rpt, group} ...) 中提到，所以我無法合理地解釋它是如何適合的。

[#8]

您使用什麼版本的 JMP？ For Each() 已在版本 16 中加入 JMP 中。

需要修改腳本才能處理這兩個更改。

[#9]

我使用 JMP 版本 16.1.0，所以這一定是原因。

FitMod 函數是否需要替換為其他函數，或者 FitMod 仍然可以以不同的方式使用嗎？

[#10 · Accepted solution]

這是腳本的修改版本。我已在 JMP 16 中對其進行了測試。然後，該腳本收集每個單獨擬合模型輸出的輸出並產生最終輸出顯示

Names Default To Here( 1 );
sd = //Open( "test_table.jmp" );
Data Table( "test_table" );
Fitmod = {};

// Determine the levels in the ID column
summarize( sd, ByGroups = By( :ID ) );

// Loop across each levle of ID 
For Each( {BG, group}, ByGroups,
	Fm = Fit Model(
		Y( :"Test value"n ),
		Effects( :Person ),
		Random Effects( :Day[:Person] ),
		NoBounds( 0 ),
		Personality( "Standard Least Squares" ),
		Method( "REML" ),
		Emphasis( "Effect Leverage" ),
		Run(
			:"Test value"n << {Summary of Fit( 1 ), Analysis of Variance( 0 ),
			Parameter Estimates( 1 ), Scaled Estimates( 0 ), Plot Actual by Predicted( 1 ),
			Plot Regression( 0 ), Plot Residual by Predicted( 1 ),
			Plot Studentized Residuals( 0 ), Plot Effect Leverage( 1 ),
			Plot Residual by Normal Quantiles( 0 ), {:Person << {LSMeans Student's t( 0.05 )}}}
		),
		Where( :ID == ByGroups[group] ),
		SendToReport(
			Dispatch( {"Test value ID=A1"}, "Whole Model", OutlineBox, {Close( 1 )} ),
			Dispatch(
				{"Test value ID=A1", "Person"},
				"Leverage Plot",
				OutlineBox,
				{Close( 1 )}
			)
		)
	);

// Save the pointer to the results in the Fitmod list
	Insert Into( Fitmod, Fm );
);

// Set the lists for the storage of the data from the by groups
testValue = dif = sumfit1 = sumfit2 = {};

// Loop across each by group and gather the data
For Each( {rpt, group}, Fitmod, 
	// Point to the current report
	reportFitmod = Fitmod[group] << Report;
	
	// Get the means for the 2 levels
	sumfit = reportFitmod[Outline Box( "Least Squares Means Table" )][Number Col Box( 1 )] << Get as Matrix;
	Insert Into( sumfit1, sumfit[1] );
	Insert Into( sumfit2, sumfit[2] );
	term = reportFitmod[Outline Box( "Least Squares Means Table" )][String Col Box( 1 )] << Get();
	
	// Get By Group column
	whereCol = Word( 2, ((reportFitmod << parent)[Text Box( 1 )]) << get text, ":=)" );
		
	// Get data from CrossTab table
	crossTab = reportFitmod[Outline Box( "LSMeans Differences Student's t" )][CrosstabBox( 1 )] <<
	get as matrix;
	meandiff = Round( Abs( crossTab[1, 2] ), 4 );
	lowerCL = Round( Abs( crossTab[3, 2] ), 3 );
	upperCL = Round( Abs( crossTab[4, 2] ), 3 );
	
	// Get the Response variable name
	Insert Into( testValue, (Substr( (reportFitmod << topparent)[Outline Box( 1 )] << get title, 10 )) );

	// Create the Differeence in mean and CL string
	Insert Into( dif, Char( meandiff ) || " [" || Char( lowerCL ) || ";" || Char( upperCL ) || "]" );
);

// Create the table
dlg = New Window( "Custom Report",
	Outline Box( "Selected Values",
		Lineup Box( N Col( 2 ), Text Box( "Factor of Interest: " ), Text Box( term[1] ) ),
		Spacer Box( size( 0, 10 ) ),
		tb = Table Box(
			String Col Box( "Test Value", testvalue ),
			String Col Box( whereCol, ByGroups ),
			Number Col Box( "Mean, " || term[1], sumfit1 ),
			Number Col Box( "Mean, " || term[2], sumfit2 ),
			String Col Box( "Difference in mean and CI", dif )
			
		)
	)

);
tb << Set Shade Headings( 0 ); // Turn off shaded table headings.
tb << Set Column Borders( 1 ); // Turn off table column borders.
tb << Set row Borders( 1 );
tb << border( 1 );