topic Re: Graph Builder. Combine Smoother and Line - how? in Discussions

Graph Builder. Combine Smoother and Line - how?

hogi — Mon, 22 Dec 2025 20:53:55 GMT

I have groups of measurement that I want to plot "together".

The individual measurement curves of a group should have the same color and be semi-transparent.
For each group there should be an additional smoother curve with the same color.

Is this possible in Jmp? - without "workarounds"?

version 1:

measurements of one groups have same color
one curve per measurement
transparency works
1 smoother line instead of 3
the smoother curve doesn't have the "right" color [consequential error]

version 2:

measurements of one groups have same color
nasty jumps back for the individual curves
transparency works
each group has it's own smoother curve
smoother curves have the wrong color

dt =Open( "$SAMPLE_DATA/Functional Data/Weekly Weather Data.jmp" );
dt << New Column( "group",Character,"Nominal",Formula( Substr( :STATION, 8, 1 ) ));

//version 1
dt << Graph Builder(
	Variables(
		X( :DATE ),
		Y( :TAVG ),
		Overlay( :STATION ),
		Color( :group )
	),
	Elements(
		Line( X, Y, Legend( 31 ) ),
		Smoother( X, Y, Overlay( 0 ), Legend( 32 ) )
	),
	SendToReport(
		Dispatch(
			{},
			"400",
			ScaleBox,
			{Legend Model(
				31,
				Properties( 0, {Transparency( 0.2 )}, Item ID( "2", 1 ) ),
				Properties( 1, {Transparency( 0.2 )}, Item ID( "3", 1 ) ),
				Properties( 2, {Transparency( 0.2 )}, Item ID( "4", 1 ) )
			)}
		)
	)
	
);


//version 2
dt << Graph Builder(
	Variables( X( :DATE ), Y( :TAVG ), Overlay( :group ), Color( :group ) ),
	Elements(
		Line( X, Y, Legend( 31 ), Row order( 1 ) ),
		Smoother( X, Y, Legend( 32 ) )
	),
	SendToReport(
		Dispatch(
			{},
			"400",
			ScaleBox,
			{Legend Model(
				31,
				Properties( 0, {Transparency( 0.2 )}, Item ID( "2", 1 ) ),
				Properties( 1, {Transparency( 0.2 )}, Item ID( "3", 1 ) ),
				Properties( 2, {Transparency( 0.2 )}, Item ID( "4", 1 ) )
			)}
		)
	)
)

Re: Graph Builder. Combine Smoother and Line - how?

jthi — Fri, 14 Jul 2023 09:19:05 GMT

Try removing group from color for smoother and to remove zigzag disable Row order

Re: Graph Builder. Combine Smoother and Line - how?

hogi — Sun, 01 Sep 2024 12:09:15 GMT

Ah, the Color = "Group" is just too much. It can be removed completely.

concerning Zig-Zag:
I want to have separate curves per station, this is why I enabled row order.

Disabling the option leads to one combined curve for all stations of a group.

version 2 (b):

measurements of one group have same color
~~nasty jumps back for the individual curves (fixed by removing row order)~~
unfortunately not anymore: one curve per station
transparency works
each group has it's own smoother curve
smoother curves with matching color

Re: Graph Builder. Combine Smoother and Line - how?

hogi — Sun, 01 Sep 2024 16:58:05 GMT

I hope somebody finds a way to get this graph created in Jmp (17) - without adding new rows and columns to the graph.

will solve the problem. If Overlay accepts more than one column, the user can select different Overlays for the two plot types:

Overlay for the smoother element:
:group-> one fit curve per group
Overlay for the line element:
:Station -> separate traces per station = no zig-zag lines

Besides enhancing the Overlay functionality , here is another wish which uses a simple trick to add the breaks:
The idea: a measurement trace runs from left to right.
Each step from right to left marks the start of a new trace -> add a break.

Re: Graph Builder. Combine Smoother and Line - how?

hogi — Sun, 01 Sep 2024 17:12:06 GMT

Till or becomes available,

you can use this workaround:

add dummy rows with missing x / y value and select no connection for missing values.

version 3:

same group = same color
no nasty zig-zag curves
transparency works
each group has it's own smoother curve
smoother curves with matching color
new rows added to the data table

dt =Open( "$SAMPLE_DATA/Functional Data/Weekly Weather Data.jmp" );
dt << New Column( "group",Character,"Nominal",Formula( Substr( :STATION, 8, 1 ) ));

//version 3
stations = dt << Summary(Group( :STATION, :NAME ));
For EACH({station}, stations[0,0], dt << add row({:STATION=station[1],:NAME=station[2]})); 
dt << sort( BY(:NAME, :DATE ), Replace Table);

dt << Graph Builder(
	Variables( X( :DATE ), Y( :TAVG ), Overlay( :group ) ),
	Elements(
		Line( X, Y, Legend( 1 ), Row order( 1 ), Missing Values( "No Connection" ) ),
		Smoother( X, Y, Legend( 2 ) )
	),
	SendToReport(
		Dispatch(
			{},
			"400",
			ScaleBox,
			{Legend Model(
				1,
				Properties( 0, {Transparency( 0.3 )}, Item ID( "2", 1 ) ),
				Properties( 1, {Transparency( 0.3 )}, Item ID( "3", 1 ) ),
				Properties( 2, {Transparency( 0.3 )}, Item ID( "4", 1 ) )
			), Legend Model(
				2,
				Base( 0, 0, 0, Item ID( "2", 1 ) ),
				Base( 1, 0, 0, Item ID( "3", 1 ) ),
				Base( 2, 0, 0, Item ID( "4", 1 ) )
			)}
		)
	)
)

