Choose Language Hide Translation Bar
Highlighted
joshua
Level II

How to delete outlinebox that not required from graphs

Hi 

 

I want to delete outlinebox that are not required (or I don't want have).

Following this post https://community.jmp.com/t5/Discussions/How-to-show-fit-line-graphs-in-a-single-report-without-the/...

We can delete the all of the boxes. But I want to keep only 'Linear Fit Site == 1' and the equation

 
 

image.png

 

So I tried

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );
biv = Bivariate(
	Y( :NPN1 ),
	X( :PNP1 ),
	Fit Where( :SITE == 1, Fit Line( {Line Color( {213, 72, 87} )} ) ));
	
biv[Outline Box(3)] << Delete;	
biv[Outline Box(4)] << Delete;
biv[Outline Box(5)] << Delete;

But still those boxes are there. The expected output that I need

 

image.png

 

 

 

1 ACCEPTED SOLUTION

Accepted Solutions
Highlighted
Craige_Hales
Staff (Retired)

Re: How to delete outlinebox that not required from graphs

Also consider using <<Visibility rather than <<Delete.

Report(biv)[Outline Box(3)] << Visibility("collapse");

"Collapse" will hide the box and remove the space it uses in the report, without deleting the box. Two advantages: (1) the displaybox numbering does not shift around and (2) some platforms might be confused by deleting certain display boxes they depend on.

I like Jim's final example combined with Visibility:

dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );
biv = Bivariate(
	Y( :NPN1 ),
	X( :PNP1 ),
	Fit Where( :SITE == 1, Fit Line( {Line Color( {213, 72, 87} )} ) ));
	
Report(biv)["Summary of Fit"] << Visibility("collapse");
Report(biv)["Analysis of Variance"] << Visibility("collapse");
Report(biv)["Parameter Estimates"] << Visibility("collapse");

which explains itself to anyone that needs to understand or maintain it later.

 

Craige

View solution in original post

2 REPLIES 2
Highlighted
txnelson
Super User

Re: How to delete outlinebox that not required from graphs

See my annotated JSL below

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );
biv = Bivariate(
	Y( :NPN1 ),
	X( :PNP1 ),
	Fit Where( :SITE == 1, Fit Line( {Line Color( {213, 72, 87} )} ) ));
	
// When you are modifying the output from a Platform
// one needs to access the report
// Additionally, you need to delete the outline boxes either in
// reverse order as below, since the Butline Box nomenclature
// will change after the deletion of a box.  That is, if you delete
// Outline Box(3) first, once it is deleted, what was Outline Box(4)
// will now be the 3rd Outline Box etc.	
Report(biv)[Outline Box(5)] << Delete;
Report(biv)[Outline Box(4)] << Delete;
Report(biv)[Outline Box(3)] << Delete;

/*
// To illustrate this, you can actually eliminate the 3 Outline Boxes
// with the code below
Report(biv)[Outline Box(3)] << Delete;
Report(biv)[Outline Box(3)] << Delete;
Report(biv)[Outline Box(3)] << Delete;

// and an alternative method would be to use direct references
Report(biv)["Summary of Fit"] << Delete;
Report(biv)["Analysis of Variance"] << Delete;
Report(biv)["Parameter Estimates"] << Delete;
*/	
Jim
Highlighted
Craige_Hales
Staff (Retired)

Re: How to delete outlinebox that not required from graphs

Also consider using <<Visibility rather than <<Delete.

Report(biv)[Outline Box(3)] << Visibility("collapse");

"Collapse" will hide the box and remove the space it uses in the report, without deleting the box. Two advantages: (1) the displaybox numbering does not shift around and (2) some platforms might be confused by deleting certain display boxes they depend on.

I like Jim's final example combined with Visibility:

dt = Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );
biv = Bivariate(
	Y( :NPN1 ),
	X( :PNP1 ),
	Fit Where( :SITE == 1, Fit Line( {Line Color( {213, 72, 87} )} ) ));
	
Report(biv)["Summary of Fit"] << Visibility("collapse");
Report(biv)["Analysis of Variance"] << Visibility("collapse");
Report(biv)["Parameter Estimates"] << Visibility("collapse");

which explains itself to anyone that needs to understand or maintain it later.

 

Craige

View solution in original post

Article Labels

    There are no labels assigned to this post.