Move Local Data Filter below Column Switcher

[#1]

Hello,

I have a control chart with a Local Data Filter AND a Column Switcher. If I leave it as it is, it takes up too much space horizontally on the screen, so I'd like to move the Local Data Filter below the Column Switcher to optimise space.

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Quality Control/Coating.jmp" );

Control Chart Builder(
	Variables( Subgroup( :Sample ), Y( :Weight ) ),
	Show Control Panel( 0 ),
	Local Data Filter,
	Column Switcher( :Weight, {:Weight, :Weight 2} )
);

The problem is that I can't, I've tried moving the objects but if I move the filter or the switcher, they lose their properties.

report = Current Report();
report[Outline Box( "Column Switcher")] << append( report[Outline Box( "Local Data Filter")]  );
report[Outline Box( 2 )] << delete;

Have you ever been able to do something similar?

[#2 · Accepted solution]

You could separate them from the control chart builder. Below is one option

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Quality Control/Coating.jmp");


nw = New Window("Report",
	Data Filter Context Box(
		H List Box(
			vlb = V List Box(
				Data Filter Source Box(
					f = dt << Data Filter(
						local
					)
				),
				Spacer Box(Size(0, 20)),
			),
			ccb = dt << Control Chart Builder(
				Variables(Subgroup(:Sample), Y(:Weight)),
				Show Control Panel(0)
			)
		)
	)
);

vlb << append(cw = dt << Column Switcher(:Weight, {:Weight, :Weight 2}));
cw << Link Platform(ccb);

[#3]

Thank you this is perfect !