JMP 14: Changing Axis Title of multiple control charts

[#1]

Hi,

I have control charts created from multiple variables however I want to change the axis title so they match. Is there a quick way to do this without manually changing them. I've tried holding ctrl while doing so however that seems to change the x axis title as for some reason , any ideas, thanks?

[#2]

Are you able to attach a sample table, along with a saved script of a sample control chart report? That would help us get a handle on what exactly is your situation. Also, please show us what you mean by "title", as there may be more than one spot we could interpret as a title.

Cheers,

Brady

[#3]

Hi @Mo_Hoque_95 ,

Brady might have a method to do this simply, but the only way I know how to do this easily is with a script, especially if you have a lot of control charts. You did not mention if you are using the legacy Control Chart UI  or the Control Chart Builder UI or something else to create your control charts. Below, this script opens a JMP sample data table, creates legacy control charts, then customizes all x axis labels. //======== segments the JSL.  The second example uses the control chart builder UI.

Good Luck! I hope there is a simple alternate method. 

Names Default to Here(1);
dt =Open("$Sample_Data/Quality Control/Steam Turbine Historical.jmp");

//==========JMP 14 Legacy Control Charts ==================================
// Saved the script of my control chart window to a script window
// Assigned the Control Chart report to cc using cc=
cc = Control Chart(
	Group Size( 1 ),
	KSigma( 3 ),
	Chart Col( :Fuel, Individual Measurement ),
	Chart Col( :Steam Flow, Individual Measurement ),
	Chart Col( :Steam Temp, Individual Measurement ),
	Chart Col( :MW, Individual Measurement ),
	Chart Col( :Cool Temp, Individual Measurement ),
	Chart Col( :Pressure, Individual Measurement )
);

//xpath creates a list of references to each box. Note the X or sequence 
// AxisBox might have a different ID depending upon your use: Legacy Control Chart or Control Chart Builder
axx = cc <<  xpath("//AxisBox[@charID='1']/TextEditBox");

//now send a few customizing messages to all these axes 
axx << {Set Font Size( 12 ), Set Font Style( "Bold" ), Font Color( 19 ),
			Set Text( " Samples May 24 - Jun20" )};


//================== JMP 14 Using Control Chart Builder===============================================================
//JMP 15 and later versions have a better structure for X axis labels, I find the graph structure strange in v14
ccb14 = Control Chart Builder(
	Show Capability( 0 ),
	Variables( Y( :Fuel, :Steam Flow, :Steam Temp, :MW, :Cool Temp, :Pressure ) ),
	Chart( Position( 1 ), Limits( Sigma( "Moving Range" ) ) ),
	Chart( Position( 2 ), Limits( Sigma( "Moving Range" ) ) )
);
axxb14= ccb14 <<  xpath("//GraphBuilderTitleBox/TextEditBox");

//Every 3rd GraphTitleBox is the Xaxis or Subgroup axis 

For(i=3, i<=nitems(axxb14), i=i+5,
	axxb14[i]<<  {Set Font Size( 12 ), Set Font Style( "Bold" ), Font Color( 19 ),
			Set Text( " Samples May 24 - Jun20" )};
);


//========================JMP 15========================================================
/*
//It's my opinion, JMP 15 has better structure references , AxisBox for Subgroup
//this code is commented out since you are working with JMP14
ccb15 = Control Chart Builder(
	Variables Y( :Fuel, :Steam Flow, :Steam Temp, :MW, :Cool Temp, :Pressure ) );
axxb15= ccb15 <<  xpath("//AxisBox['Subgroup']/TextEditBox");

axxb15 << {Set Font Size( 12 ), Set Font Style( "Bold" ), Font Color( 19 ),
			Set Text( " Samples May 24 - Jun20" )};