JSL을 활용한 보고서 작성 자동화

[#1]

JMP를 활용한 분석 결과를 보고, 공유하는 방법은 여러가지가 있습니다.

본 포스팅에서는 JSL을 활용하여, 보고서 첫장(표지)을 만들고, 그 다음 페이지 부터 분석결과를 pdf 파일로 저장하는 JSL 코드에 대해 간략히 설명합니다.

보고서 자동화를 위해 알면 좋은 JSL 명령어와 활용가능한 JSL 코드를 공유합니다.

아래의 JSL 코드는 첨부된 pdf 형식의 report를 생성하기 위한 Script입니다.

Open( "$sample_data/big class.jmp" );

nw = New Window( "Reports",
	<<Journal,
	spacer box(size(0,300)),
	hlb = V List Box((
		lub = Lineup Box( N Col( 1 ), 
			tb1 = Text Box( "Data Analysis Report Using JMP®" ),
			spacer box(size(0,20)),
			tb2 = Text Box( "Team Name" ),
			spacer box(size(0,20)),
			tb3 = Text Box(As Date( Today() )),			
		)
	),
	spacer box(size(0,300)),
	Page Break Box(), // start new page
	Data Table( "Big Class" ) <<
	  Distribution(
	Continuous Distribution( Column( :weight ) ),
	Nominal Distribution( Column( :age ) )),
	Page Break Box(), // start new page
	Data Table( "Big Class" ) <<
	  Logistic( Y( :age ), X( :weight ) )
));

tb1 << Set Font Size( 26 ) << Set Font Style( "Bold" ) <<
Justify Text( "center" ) << setWrap( 800 ) << SetWidth( 1000 );

tb2 << Set Font Size( 20 ) << Set Font Style( "Bold" ) <<
Justify Text( "center" ) << setWrap( 800 ) << SetWidth( 1000 );

tb3 << Set Font Size( 16 ) << Set Font Style( "Bold" ) <<
Justify Text( "center" ) << setWrap( 800 ) << SetWidth( 1000 );


Reports = Current Journal();
Reports << Set page setup(
	margins( 0.5, 0.5, 0.5, 0.5 ),
	scale( 0.65 ),
	portrait( 1 ),
	paper size( "A4" )
);

nw << SavePDF("$DESKTOP\Sample report.pdf");

위 Script는 JMP Sample Data Table인 Big Class.jmp를 이용하여, 아래와 같은 보고서 Cover를 만들고, 2페이지부터 분석결과(Distribution과 Logistic 분석)를 함께 Reporting할 수 있도록 만들어져 있습니다.

마지막 부분은 바탕화면에 Sample Report라는 이름의 pdf 파일을 생성하게 해주는 Script입니다.

중간 중간에 있는 보고서 용지 설정, 여백, 글자 크기 등을 입맛에 맞게 변경하셔서 사용하시면 됩니다. 물론 Cover에 들어가는 내용도 원하시는 내용으로 변경가능합니다.

 

Final Script for Automation.jsl