Can I arrange data filters in two columns?

[#1]

I am trying to create a dashboard that has 5 data filters (see image below). Four of the filters fit in one column. The fifth filter is a long list of bird species with a scroll bar. It's easiest to cover this whole list when I include this filter in its own column, like in the image below (which is just a mock-up, not something I've been able to achieve yet. I tried creating these as two separate filters, and saved the data filter scripts to my data table. However, JMP only allows me to open one data filter at a time, so I haven't been able to open them both up to arrange them next to each other, as below. I tried putting all 5 filters in one column, hoping that I would be able to drag the long species filter over to create a second column, but this didn't work. It seems like this should work somehow. Is there a setting that allows me to open two filters at the same time? Is there a way to arrange filters for different fields into two columns, like my mock-up? Thank in advance for any ideas on this. 

[#2 · Accepted solution]

Hi @caseylott,

You can do this with nested data filter context boxes, here you can see three different local data filters, including the one inside the graph builder platform. Note that you can have multiple charts which would use both of the outer local data filters, and that you can have any number of nested filters.

Names default to here(1);

dt = Open("$Sample_data/big class.jmp");

New Window("Nested Data Filters",
	Data Filter Context Box(  //Left Data filter context box
		H List Box(
			dt << Data Filter( Local, Add Filter( columns( :height ) ) ),
			Data Filter Context Box( //Second-from-left context box
				H List Box(
					dt << Data Filter( Local, Add Filter( columns( :age ), Display( :age, N Items( 6 ) ) ) ),
					//could add a v list box here and put a second graph which also uses the outer local data fitlers.
					dt << Graph Builder(
						Size( 528, 456 ),
						Show Control Panel( 0 ),
						Variables( X( :weight ), Y( :height ) ),
						Elements( Points( X, Y, Legend( 5 ) ), Smoother( X, Y, Legend( 6 ) ) ),
						//included a local data filter in the platform
						Local Data Filter( Add Filter( columns( :sex ), Display( :sex, N Items( 2 ) ) ) ) 
					)
				)
			)
		)
	)
);

[#3]

Thank you @ih 

This will work great for me. Even though I've been using JMP for years, I'm a real beginner with .jsl. Clearly, it's time I start learning! Am I correct that there is no simple way to achieve the same result by dragging and dropping, right clicking, or using any other part of the data filter dialog? 

Casey

[#4]

Right, as far as I know there is no way to do this in the dialog.