How can I hide/remove the "Legacy Control Charts are being removed in JMP 19" warning messages?

[#1]

Our application is executing JMP scripts via the COM automation objects to create control charts for product stability monitoring.  At a later date, we will look to update the scripts to use Control Chart Builder.  For now, we need to use the existing control charts.  After upgrading from JMP 14 to JMP 18, the control charts now show large red warning banners, as shown below.  Is there a setting change we can make, script command we can execute, etc., to hide these red banners?  Any help would be appreciated.  Thanks!

[#2 · Accepted solution]

You might be able to disable these from preferences but I'm not sure from where. You can script it with something like this

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Quality Control/Coating.jmp");
obj = dt << Control Chart(
	Sample Size(:Sample),
	KSigma(3),
	Chart Col(:Weight),
	Chart Type(XBar)
);

tbs = Report(obj) << XPath("//TextBox[contains(text(), 'Legacy Control Charts are being removed in JMP 19. Please use Control Chart Builder from the Quality and Process menu instead.')]");

tbs << Visibility("Collapse");

or do it manually from report's properties

[#3]

Wonderful, that worked!  Thank you very much!  This is what I added to my script, where the "ccr" variable is the control chart report object:

tbs = ccr << XPath("//TextBox[contains(text(), 'Legacy Control Charts are being removed in JMP 19.')]");
tbs << Visibility("Collapse");

I am not experienced with JMP scripting; I am inheriting the application from a previous developer.  I want the code to work with all versions of JMP.  So for users that are on an older version where this text box would not be found, how should I tweak the code?  In other words, what is the JMP way to write a null check (pseudo-code below)?

tbs = ccr << XPath("//TextBox[contains(text(), 'Legacy Control Charts are being removed in JMP 19.')]");

if (tbs != null)
   tbs << Visibility("Collapse");

[#4 · Accepted solution]

You can either check for JMP version

If(Word(1, JMP Version(), ".") == "18",
	tbs = ccr << XPath("//TextBox[contains(text(), 'Legacy Control Charts are being removed in JMP 19.')]");
	tbs << Visibility("Collapse");
);

or you can check if the text boxes are found using N Items

tbs = ccr << XPath("//TextBox[contains(text(), 'Legacy Control Charts are being removed in JMP 19.')]");

If(N Items(tbs) > 0,
	tbs << Visibility("Collapse");
);

And if you happen to have this left in JMP19 you most likely will run into error before that (but who knows how it will be handled, in "worst" case you can still script it even in JMP19 even though it is totally gone from menus).

[#5]

Thank you!  I like option 2 best, so I have implemented that.  I will test it Monday with a user who I know still has JMP 14 installed.  Have a great weekend!