#1000

Re: Graph Builder. Combine Smoother and Line - how?

hogi — Mon, 19 Feb 2024 18:43:08 GMT

@XanGregg , will Overlay Encoding facilitate the creation of such plots (different color and individual fit curves for different variants - but more than one measurement curve per variant).

Re: Graph Builder. Combine Smoother and Line - how?

hogi — Sun, 01 Sep 2024 17:34:27 GMT

And Configure Levels?
no: again the zig-zag lines.

dt =Open( "$SAMPLE_DATA/Functional Data/Weekly Weather Data.jmp" );
Graph Builder(
	Transform Column(
		"STATION'",
		Character,
		Set Property( "Configure Levels", 1 ),
		Formula(
			Map Value(
				:STATION,
				{"USW00092811", "USW00012924", "USW00014922", "USW00014751",
				"USW00024024", "USW00014751", "USW00024144", "USW00014751",
				"USW00094626", "USW00014751", "USW00003868", "USW00003195",
				"USW00003949", "USW00003195", "USW00013733", "USW00003195",
				"USW00013877", "USW00003195", "USW00053182", "USW00003195",
				"USW00093067", "USW00003195", "USW00093242", "USW00003195",
				"USW00093718", "USW00003195"},
				Unmatched( :STATION )
			)
		)
	),
	Variables( X( :DATE ), Y( :TAVG ), Overlay( :STATION' ) ),
	Elements(
		Line( X, Y, Legend( 1 ), Row order( 1 ), Missing Values( "No Connection" ) ),
		Smoother( X, Y, Legend( 2 ) )
	)
)

Re: Graph Builder. Combine Smoother and Line - how?

hogi — Mon, 22 Dec 2025 16:49:08 GMT

~~If you generate such plots regularly, please have a look at .~~
~~There is a Shortcut Icon to create the dummy rows automatically and to sort the table to put the dummy rows in the right position.~~

The feature was removed from QuickSelect Toolbar.
A similar feature in now available via the GraphBuilder Toolbar

Re: Graph Builder. Combine Smoother and Line - how?

hogi — Mon, 16 Sep 2024 13:25:42 GMT

We are just beta testing a "remote control" AddIn for Graph Builder which will facilitate the manual formatting of the plots.
I added a button to remove the zig-zag lines : )

compared to "add dummy rows" it has the benefit that it doesn't collided with

(view in My Videos)

Re: Graph Builder. Combine Smoother and Line - how?

hogi — Tue, 26 Nov 2024 16:23:22 GMT

a formalism like "curve ID column" in Fit curve to split the data into individual curves - but still to bundle similar curves based on another column.

Fit Curve has this feature - Graph Builder could benefit from the feature as well.

Re: Graph Builder. Combine Smoother and Line - how?

hogi — Wed, 07 Jan 2026 09:59:41 GMT

A nice improvement in JMP19 is the Type Properties() feature, which allows us to apply transparency much easier:

same group = same color
transparency via Type Properties - no need to set it manually for every curve.
each group has it's own smoother curve (overlay encoding = auto or color)
smoother curves with matching color
just the zig-zag lines need some extra effort *)

*) and this topic may be addressed in a future version of JMP:
https://community.jmp.com/t5/JMP-Wish-List/Graph-Builder-Line-possibility-to-add-breaks/idc-p/921029/highlight/true#M8150
cool!

Graph Builder(
	Variables(
		X( :DATE ),
		Y( :TAVG ),
		Overlay( :group, Overlay Encoding( "Color" ) )
	),
	Elements(Smoother( X, Y, Legend( 2 ) ),  Line( X, Y, Legend( 1 ), Ordering( "Row Order" ) ) ),
	SendToReport(
		Dispatch( {}, "400", ScaleBox,
			{Legend Model(
				1,
				Type Properties( 0, "H Line", {Transparency( 0.2 )} )
			)}
		)
	)
);

Re: Graph Builder. Combine Smoother and Line - how?

hogi — Tue, 17 Feb 2026 17:38:48 GMT

cool, JMP20 will bring a very easy solution for the issue with the zig-zag lines : Yes, stay Tuned!

dt =Open( "$SAMPLE_DATA/Functional Data/Weekly Weather Data.jmp" );
dt << New Column( "group",Character,"Nominal",Formula( Substr( :STATION, 8, 1 ) ));

Graph Builder(
	Variables( X( :DATE ), Y( :TAVG ), Overlay( :group ) ),
	Elements( Line( X, Y,  Ordering( "Row Ascending" ) ), Smoother( X, Y ) )
);

Re: Graph Builder. Combine Smoother and Line - how?

hogi — Tue, 17 Feb 2026 17:43:45 GMT

It feels like a game changer for specific types of plots, such as grouped I-V curves.
@isabelleswaenep