topic Re: Reporting of data from LSMeans Differences Student's t in Discussions

Reporting of data from LSMeans Differences Student's t

Juli — Mon, 18 Nov 2024 12:13:36 GMT

Hi all,

I am trying to make a report with specific data from the table of LSMeans Differences Student's t:

I would like a table with one of the formats as below:

Sadly, I cannot get it to print correctly for the mean and it cannot take data from the bigger table. I get the below

I have tried the following code, where I have altered the '17' to numbers from 1-30 and nothing works - 17 is for a different outline box:

sd = Open( "test_table.jmp" );

Fitmod = Fit Model(
Y( :"Test value"n ),
Effects( :Person ),
Random Effects( :Day[:Person] ),
NoBounds( 0 ),
Personality( "Standard Least Squares" ),
Method( "REML" ),
Emphasis( "Effect Leverage" ),
Run(
:"Test value"n << {Summary of Fit( 1 ),
Analysis of Variance( 0 ), Parameter Estimates( 1 ), Scaled Estimates( 0 ),
Plot Actual by Predicted( 1 ), Plot Regression( 0 ),
Plot Residual by Predicted( 1 ), Plot Studentized Residuals( 0 ),
Plot Effect Leverage( 1 ), Plot Residual by Normal Quantiles( 0 ),
{:Person << {LSMeans Student's t( 0.05 )}}}
),
Where( :ID == "A1" ),
SendToReport(
Dispatch(
{"Test value ID=A1"},
"Whole Model",
OutlineBox,
{Close( 1 )}
),
Dispatch(
{"Test value ID=A1", "Person"},
"Leverage Plot",
OutlineBox,
{Close( 1 )}
)
)
);

report(Fitmod) [Outline Box( 2 )] << Close( 0 );
reportFitmod = Fitmod << Report;

sumfit = reportFitmod[Outline Box( 17 )][Number Col Box( 1 )] << Get as Matrix; 

meandiff = sumfit[1];
lowerCL = sumfit[3];
upperCL = sumfit[4];

term = reportFitmod[Outline Box( 13 )][String Col Box( 1 )] << Get();

est = reportFitmod[Outline Box( 13 )][Number Col Box( 1 )] << Get as Matrix;

dvalues = [];
dvalues = meandiff |/ lowerCL |/ upperCL ;
sfactor = term[2];

dlg = New Window( "Custom Report",
Outline Box( "Selected Values",
Lineup Box( N Col( 2 ),
Text Box( "Factor of Interest: " ),
Text Box( sfactor ), ),
tb = Table Box(

String Col Box( " ",
{"Mean difference: ", "Upper limit: ", "Lower limit: "}
),
Spacer Box( Size( 30, 30 ) ),
,
Spacer Box( Size( 0, 30 ) ),
,
Table Box(
CloneTerm,
Spacer Box( Size( 10, 0 ) ),
,
Number Col Box( "Estimate", est ),
Spacer Box( Size( 10, 0 ) ),
,
Number Col Box( "Mean difference", meandiff)
)
)
);

tb << Set Shade Headings( 0 ); // Turn off shaded table headings.
tb << Set Heading Column Borders( 0 ); // Turn off table column borders.

How do you report the data from the bigger table?

Best regards

Re: Reporting of data from LSMeans Differences Student's t

txnelson — Mon, 18 Nov 2024 11:52:01 GMT

Welcome to the JMP Community.

I think there is a mix up between the data table you attached and the script you attached. The references in the script to the columns to be analyzed do not match the columns in the attached data table.

If you can provide the correct attachments I am sure the Community will be able to assist you in your efforts.

Re: Reporting of data from LSMeans Differences Student's t

Juli — Mon, 18 Nov 2024 12:14:54 GMT

Dear Jim,

I apologize for the mix-up. Thank you for letting me know. I have attached the correct script now.

Julie

Re: Reporting of data from LSMeans Differences Student's t

txnelson — Mon, 18 Nov 2024 14:36:17 GMT

This may give you a leg up on getting your final product. It produces

Names Default To Here( 1 );
sd = //Open( "test_table.jmp" );
Data Table( "test_table" );
Fitmod = Fit Model(
	Y( :"Test value"n ),
	Effects( :Person ),
	Random Effects( :Day[:Person] ),
	NoBounds( 0 ),
	Personality( "Standard Least Squares" ),
	Method( "REML" ),
	Emphasis( "Effect Leverage" ),
	Run(
		:"Test value"n << {Summary of Fit( 1 ), Analysis of Variance( 0 ), Parameter Estimates( 1 ), Scaled Estimates( 0 ),
		Plot Actual by Predicted( 1 ), Plot Regression( 0 ), Plot Residual by Predicted( 1 ), Plot Studentized Residuals( 0 ),
		Plot Effect Leverage( 1 ), Plot Residual by Normal Quantiles( 0 ), {:Person << {LSMeans Student's t( 0.05 )}}}
	),
	Where( :ID == "A1" ),
	SendToReport(
		Dispatch( {"Test value ID=A1"}, "Whole Model", OutlineBox, {Close( 1 )} ),
		Dispatch( {"Test value ID=A1", "Person"}, "Leverage Plot", OutlineBox, {Close( 1 )} )
	)
);
Report( Fitmod )[Outline Box( 2 )] << Close( 0 );
reportFitmod = Fitmod << Report;
sumfit = reportFitmod[Outline Box( "Least Squares Means Table" )][Number Col Box( 1 )] << Get as Matrix; 
// Get data from CrossTab table
crossTab = reportFitmod[Outline Box( "LSMeans Differences Student's t" )][CrosstabBox( 1 )] << get as matrix;
// Get Where clause variable
whereCol = Word( 2, ((reportFitmod << parent)[Text Box( 1 )]) << get text, ":=)" );
whereVal = {};
Eval( Parse( "insert into(whereVal," || Word( 2, ((reportFitmod << parent)[Text Box( 1 )]) << get text, "=)" ) || ");" ) );
meandiff = Round( Abs( crossTab[1, 2] ), 4 );
lowerCL = Round( Abs( crossTab[3, 2] ), 3 );
upperCL = Round( Abs( crossTab[4, 2] ), 3 );
term = reportFitmod[Outline Box( "Least Squares Means Table" )][String Col Box( 1 )] << Get();
est = reportFitmod[Outline Box( "Least Squares Means Table" )][Number Col Box( 1 )] << Get as Matrix;
testValue = {};
Insert Into( testValue, (Substr( reportFitmod[Outline Box( 1 )] << get title, 10 )) );
dif = {};
Insert Into( dif, Char( meandiff ) || " [" || Char( lowerCL ) || ";" || Char( upperCL ) || "]" );

dlg = New Window( "Custom Report",
	Outline Box( "Selected Values",
		Lineup Box( N Col( 2 ), Text Box( "Factor of Interest: " ), Text Box( sfactor ) ),
		Spacer Box( size( 0, 10 ) ),
		tb = Table Box(
			String Col Box( "Test Value", testvalue ),
			String Col Box( whereCol, whereVal ),
			Number Col Box( "Mean, " || term[1], sumfit[1] ),
			Number Col Box( "Mean, " || term[2], sumfit[2] ),
			String Col Box( "Difference in mean and CI", dif )
			
		)
	)

);
tb << Set Shade Headings( 0 ); // Turn off shaded table headings.
tb << Set Column Borders( 1 ); // Turn off table column borders.
tb << Set row Borders( 1 );
tb << border( 1 );

Re: Reporting of data from LSMeans Differences Student's t

Juli — Wed, 20 Nov 2024 08:07:16 GMT

Hi Jim,

How should the script be altered if there are multiple IDs to generate a table with all the different elements? Can a loop be implemented for this?

Best regards,

Julie

Re: Reporting of data from LSMeans Differences Student's t

txnelson — Wed, 20 Nov 2024 11:26:54 GMT

I have modified the JSL to be able to handle multiple levels of ID.

Names Default To Here( 1 );
sd = //Open( "test_table.jmp" );
Data Table( "test_table " );
Fitmod = Fit Model(
	Y( :"Test value"n ),
	Effects( :Person ),
	Random Effects( :Day[:Person] ),
	NoBounds( 0 ),
	Personality( "Standard Least Squares" ),
	Method( "REML" ),
	Emphasis( "Effect Leverage" ),
	Run(
		:"Test value"n << {Summary of Fit( 1 ), Analysis of Variance( 0 ), Parameter Estimates( 1 ),
		Scaled Estimates( 0 ), Plot Actual by Predicted( 1 ), Plot Regression( 0 ),
		Plot Residual by Predicted( 1 ), Plot Studentized Residuals( 0 ), Plot Effect Leverage( 1 ),
		Plot Residual by Normal Quantiles( 0 ), {:Person << {LSMeans Student's t( 0.05 )}}}
	),
	by( :ID ),
	SendToReport(
		Dispatch( {"Test value ID=A1"}, "Whole Model", OutlineBox, {Close( 1 )} ),
		Dispatch( {"Test value ID=A1", "Person"}, "Leverage Plot", OutlineBox, {Close( 1 )} )
	)
);

// Set the lists for the storage of the data from the by groups
whereVal = testValue = dif = sumfit1 = sumfit2 = {};

// Loop across each by group and gather the data
For Each( {rpt, group}, Fitmod, 
	// Point to the current report
	reportFitmod = Fitmod[group] << Report;
	
	// Get the means for the 2 levels
	sumfit = reportFitmod[Outline Box( "Least Squares Means Table" )][Number Col Box( 1 )] << Get as Matrix;
	Insert Into( sumfit1, sumfit[1] );
	Insert Into( sumfit2, sumfit[2] );
	term = reportFitmod[Outline Box( "Least Squares Means Table" )][String Col Box( 1 )] << Get();
	
	// Get By Group column
	whereCol = Word( 1, (reportFitmod[Outline Box( 1 )] << get title), "=)" );
	Insert Into( whereVal, Word( 2, (reportFitmod[Outline Box( 1 )] << get title), "=)" ) );
		
	// Get data from CrossTab table
	crossTab = reportFitmod[Outline Box( "LSMeans Differences Student's t" )][CrosstabBox( 1 )] <<
	get as matrix;
	meandiff = Round( Abs( crossTab[1, 2] ), 4 );
	lowerCL = Round( Abs( crossTab[3, 2] ), 3 );
	upperCL = Round( Abs( crossTab[4, 2] ), 3 );
	
	// Get the Response variable name
	Insert Into( testValue, (Substr( (reportFitmod << topparent)[Outline Box( 1 )] << get title, 10 )) );

	// Create the Differeence in mean and CL string
	Insert Into( dif, Char( meandiff ) || " [" || Char( lowerCL ) || ";" || Char( upperCL ) || "]" );
);

// Create the table
dlg = New Window( "Custom Report",
	Outline Box( "Selected Values",
		Lineup Box( N Col( 2 ), Text Box( "Factor of Interest: " ), Text Box( term[1] ) ),
		Spacer Box( size( 0, 10 ) ),
		tb = Table Box(
			String Col Box( "Test Value", testvalue ),
			String Col Box( whereCol, whereVal ),
			Number Col Box( "Mean, " || term[1], sumfit1 ),
			Number Col Box( "Mean, " || term[2], sumfit2 ),
			String Col Box( "Difference in mean and CI", dif )
			
		)
	)

);
tb << Set Shade Headings( 0 ); // Turn off shaded table headings.
tb << Set Column Borders( 1 ); // Turn off table column borders.
tb << Set row Borders( 1 );
tb << border( 1 );

Your job now is to study the script, and learn what it does. The script works for the sample data table and Fit Model you specified. However, different data tables with different columns and different Fit Model executions may not work with the JSL that generates the report output. You will need to become knowledgeable enough to modify the script to meet your needs.

Good references for this is the Scripting Guide and the Scripting Index, available under the Help pull down menu in JMP.

Of course, the JMP Discussion Community will be there to assist you with your learning of the script.

Re: Reporting of data from LSMeans Differences Student's t

Juli — Wed, 04 Dec 2024 16:08:44 GMT

Thank you for your impressive work!

I have tried to run the script, but I get an error. I have tried to browse through old cases and google for both the function For Each and the error as well as trying to modify the script but to no avail. I have version 16, could this pose an issue to the script?

My belief is the error stems from {rpt, group} as I have tried to remove all in the For Each and I still get this error.

Most of it I can understand, but where do we get this rpt from and how is it used? It is only mentioned in the For Each( {rpt, group} ...) so I cannot rationalise how it fits.

Re: Reporting of data from LSMeans Differences Student's t

txnelson — Wed, 04 Dec 2024 16:37:44 GMT

What version of JMP are you using? For Each() was added to JMP in version 16. The By() functionality in Fit Mod was not added until JMP 18.

The script will need to be modified to handle both of these changes.

Re: Reporting of data from LSMeans Differences Student's t

Juli — Thu, 12 Dec 2024 13:48:27 GMT

I use JMP version 16.1.0, so that must be the reason.

Does the FitMod function need to be replaced by another function or can FitMod still be used just differently?

Re: Reporting of data from LSMeans Differences Student's t

txnelson — Thu, 12 Dec 2024 15:04:26 GMT

Here is a modified version of the script. I have tested it in JMP 16. I removed the By clause and replaced the functionality with a For Each() loop that runs the Fit Model for each level of ID separately. The script then gathers the output from each of the separate Fit Model outputs and generates the final output display

Names Default To Here( 1 );
sd = //Open( "test_table.jmp" );
Data Table( "test_table" );
Fitmod = {};

// Determine the levels in the ID column
summarize( sd, ByGroups = By( :ID ) );

// Loop across each levle of ID 
For Each( {BG, group}, ByGroups,
	Fm = Fit Model(
		Y( :"Test value"n ),
		Effects( :Person ),
		Random Effects( :Day[:Person] ),
		NoBounds( 0 ),
		Personality( "Standard Least Squares" ),
		Method( "REML" ),
		Emphasis( "Effect Leverage" ),
		Run(
			:"Test value"n << {Summary of Fit( 1 ), Analysis of Variance( 0 ),
			Parameter Estimates( 1 ), Scaled Estimates( 0 ), Plot Actual by Predicted( 1 ),
			Plot Regression( 0 ), Plot Residual by Predicted( 1 ),
			Plot Studentized Residuals( 0 ), Plot Effect Leverage( 1 ),
			Plot Residual by Normal Quantiles( 0 ), {:Person << {LSMeans Student's t( 0.05 )}}}
		),
		Where( :ID == ByGroups[group] ),
		SendToReport(
			Dispatch( {"Test value ID=A1"}, "Whole Model", OutlineBox, {Close( 1 )} ),
			Dispatch(
				{"Test value ID=A1", "Person"},
				"Leverage Plot",
				OutlineBox,
				{Close( 1 )}
			)
		)
	);

// Save the pointer to the results in the Fitmod list
	Insert Into( Fitmod, Fm );
);

// Set the lists for the storage of the data from the by groups
testValue = dif = sumfit1 = sumfit2 = {};

// Loop across each by group and gather the data
For Each( {rpt, group}, Fitmod, 
	// Point to the current report
	reportFitmod = Fitmod[group] << Report;
	
	// Get the means for the 2 levels
	sumfit = reportFitmod[Outline Box( "Least Squares Means Table" )][Number Col Box( 1 )] << Get as Matrix;
	Insert Into( sumfit1, sumfit[1] );
	Insert Into( sumfit2, sumfit[2] );
	term = reportFitmod[Outline Box( "Least Squares Means Table" )][String Col Box( 1 )] << Get();
	
	// Get By Group column
	whereCol = Word( 2, ((reportFitmod << parent)[Text Box( 1 )]) << get text, ":=)" );
		
	// Get data from CrossTab table
	crossTab = reportFitmod[Outline Box( "LSMeans Differences Student's t" )][CrosstabBox( 1 )] <<
	get as matrix;
	meandiff = Round( Abs( crossTab[1, 2] ), 4 );
	lowerCL = Round( Abs( crossTab[3, 2] ), 3 );
	upperCL = Round( Abs( crossTab[4, 2] ), 3 );
	
	// Get the Response variable name
	Insert Into( testValue, (Substr( (reportFitmod << topparent)[Outline Box( 1 )] << get title, 10 )) );

	// Create the Differeence in mean and CL string
	Insert Into( dif, Char( meandiff ) || " [" || Char( lowerCL ) || ";" || Char( upperCL ) || "]" );
);

// Create the table
dlg = New Window( "Custom Report",
	Outline Box( "Selected Values",
		Lineup Box( N Col( 2 ), Text Box( "Factor of Interest: " ), Text Box( term[1] ) ),
		Spacer Box( size( 0, 10 ) ),
		tb = Table Box(
			String Col Box( "Test Value", testvalue ),
			String Col Box( whereCol, ByGroups ),
			Number Col Box( "Mean, " || term[1], sumfit1 ),
			Number Col Box( "Mean, " || term[2], sumfit2 ),
			String Col Box( "Difference in mean and CI", dif )
			
		)
	)

);
tb << Set Shade Headings( 0 ); // Turn off shaded table headings.
tb << Set Column Borders( 1 ); // Turn off table column borders.
tb << Set row Borders( 1 );
tb << border( 1 );

Re: Reporting of data from LSMeans Differences Student's t

Juli — Mon, 30 Dec 2024 14:47:30 GMT

Hi Jim,

Thank you so much!

Best regards,

Julie

Re: Reporting of data from LSMeans Differences Student's t

Juli — Wed, 08 Jan 2025 09:54:25 GMT

Hi Jim,

I have an additional question. If I want to run the analysis with many test values, would I be able to either:

1. Make a loop with FitModel and then continue as in the script above?

2. Do the analysis separately where I get the report in one report, and then run a script which saves the data like the script above?

Or is there another way that I should try to look into?

Best regards,

Julie

Re: Reporting of data from LSMeans Differences Student's t

txnelson — Wed, 08 Jan 2025 11:04:49 GMT

Julie,

Either approach would probably work.

Making this decision seems to me to be an awfully big decision to make at the beginning. I would first come up with what you want the final product to look like, and then take the script, and modify it to give you that result on just 2 test values. That will give you both a little more information on what the approach should be, and also expose what areas in JSL that you need to learn more about, in order to expand the script to your final product.

Re: Reporting of data from LSMeans Differences Student's t

Juli — Wed, 08 Jan 2025 13:06:00 GMT

Hi Jim,

Great to know that both approaches are possible to do in JSL.

Would it be possible to alter the code to also have Y( :"Test value"n ) to go through all the continuous columns?

// Determine the levels in the ID column
summarize( sd, ByGroups = By( :ID ) );

// Loop across each level of ID 
For Each( {BG, group}, ByGroups,
	Fm = Fit Model(
		Y( :"Test value"n ),
		Effects( :Person ),
		Random Effects( :Day[:Person] ),
		NoBounds( 0 ),
		Personality( "Standard Least Squares" ),
		Method( "REML" ),
		Emphasis( "Effect Leverage" ),
		Run(
			:"Test value"n << {Summary of Fit( 1 ), Analysis of Variance( 0 ),
			Parameter Estimates( 1 ), Scaled Estimates( 0 ), Plot Actual by Predicted( 1 ),
			Plot Regression( 0 ), Plot Residual by Predicted( 1 ),
			Plot Studentized Residuals( 0 ), Plot Effect Leverage( 1 ),
			Plot Residual by Normal Quantiles( 0 ), {:Person << {LSMeans Student's t( 0.05 )}}}
		),
		Where( :ID == ByGroups[group] ),
		SendToReport(
			Dispatch( {"Test value ID=A1"}, "Whole Model", OutlineBox, {Close( 1 )} ),
			Dispatch(
				{"Test value ID=A1", "Person"},
				"Leverage Plot",
				OutlineBox,
				{Close( 1 )}
			)
		)
	);

// Save the pointer to the results in the Fitmod list
	Insert Into( Fitmod, Fm );
);

I have looked at many other loops and tried to alter it to the following:

Names Default To Here( 1 );
sd = Open( "test_table_002.jmp" );
Data Table( "test_table_002" );
Fitmod = {};

// Determine the levels in the ID column
summarize( sd, ByGroups = By( :ID ) );
colList = sd << Get Column Names( Continuous, String );

// Loop across each level of ID 
For Each( i = 1, i <= Nitems( colList ), i++,
	For Each( {BG, group}, ByGroups,
		Fm = Fit Model(
			Y( colList ),
			Effects( :Person ),
			Random Effects( :Day[:Person] ),
			NoBounds( 0 ),
			Personality( "Standard Least Squares" ),
			Method( "REML" ),
			Emphasis( "Effect Leverage" ),
			Run(
				colList << {Summary of Fit( 1 ), Analysis of Variance( 0 ),
				Parameter Estimates( 1 ), Scaled Estimates( 0 ), Plot Actual by Predicted( 1 ),
				Plot Regression( 0 ), Plot Residual by Predicted( 1 ),
				Plot Studentized Residuals( 0 ), Plot Effect Leverage( 1 ),
				Plot Residual by Normal Quantiles( 0 ), {:Person << {LSMeans Student's t( 0.05 )}}}
			),
			Where( :ID == ByGroups[group] ),
			SendToReport(
				Dispatch( {"Test value ID=A1"}, "Whole Model", OutlineBox, {Close( 1 )} ),
				Dispatch(
					{"Test value ID=A1", "Person"},
					"Leverage Plot",
					OutlineBox,
					{Close( 1 )}
				)
			)
		);

	// Save the pointer to the results in the Fitmod list
		Insert Into( Fitmod, Fm );
	);
);

However, I get an error code that I do not fully understand.

I have attached a test table and I double checked that I attached the correct one.

Best regards,

Julie

Re: Reporting of data from LSMeans Differences Student's t

txnelson — Wed, 08 Jan 2025 14:58:11 GMT

What is the error message?

Re: Reporting of data from LSMeans Differences Student's t

Juli — Thu, 09 Jan 2025 06:50:34 GMT

Here is the error message:

I only have 43 lines in the script for now

Re: Reporting of data from LSMeans Differences Student's t

txnelson — Thu, 09 Jan 2025 11:38:23 GMT

You script modification is very close to working. In Line 11 you are specifying

For Each( i = 1, i <= Nitems( colList ), i++,

It should be

For( i = 1, i <= Nitems( colList ), i++,

There is a big difference between the function For Each() and For(). Definition and Examples of the 2 different functions can be found in the Scripting Index.

You will also need to change your references to

colList

in lines 15 and 23 to specify which of the items in colList you are referencing.

Since you are using the variable "i" as your looking index value, you will need to specify

colList[i]

In the sample data table you provided, you only have the column Test Value as your numeric(continous) columns, so you will only loop once with your For() function. However, if you add more numeric(continuous) columns you code with the modifications to the syntax I have mentioned will run for each of the numeric(continuous) column

Re: Reporting of data from LSMeans Differences Student's t

Juli — Thu, 09 Jan 2025 14:10:58 GMT

Thank you. That makes a lot of sense!

One final question, if I want to alter the text in the Dispatch that is sent to the report - how would this be done?

It is currently "Test value ID=A1" and what is printed is fx Test value 1 or Test value 2. When I tried to change to "Test value ID=colList", the same was printed so I do not understand how it works.

I would like it to print the following text for fx test value 1 with ID A1: "Test value 1, ID=A1". I have tried with different strings and functions but either I get an error or it just prints the same as previously.

Best regards,

Julie

Re: Reporting of data from LSMeans Differences Student's t

txnelson — Thu, 09 Jan 2025 20:41:59 GMT

I am not understanding what you are saying. I will approach it from a different direction. Here is the output from your data table for column Test Value 1

what do you want to change from this output?

Re: Reporting of data from LSMeans Differences Student's t

Juli — Fri, 10 Jan 2025 08:32:02 GMT

Dear Jim,

I have written it to the picture where I want it changed and to what:

If it does not specify the ID, then I do not know how to differentiate between the different windows that pop up when there are multiple IDs.

I hope this makes more sense :)

Best regards,

Julie