cancel
Showing results for 
Show  only  | Search instead for 
Did you mean: 
JMP is taking Discovery online, April 16 and 18. Register today and join us for interactive sessions featuring popular presentation topics, networking, and discussions with the experts.
Choose Language Hide Translation Bar
Gabriela_MJ
Level I

Actual by predicted plot of specific model

Hello,

 

I have a column (type formula) which corresponds to the model of another column (response).

I would like to know if it is possible to graph the actual by predicted plot considering as "actual" the response column and the column which contains the formula as the "predicted". 

I only see these graph when the model is defined by jmp.

 

Thanks in advance.

1 ACCEPTED SOLUTION

Accepted Solutions

Re: Actual by predicted plot of specific model

This could be done with column formulas but it would get messy. This script should do the trick:

dlg = Column Dialog(
	Title( "Evaluate Model" ),
	yCol = Col List( "Response",
		Data Type( Numeric ),
		Min Col( 1 ),
		Max Col( 1 )
	),
	mCol = Col List( "Model",
		Data Type( Numeric ),
		Min Col( 1 ),
		Max Col( 1 )
	)
);
If( dlg["Button"] == -1,
	Throw( "User cancelled" );
);
Remove From( dlg );
Eval List( dlg );
dt = Current Data Table();
response = yCol[1] << Get As Matrix;
model = mCol[1] << Get As Matrix;
residual = model - response;
sst = Sum( (response - Mean( response ) )^2 );
sse = Sum( residual^2 );
ssm = sst - sse;
r square = ssm / sst;
dt << New Column( "Residual", Values( residual ) );
New Window( "Evaluate Model",
	dt << Graph Builder(
		Variables( X( mCol[1] ), Y( yCol[1] ) ),
		Elements( Points( X, Y, Legend( 3 ) ) ),
		Show Control Panel( 0 )
	),
	dt << Graph Builder(
		Variables( X( :Residual ), Y( yCol[1] ) ),
		Elements( Points( X, Y, Legend( 3 ) ) ),
		Show Control Panel( 0 )
	),
	Text Box( "R square is " || Char( r square ) )
);

View solution in original post

4 REPLIES 4

Re: Actual by predicted plot of specific model

I think the solution might be simple.

  1. Select Graph > Graph Builder.
  2. Select the observed response and drag it to the Y drop zone.
  3. Select the model column and drag it to the X drop zone.

Let me know if I over-simplified your request.

Gabriela_MJ
Level I

Re: Actual by predicted plot of specific model

Hello,

 

Thank's for your answer. I think I did not explain very well my objective. 

What I want to do, it is to evaluate my model. I would like to define the RSquare value of the model (if it is possible) and obtain the residual by predicted plot. Something like the jmp report for the fit least squares but considering the model that I defined as a formula.

 

Kind regards

Re: Actual by predicted plot of specific model

This could be done with column formulas but it would get messy. This script should do the trick:

dlg = Column Dialog(
	Title( "Evaluate Model" ),
	yCol = Col List( "Response",
		Data Type( Numeric ),
		Min Col( 1 ),
		Max Col( 1 )
	),
	mCol = Col List( "Model",
		Data Type( Numeric ),
		Min Col( 1 ),
		Max Col( 1 )
	)
);
If( dlg["Button"] == -1,
	Throw( "User cancelled" );
);
Remove From( dlg );
Eval List( dlg );
dt = Current Data Table();
response = yCol[1] << Get As Matrix;
model = mCol[1] << Get As Matrix;
residual = model - response;
sst = Sum( (response - Mean( response ) )^2 );
sse = Sum( residual^2 );
ssm = sst - sse;
r square = ssm / sst;
dt << New Column( "Residual", Values( residual ) );
New Window( "Evaluate Model",
	dt << Graph Builder(
		Variables( X( mCol[1] ), Y( yCol[1] ) ),
		Elements( Points( X, Y, Legend( 3 ) ) ),
		Show Control Panel( 0 )
	),
	dt << Graph Builder(
		Variables( X( :Residual ), Y( yCol[1] ) ),
		Elements( Points( X, Y, Legend( 3 ) ) ),
		Show Control Panel( 0 )
	),
	Text Box( "R square is " || Char( r square ) )
);

Re: Actual by predicted plot of specific model

You could try Fit Y by X. Put the real data in X, the model data in Y. Fit a line (red triangle). The slope is the RSquared and you can examine the residuals using the other plots.

Best,

M