How to loop images to append and save in ppt slides with different outline box title?

[#1]

Hi all

I have created a function for variability plots with different parameters. My question is, can I append the images and save them as PowerPoint slides with their respective names in the outline box? I am currently doing this individually and is running this on JMP 15

[#2]

Here is a simple example using JMP 15 syntax

Names Default To Here( 1 );

dt = 
// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

// Get a list of all of the parameter columns
colList = dt << get column names( continuous, string );

// Use only the first 10 columns for this example
Remove From( colList, 11, Length( colList ) - 10 );

// Create a Journal to be used for the creation of the .ppt
jr = New Window( "The Journal", <<journal, vlb = V List Box() );

// Loop across the columns and create the Variability Charts and 
// place them into the journal with new names
For( i = 1, i <= Length( colList ), i++,
	vc = Variability Chart( invisible,
		Y( Column( colList[i] ) ),
		X( :wafer ),
		Model( "Main Effect" ),
		Std Dev Chart( 0 )
	);
	Report( vc )[Outline Box( 2 )] << set title( colList[i] );
	vlb << append( Report( vc )[Outline Box( 2 )] );
	vc << close window;
);

// Save the journal to a PowerPoint
jr << Save Presentation( "$TEMP/jmp_example.pptx" );

// Close the Journal
jr << close window;

// Open the PowerPoint document
Open( "$TEMP/jmp_example.pptx" );