Changing titles for oneway

[#1]

My script below, first script, will not acknowledge any changes I make for set title. It keeps defaulting to "Oneway Analysis of PARAMETER_VALUE By Status" regardless of what I enter for set title.

I have a script for distribution, second script, and I don't seem to have any problems with it so I'm not sure what is going on. 

Any ideas on what I need to change?

Thank You

Template_TM = Expr(
	TM = Oneway(
		Y(:PARAMETER_VALUE),
		X(:Status),
		Each Pair(1),
		Means and Std Dev(1),
		t Test(1),
		Points Jittered(1),
		Box Plots(1),
		Mean Error Bars(1),
		Std Dev Lines(1),
		Comparison Circles(1),
		X Axis Proportional(0),
		Histograms(0),
		Where(:PARAMETER_ID == Eval(TargetParameter)),
		SendToReport(
			Dispatch({}, "Oneway Analysis of MEAS_DATA By Status", OutlineBox, {Set Title( TargetParameter )}),
			Dispatch({}, "1", ScaleBox, {Scale("Log"), Min(0.0001), Max(5), Inc(1), Minor Ticks(1), Label Row Nesting(1), Add Ref Line(Eval(Limit_UCL), "Dotted", "Dark Blue", "UCL", 1)}),
			Dispatch({}, "MEAS_DATA", TextEditBox, {Set Text("E10 Atoms / cm2")}),
			Dispatch({}, "Oneway Plot", FrameBox,),
			Dispatch({}, "Means Comparisons", OutlineBox, {Close(1)})
		)
	)
);

Template_CAP = Expr(

	CAP01 =
		Distribution(
		Continuous Distribution(
		Column(:PARAMETER_VALUE),
		Quantiles(0),
		Horizontal Layout(1),
		Vertical(0),
		Capability Analysis(USL(Eval(Limit_UCL)))),
		Where(:PARAMETER_ID == Eval(TargetParameter) & :Status == "1) POR"),
		SendToReport(
			Dispatch({},"Distributions",OutlineBox,{Set Title( TargetParameter )}),
			Dispatch({"Distribution 1) POR", "PARAMETER_VALUE"},"1",ScaleBox,{Format("Fixed Dec", 15, 3), Min(0), Max(2), Inc(0.2),Minor Ticks(1), Label Row Nesting(1)}),
			Dispatch({"Distributions", "PARAMETER_VALUE"},"Distrib Histogram",FrameBox,{DispatchSeg(LabelSeg(1), {Font("Tw Cen MT", 7, "Plain")})}),
			Dispatch({"Distributions", "PARAMETER_VALUE", "Capability Analysis", " Long Term Sigma"}, "1", ScaleBox, {Format("Fixed Dec", 9, 3), Min(-2), Max(2), Inc(0.5), Minor Ticks(0), Label Row Nesting(1)})
		)
	);

[#2]

The first thing I see is that when I select your script for Oneway, there's a stray quotation mark after TargetParameter for Oneway that isn't there for Distribution. You have to select it to see it - I don't know why.

{Set Title( TargetParameter")}

If I run that, I get syntax errors because everything's messed up. But if I remove the quotation mark, this works for me. Here's what I changed it to so I could run it. I made some changes to the axis numbers so the data showed up in the graph, and I commented out the line referring to a texteditbox that doesn't appear in my report. But the outline box's title is changed to what I set TargetParameter equal to (in this case, "F").

dt = Open("$SAMPLE_DATA/Big Class.jmp");
TargetParameter = "F";
Limit_UCL = 100;

Template_TM = Expr(
	TM = Oneway(
		Y(:weight),
		X(:height),
		Each Pair(1),
		Means and Std Dev(1),
		t Test(1),
		Points Jittered(1),
		Box Plots(1),
		Mean Error Bars(1),
		Std Dev Lines(1),
		Comparison Circles(1),
		X Axis Proportional(0),
		Histograms(0),
		Where(:sex == Eval(TargetParameter)),
		SendToReport(
			Dispatch({}, "Oneway Analysis of weight By height", OutlineBox, {Set Title( TargetParameter )}),
			Dispatch({}, "1", ScaleBox, {Scale("Log"), Min(60), Max(150), Inc(1), Minor Ticks(1), Label Row Nesting(1), Add Ref Line(Eval(Limit_UCL), "Dotted", "Dark Blue", "UCL", 1)}),
		//	Dispatch({}, "MEAS_DATA", TextEditBox, {Set Text("E10 Atoms / cm2")}),
			Dispatch({}, "Oneway Plot", FrameBox,),
			Dispatch({}, "Means Comparisons", OutlineBox, {Close(1)})
		)
	);
)

[#3 · Accepted solution]

Melanie,

That quotation mark was a typo. After I copied my script over I changed that  to say TargetParameter and missed deleting that extra quotation mark.

You did however help me see my mistake/issue and this is now working. (Thank you so much)

The issue was in the first dispatch line, I had:

Dispatch({}, "Oneway Analysis of MEAS_DATA By Status", OutlineBox, {Set Title(TargetParameter)}),

 When I should have had:

Dispatch({}, "Oneway Analysis of PARAMETER_VALUE By Status", OutlineBox, {Set Title( TargetParameter )}),

I didn't think of changing this because I didn't think that would make a difference but I guess this has to match whatever is entered for Y and X.

Thanks again for your reply I probably wouldn't have noticed it without you.

[#4]

Ha! I didn't even see that, because I had to change the whole title to make it work at all with my one-off attempt. Glad you saw it :)