How to "click" combo box item using JSL

[#1]

Dear community,

I am trying to select an item in a combo box and "click" it using jsl. I know how this works for a "Button Box", but it seems that another approach is needed. Here is the example:

I want to be able to select an item in the combo box AND execute the combo box script by pressing the button. The text box just shows the combo box selection. Now, running the below script will change the combo box selection, but it does not run the script. This is evedint because the text box does not change its number.

New Window( "Example",
	V List Box(
		CB = Combo Box(
			{"Select", "1", "2"}, 
					TB << Set Text( CB << Get Selected() )
		),
		TB = Text Box( "Select" ),
		BB = Button Box("Set Combo Box to 1",
			CB << set(2)
		)
	)
)

[#2]

Seems like that should work but it doesn't.  You can accomplish that by putting the combo box select actions into an expression, and then executing them in both places:

cb_expr = expr(TB << Set Text( CB << Get Selected()));

New Window( "Example",
	V List Box(
		CB = Combo Box(
			{"Select", "1", "2"}, 
					cb_expr;
		),
		TB = Text Box( "Select" ),
		BB = Button Box("Set Combo Box to 1",
			CB << set(2);
			cb_expr;
		)
	)
);

[#3 · Accepted solution]

use the run script(1) command on the set. 

Names Default to here(1);
New Window( "Example",
	V List Box(
		CB = Combo Box(
			{"Select", "1", "2"}, 
					TB << Set Text( CB << Get Selected() )
		),
		TB = Text Box( "Select" ),
		BB = Button Box("Set Combo Box to 1",
			CB << set(2, runscript(1))
		)
	)
)

[#4]

Very simple, thank you.