In process capability function, How to display only Histogram?

[#1]

Hi!

I want to see only Histogram with Process Capability.

There is a column list "colDlg["ycol"]", but it does not apply to reporting.
Could you give any advice on this?

Also, is it possible to add "groupby" to the histogram?

//Select Test Item for Scatterplot Matrix
colDlg = Column Dialog(
Title( "Test Item Selct" ),
ycol = Col List( "Test Item", Min Col( 1 ) ), //
);

hist = dt << Process Capability(
	Process Variables(eval(colDlg["ycol"])),
	Spec Limits Dialog( "No (skip columns with no spec limits)" ),
	Moving Range Method( Average of Moving Ranges ),
	Individual Detail Reports( 1 ),
	Capability Box Plots( 0 ),
	Overall Sigma Normalized Box Plots( 0 ),
	Overall Sigma Summary Report( 0 ),
	Goal Plot( 0 ),
	Capability Index Plot( 0 ),
	Process Performance Plot( 0 ),

    /* This part is not applied.
	{colDlg["ycol"] << Process Capability Analysis(
		Process Summary( 0 ),
		Overall Sigma Capability( 0 ),
		Nonconformance( 0 ),
		Within Sigma Capability( 0 ),
		Histogram(
			1,
			Show Target( 0 ),
			Show Within Sigma Density( 0 ),
			Show Overall Sigma Density( 0 )
		)
	)}*/

);

[#2]

Here is an example of removing the unwanted Outlier Boxes

Names Default To Here( 1 );
dt = 
// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

pc = Process Capability(
	Process Variables( :NPN1, :NPN2 ),
	Moving Range Method( Average of Moving Ranges ),
	Individual Detail Reports( 1 ),
	Capability Box Plots( 0 ),
	Goal Plot( 0 ),
	Capability Index Plot( 0 ),
	Process Performance Plot( 0 )
);

(Report( pc ) << xpath( "//OutlineBox[text()='Process Summary']" )) << delete;
(Report( pc ) << xpath( "//OutlineBox[text()='Within Sigma Capability']" )) << delete;
(Report( pc ) << xpath( "//OutlineBox[text()='Overall Sigma Capability']" )) << delete;
(Report( pc ) << xpath( "//OutlineBox[text()='Nonconformance']" )) << delete;

I am not sure as to what you are wanting to do with your comment about GroupBy.  Would you please illustrate what the expected grouping would be and how the various groups would be displayed?

[#3]

Hi.

Thank you for the solution.

I want to delete below things on histogram. Could you tell me how to do it?

-Within Sigma Density

-Overall Sigma Density

-Target

(*Sample image)

As for Groupby,

I want to  select machine number as groupby.

machine number is integer.

please see the sample image below

(*"Column 1" would be Machine #) 

By any chance, If you know the better analysis to compare machine, please let me know.

I'll really appreciate it.

(*Sample image)

Thanks

[#4 · Accepted solution]

To remove the Target reference line in the histogram, simply set the value for the target in the Spec Limits Column Property to blank.

Below is an example of using a By() element in the Process Capability, and going through each By level and delete the outline boxes associated with the Capability Analysis.

Names Default To Here( 1 );
dt = 
// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

pc = Process Capability(
	Process Variables( :NPN1, :NPN2 ),
	Moving Range Method( Average of Moving Ranges ),
	Individual Detail Reports( 1 ),
	Capability Box Plots( 0 ),
	Goal Plot( 0 ),
	Capability Index Plot( 0 ),
	Process Performance Plot( 0 ),
	by( :Site )
);
nSites = N Items( Associative Array( :site ) );
For( i = 1, i <= nsites, i++,
	(Report( pc[i] ) << xpath( "//OutlineBox[text()='Process Summary']" )) << delete;
	(Report( pc[i] ) << xpath( "//OutlineBox[text()='Within Sigma Capability']" )) << delete;
	(Report( pc[i] ) << xpath( "//OutlineBox[text()='Overall Sigma Capability']" )) << delete;
	(Report( pc[i] ) << xpath( "//OutlineBox[text()='Nonconformance']" )) << delete;
);

[#5]

Thank you very much!