아래 첨자 참조가 잘못된 표시 상자

[#1]

아래 스크립트에서 반환된 제목이 "Fitted Weibull Distribution"일 것으로 예상했지만 대신 "Fitted Normal Distribution"이 반환되었습니다. 무슨 문제인지 잘 모르겠고, 정말 도움을 주셔서 감사합니다.

names default to here(1);

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

db = dt << Distribution(
	Stack( 1 ),
	Continuous Distribution(
		Column( :height ),
		Horizontal Layout( 1 ),
		Vertical( 0 )
	)
);

db << fit all;

Title_1 = report(db)[Outlinebox("Fitted?")] << get title;
print(Title_1);

[#2]

내 추측은 JMP가 Fitted 출력을 모두 메모리에 생성하므로 요청할 때

Title_1 = report(db)[Outlinebox("Fitted?")] << get title;

Fitted Normal은 메모리에서 첫 번째이므로 반환됩니다. 이 문제는 다음을 통해 우회할 수 있습니다.

Title_1 = report(db)[Outlinebox("Fitted Weibull?")] << get title;

또는

Title_1 = report(db)[Outlinebox( 6 )] << get title;

[#3]

보이지 않더라도 모든 다른 적합이 여전히 존재한다고 생각합니다(If 상자 아래에 있음). 보고서 구독은 여전히 ​​해당 적합과 일치하고 마지막으로 ? 와일드카드 검색을 사용하면 검색을 만족하는 첫 번째 개요 상자와 일치합니다(이 경우 Fit Normal Distribution).

JMP를 사용하면 속성 표시 메뉴(상자 경로)에서 경로를 빌드할 수 있습니다.

Report(platform)["height","Fitted Weibull Distribution"]

더 긴 검색어를 입력할 수 있습니다. (가능하다면 ? 는 피하는 것이 좋습니다.)

Title_1 = report(db)[Outlinebox("Fitted W?")] << get title;

또는 XPath를 사용하여 모든 제목을 가져오고 원하는 것을 가져옵니다.

fit_obs = Report(db) << XPath("//OutlineBox[contains(text(), 'Fitted ')]");
fit_obs << get title;

[#4]

아, 맞아요. 모든 가능한 핏이 백그라운드에 저장된다는 걸 전에는 몰랐어요. 알아두면 좋죠!

[#5]

저는 정렬된 적합 표를 사용하여 참조를 만들 것입니다.

Names Default To Here( 1 );

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

db = dt << Distribution(
	Stack( 1 ),
	Continuous Distribution(
		Column( :height ),
		Horizontal Layout( 1 ),
		Vertical( 0 )
	)
);

db << fit all;

rpt = db << Report;
dist = rpt["Compare Distributions"][String Col Box( "Distribution" )] << Get;
Title_1 = rpt[Outline Box( "Fitted" || dist[1] || "?" )] << get title;
Print( Title_1 );

[#6]

이게 제가 찾고 있는 것에 가까워지고 있다고 생각합니다. 제가 하려는 것은 사용자가 선택한 분포와 해당 매개변수를 얻는 것입니다. 스크립트를 아래와 같이 수정하려고 했지만 반드시 올바른 출력이 나오지는 않습니다. 제가 잘못한 부분을 지적해 주시겠습니까?

추가로, 이로 인해 몇 가지 다른 의심이 제기되었습니다.

- << 선택된 인덱스를 행렬 메시지로 가져오면 결과가 역순으로 반환되는 이유는 무엇입니까?

Names Default To Here( 1 );

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

db = dt << Distribution(
	Stack( 1 ),
	Continuous Distribution(
		Column( :height ),
		Horizontal Layout( 1 ),
		Vertical( 0 )
	)
);

db << fit all;

rpt = db << Report;

rpt["Compare Distributions"][CheckBoxBox( 1 )]<

Appreciate the help so far

[#7 · Accepted solution]

for 루프 내부의 개요 검색에서 일부 공백이 빠진 것 같습니다("Fitted" -> "Fitted " 뒤에 공백이 있어야 함).

인덱스에 관해서: 아마도 "원래" 순서대로 인덱스를 가져오는 것 같습니다.

아래는 XPath를 사용하여 체크박스 혼란을 피하려는 예입니다.

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

db = dt << Distribution(Stack(1), Continuous Distribution(Column(:height), Horizontal Layout(1), Vertical(0)));
db << fit all;
rpt = db << Report;

rpt["Compare Distributions"][CheckBoxBox(1)] << set(3, 1); //make additional random selection
Wait(0);

tb = rpt[Outline Box("Compare Distributions"), Table Box(1)];
items = tb[1] << XPath("//CheckBoxBoxItem");
selections = {};
For Each({item, idx}, items,
	If(Contains(item, "\[isChecked="true"]\"),
		Insert Into(selections, idx);
	);
);

dists = (tb[2] << Get)[selections];

For Each({distname}, dists,
	ob = rpt[Outline Box("Fitted " || distname || " ?")];
	show(ob << get title);
);

[#8]

@jthi 감사합니다! 잘 됩니다!

그런데, 제 학습을 위해 'ischecked = "true"' 구문을 사용하지 않았을 겁니다. 스크립팅 인덱스나 디스플레이박스 속성 자체에서 이걸 찾지 못했거든요. 이걸 어떻게 유도했는지 공유해 주시겠어요? 제가 나중에 참고할 수 있도록 이 프로세스를 배우면 좋을 것 같아요.

[#9 · Accepted solution]

나는 원하는 것을 얻는 데 사용할 수 있는 흥미로운 것이 있는지 확인하기 위해 Table Box 참조에서 << XML 가져오기를 사용했습니다.