How to add Kurtosis and Skewness to Tabulate

[#1]

Hello,

I would like to add "Kurtosis" and "Skewness" to my row table. How do I do that?

dt = Current Data Table();
tab = dt << Tabulate(
    Show Control Panel( 0 ),
    Add Table(
        Column Table( Analysis Columns( :VAR1, :VAR2, :VAR3, ) ),
        Row Table( Statistics( Mean, Std Dev, Min, Max, Range, CV, Median ) )
    )
);
Wait( 0.1 );
dtTab = tab << makeIntoDataTable;
Write( "Make a new data table from the Tabulate Platform", "\!N" );

[#2 · Accepted solution]

I think you cannot get kurtosis and skewness through tabulate but they can be found from Distribution platform.

1. Create Distribution with only distributions with the variables you are interested in
2. Hold CTRL (this will make the options affect all of the distributions) and click red triangle in one of the distributions of the variables
3. Go to Display Options / Customize Summary Statistics -> select statistics you are interested in
4. Right click on one of the summary statistics tables in Distribution platform and choose Make Combined Data Table
5. Split result data table if needed

Example script with Semiconductor Capability sample data (scripts copy pasted almost directly from JMP):

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

platform = dt <<
Distribution(
	Continuous Distribution(
		Column(:NPN1),
		Summary Statistics(1),
		Customize Summary Statistics(
			Std Err Mean(0),
			Upper Mean Confidence Interval(0),
			Lower Mean Confidence Interval(0),
			N(0),
			Skewness(1),
			Kurtosis(1),
			CV(1),
			Minimum(1),
			Maximum(1),
			Median(1)
		),
		Process Capability(0)
	),
	Continuous Distribution(
		Column(:PNP1),
		Summary Statistics(1),
		Customize Summary Statistics(
			Std Err Mean(0),
			Upper Mean Confidence Interval(0),
			Lower Mean Confidence Interval(0),
			N(0),
			Skewness(1),
			Kurtosis(1),
			CV(1),
			Minimum(1),
			Maximum(1),
			Median(1)
		),
		Process Capability(0)
	),
	Continuous Distribution(
		Column(:PNP2),
		Summary Statistics(1),
		Customize Summary Statistics(
			Std Err Mean(0),
			Upper Mean Confidence Interval(0),
			Lower Mean Confidence Interval(0),
			N(0),
			Skewness(1),
			Kurtosis(1),
			CV(1),
			Minimum(1),
			Maximum(1),
			Median(1)
		),
		Process Capability(0)
	),
	Histograms Only
);
Wait(0);
dt_statistics = Report(platform)[Outline Box("Distributions")][Outline Box("NPN1")][
Outline Box("Summary Statistics")][Table Box(1)] << Make Combined Data Table;
Report(platform) << Close Window;
Close(dt, no save);
dt_split = dt_statistics << Split(
	Split By(:Column 1),
	Split(:Column 2),
	Group(:Y),
	Sort by Column Property
);
Close(dt_statistics, no save);

[#3]

That's really a pretty good question, maybe reframing it another way..

Rather than combining statistics, using complex scripting, wouldn't it be easier if Tabulate included more, or maybe all the univariate statistics included in the distribution platform?

..Yes, yes it would. 

I'm staff, so I can't do this, but you could add this to the Wish List (its in blue menu bar at the top of the window.)