Saving entered Profiler Remember Setting in Model Script

[#1]

I am using the Reliability Growth Model (JMP 16.2.0) and entering ~20 unique values in the Cumulative Events Profiler using the Remember Settings feature. Unfortunately these values do not save with the Reliability Growth JSL script, so each time I re-open the model I am forced to manually enter the 20 values all over again if I desire to compare values-a necessary part of my analysis. 

Is there a way to generate the JSL code for these entered values that I can attached to the model script so that when I launch it, the 20 values will still remain?

Thank you!

JP

[#2]

I am the developer of the platform. The platform can remember those settings in the saved script since JMP17. Please consider update.

[#3]

Thank you for this advise. I have opened in inquiry in updating to a newer version with my company- while this is being explored is it possible to share the JSL script that I can utilize immediately? 

[#4]

The mechanism of remembering those settings in JMP17 and higher version is not applicable in JMP16. I.e. the script in JMP17 won't be recognized in JMP16.

In JMP16, however, you can manually code it up. Following is an example with brief explanation:

dt = open("$Sample_Data/Reliability/NewEngineOperation.jmp");
//Following runs the platform, fit a model, and returns a handle.
//We usually call it "obj" as a convention.
obj = dt << Reliability Growth(
	Input Format( Time to Event ),
	Time to Event( :Hours ),
	Event Count( :Fixes ),
	Crow AMSAA( Show Profilers( 1 ), Show Profilers( 1 ) ),
);

//Report(obj) gets the display part that you see for "obj"
//What are in the squared brackets navigate the display and find the Profiler
//Eventually, get scriptable object command to the display of the profiler retrieves the Profiler itself. Assign it to "cef". Now "cef" can accept messages.
cef = (report(obj)["Models", "Crow-AMSAA", "Profilers", "Cumulative Events Profiler"]) << get scriptable object();
//This command sets up the profiler with desired values.
cef	<< Term Value(Hours( 5102.5, Lock( 0 ), Show( 1 ) ) );
//This command tell the profiler to "remember" the current setting.
cef << Remember Settings( "Setting 1", Differences Report( 0 ) );
//This command sets up the profiler with a different desired value.
cef << Term Value( Hours( 4032, Lock( 0 ), Show( 1 ) ) );
//This command tells the profiler to remember current setting again.
cef << Remember Settings( "Setting 2", Differences Report( 1 ) );
//The last command sets the profiler again, but no remember command follows.
cef << Term Value( Hours( 4032, Lock( 0 ), Show( 1 ) ) );