How to avoid JMP Alert window in a JSL

[#1]

Names Default To Here( 1 );

If( N Table() == 0, Open(), );

dt = Current Data Table();

//Create Lauch Window for prompting dialog
nw = New Window( <<Modal,
    V List Box(
        Lineup Box( N Col( 2 ), Spacing( 14 ), ),
        H List Box(
            Panel Box( "Select Columns", clb = Filter Col Selector( dt, all ) ),
            Panel Box( "Cast Selected Columns into Fit Model Roles",
                Lineup Box( N Col( 2 ),
                    Button Box( "Y, Response", clbY << Append( clb << Get Selected ) ),
                    clbY = Col List Box( "Numeric", MinItems( 1 ), nlines( 8 ) ), 

                    Button Box( "X, Two Samples",
                        clbXs << Append( clb << Get Selected )
                    ),
                    clbXs = Col List Box(
                        "Character",
                        MinItems( 1 ),
                        MaxItems( 1 ),
                        nlines( 1 )
                    ), 

                )
            ), 

            Panel Box( "Action",
                Button Box( "OK",
                    yVars = clby << Get Items( "Column Reference" );
                    eVars = clbXs << Get Items( "Column Reference" );
                ), 

                Button Box( "Cancel" ),
                Text Box(),
                Button Box( "Remove",
                    clbY << Remove Selected;
                    clbXs << Remove Selected;
                )
            ), 

        ),
        H List Box()
    )
);

If( nw["button"] == -1,
    Throw( "Cancelled!" )
);

[#2]

Open will throw an error if Cancel is pressed and you can catch it with Try-catch.

Names Default To Here(1);

Try(
	dt = Open();
,
	show(exception_msg);
);

Do error handling in the catch part, example above will just print the message to log and lets script to continue running.

[#3]

Thanks for your fast reply. What additional code must be added or changed after the open dialog is canceled (with no alert window) to stop the code from running the dialog window?

[#4 · Accepted solution]

Names Default To Here( 1 );
If( N Table() == 0,
	dt = Current Data Table();
	Clear Symbols( dt );
	Try( dt = Open() );
	If( Is Empty( dt ), throw());
);

[#5]

Thanks, Jim. That was exactly what I was looking for.