How do I pre-append a text box to a web report?

[#1]

Hello,  

I would like to add a text box at the top of the report that describes the contents of the report on the web page. 

I want to insert the text description where the red arrow is ---> is on the screen shot.   Sorry, just can't seem to find the appropriate JSL to accomplish this.   Running JMP 15.2.1 Thanks, Rich

dt1 = Open( "C:\Public\gsod\gis_873950_detail_t.csv" , invisible );
Current Data Table( dt1 );
SidebySide = Fit Group(
Bivariate(
Y( :Average Temperature ),
X( :Year ),
Fit Mean( {Line Color( {212, 73, 88} )} ),
Fit Line( {Line Color( {61, 174, 70} )} ),
SendToReport(
Dispatch( {}, "Bivariate Plot Average Temperature by Year", FrameBox, {Frame Size( 370, 240 )} )
)
),
Oneway( Y( :Average Temperature ), X( :co_2 ), Means( 1 ), Mean Diamonds( 1 ) ),
<<{Arrange in Rows( 2 )}
);

report( SidebySide )[Outline Box(1)] << set title("USAF: 873950 COMODORO PIERRESTEGUI, AR 31.3 S 58.0 W");
report( SidebySide )[Outline Box(2)] << set title("Bivariate Fit of Average Temperature By Year" );
report( SidebySide )[Outline Box(9)] << set title("Oneway Analysis of Average Temperature By co_2" );
ReportSidebySide = SidebySide << report;
ReportSidebySide << Save Interactive HTML ( "C:\Public\gsodReports\COMODORO_PIERRESTEGUI_AR_873950.t_mean.WIP.htm" );
close( dt1 , "nosave" );

[#2]

You have to insert text box before the first outline box. One thing you could try, is to build the report into a new window (or you could use for example Sib << Prepend, but I would build the report with New Window)

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");

nw = New Window("HTML WINDOW NAME",
	V List Box(
		Text Box("Text here"),
		biv = dt << Bivariate(Y(:Height), X(:Weight));
	);
);
Report(biv)[OutlineBox(1)] << Set Title("New title");

nw << Save Interactive HTML("$TEMP/deleteme1.html");
open("$TEMP");
nw << close window(1);

stop();
biv = dt << Bivariate(Y(:Height), X(:Weight));
ob_ref = Report(biv)[OutlineBox(1)];
ob_ref << Set Title("New title");
ob_ref << Sib Prepend(Text Box("TEXT HERE"));
(biv << top parent) << Save Interactive HTML("$TEMP/deleteme2.html");

[#3]

Here is a quick example on Big Class:

Open("$SAMPLE_DATA\Big Class.jmp");
SidebySide = Fit Group(
	biv  = Bivariate(
		Y( :weight ),
		X( :height ),
		Fit Mean( {Line Color( {212, 73, 88} )} ),
		Fit Line( {Line Color( {61, 174, 70} )} ),
		By( :sex )
	),
	Oneway( Y( :height ), X( :sex ), Mean Diamonds( 1 ) ),
	<<{Arrange in Rows( 2 )}
);

Report(SidebySide)[OutlineBox(1)] << prepend(Text box("Your text description"));