Can I use Local Data Filter on a Fit Group containing Graph Builder windows (w/o the Graph Builder getting obliterated)?

[#1]

I'm having an issue combining Graph Builder and Local Data Filter within Fit Group. As soon as the Local Data Filter is applied to the Fit Group, all of the Graph Builder objects immediately disappear.

(Note, other platforms like Bivariate and Oneway are not affected by this and those windows remain after applying the Local Data Filter, only the Graph Builder windows disappear.)

Here is a sample script to demonstrate the problem: this script should generate three plots, two Graph Builder plots and one Oneway plot. But, due to the Local Data Filter, the Graph Builder plots get obliterated, and all you see is the Oneway plot. If you delete the Local Data Filter from the script, you will see all three plots.

BigClass = open("C:\Program Files\SAS\JMPPRO\16\Samples\Data\Big Class.jmp");

BigClass << Fit Group(
Graph Builder(
	Size( 534, 456 ),
	Show Control Panel( 0 ),
	Variables( X( :height ), Y( :weight ) ),
	Elements(
		Points( X, Y, Legend( 3 ) ),
		Line Of Fit( X, Y, Legend( 5 ), Confidence of Fit( 0 ) )
	)
),
Graph Builder(
	Size( 534, 450 ),
	Show Control Panel( 0 ),
	Variables( X( :age ), Y( :weight ) ),
	Elements( Line( X, Y, Legend( 6 ) ), Points( X, Y, Legend( 7 ) ) )
),
Oneway(
	Y( :height ),
	X( :age ),
	Means and Std Dev( 1 ),
	Plot Actual by Quantile( 1 ),
	Line of Fit( 0 ),
	Box Plots( 1 ),
	Mean Lines( 1 ),
	Mean Error Bars( 1 ),
	Std Dev Lines( 1 ),
	Connect Means( 1 ),
	X Axis Proportional( 0 ),
	Points Jittered( 1 ),
	Grand Mean( 0 )
),
<<Local Data Filter( Add Filter( columns( :sex ), Where( :sex == "F" ) ) );
)

Another way to reproduce the problem: run the above script after deleting the Local Data Filter, and you will see three plots. Then, on the Fit Group window with those three plots, click the GUI button to add Local Data Filter, and the Graph Builder plots immediately disappear.

I have tested this on JMP14 Pro and JMP16 Pro, both show the same issue.

[#2]

Your script works as given in JMP 17.  Is the group data filter the main reason for wanting to use the Fit Group in this case?  One way that you could do this interactively in JMP is to build a dashboard from the 3 platforms.  In JSL you could build something similar to what the dashboard would produce (works in JMP 14-17):

BigClass = open("$SAMPLE_DATA\Big Class.jmp");
New Window("Report",
	DataFilterContextBox(
		HListBox(
			BigClass<<Data Filter(Local, Add Filter( columns( :sex ), Where( :sex == "F" ) ) );

			VListBox(
				BigClass << Graph Builder(
					Size( 534, 456 ),
					Show Control Panel( 0 ),
					Variables( X( :height ), Y( :weight ) ),
					Elements(
						Points( X, Y, Legend( 3 ) ),
						Line Of Fit( X, Y, Legend( 5 ), Confidence of Fit( 0 ) )
					)
				),
				BigClass << Graph Builder(
					Size( 534, 450 ),
					Show Control Panel( 0 ),
					Variables( X( :age ), Y( :weight ) ),
					Elements( Line( X, Y, Legend( 6 ) ), Points( X, Y, Legend( 7 ) ) )
				),
				BigClass << Oneway(
					Y( :height ),
					X( :age ),
					Means and Std Dev( 1 ),
					Plot Actual by Quantile( 1 ),
					Line of Fit( 0 ),
					Box Plots( 1 ),
					Mean Lines( 1 ),
					Mean Error Bars( 1 ),
					Std Dev Lines( 1 ),
					Connect Means( 1 ),
					X Axis Proportional( 0 ),
					Points Jittered( 1 ),
					Grand Mean( 0 )
				)
			)
		)
	)
);