Delete a text box and a button from a lineup box

[#1]

I'm trying to delete both the button itself and the associated text box before it. So when I cilck button nr 3 I want text nr 3 to also be deleted. Any ideas?

nr=5;
new window("Button test",
	Lineuplist=Lineup Box( N Col( 2 ),
		
	)
);
For(i=1,i<=nr,i++,
	Lineuplist << append(textbox("Text nr "||char(i)));
	Lineuplist << append(
		buttonbox("Button nr "||char(i),
			<< Set Function(
				Function({this},
					this << delete;
				)
			)
		);
	);
);

[#2]

@pauldeen

nr=5;
new window("Button test",
	Lineuplist=Lineup Box( N Col( 2 ))
	      ); 
);
For(i=1,i<=nr,i++,
	Lineuplist << append(textbox("Text nr "||char(i)));
	Lineuplist << append(
		buttonbox("Button nr "||char(i),
			<< Set Function(
				Function({this},
					this << delete;
				)
			)
		);
	);
	Lineuplist[Text Box(i)] << delete ; // this is the piece of code which will do what you are after . Insert it where you delete the button 
);

[#3 · Accepted solution]

Here is a piece of code that works:

nr=5;
new window("Button test",
	Lineuplist=Lineup Box( N Col( 2 ),
		
	)
);
For(i=1,i<=nr,i++,
	Lineuplist << append(textbox("Text nr "||char(i)));
	Lineuplist << append(
		buttonbox("Button nr "||char(i),
			<< Set Function(
				Function({this},
					ps=this<<sib;
					par=this<<parent;
					buttonName=this<<get button name;
					buttonNo=regex(buttonName,".*?([0-9]*)$","\1");
					locator=eval insert("//TextBox[text()='Text nr ^buttonNo^']");
					textBox=par<<xpath(locator);
					textBox<<delete;
					this<<delete;
				)
			)
		);
	);
);

[#4]

Thanks!