Shading graph area in multiple graphs simultaneously

[#1]

Hi All,

In my work, we split the subject into multiple splits and check the variation of certain parameters in each split.

Let's say we have 100 parameters which are being measured and 8 splits are there. Through JMP analysis, we get 100 graphs (for 100 parameters) with split on the x-axis.

Now i want to shade a certain split in each graph. I checked various options but couldn't do them simultaneously.

Is there any way this operation can be performed?

Thanks

[#2]

I am not sure if this is what you were talking about, Here is my guess as to what you want.  

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

dt << New Column( "Split", character, set each value( Char( Mod( :wafer, 5 ) + 1 ) ) );

colNames = dt << get column names( continuous );

vc = Variability Chart( Y( Eval( colNames ) ), X( :split ), Std Dev Chart( 0 ) );

For( k = 1, k <= N Items( colNames ), k++,
	mymax = Report( vc[k] )[axisbox( 1 )] << get max;
	mymin = Report( vc[k] )[axisbox( 1 )] << get min;
	Eval(
		Substitute(
				Expr(
					Report( vc[k] )[framebox( 1 )] << add graphics script(
						Transparency( .5 );
						Fill Color( "yellow" );
						Rect( 2, __Max__, 3, __Min__, fill = 1 );
					)
				),
			Expr( __max__ ), mymax,
			Expr( __min__ ), mymin
		)
	);
);