topic Re: Replace Head() ? in Discussions

Replace Head() ?

hogi — Fri, 03 Jan 2025 21:44:59 GMT

In the Scripting breakout room of Discovery Summit 2024 we just discussed if there is a JSL function to replace the head of an expression.

Something like

Replace Head(myExpression, Expr(original head()), Expr(new head()));

edit: ~~Expr(original head())~~

... to convert

original head(args)

into

new head(args)

In this context, one might think of Substitute. Besides replacing strings

Substitute ("hello", "h", "J", "l", "f", "o", "")

one can use Substitute also to replace Expressions, like in

Substitute({1+2},Expr(add()),Expr(subtract()))

It gets close, but it is far from optimal, e.g.

Substitute({1,2,{3,4}}, Expr(List()),Expr(Show()));

will return Show( 1, 2, Show( 3, 4 ) )

: (

A possible solution: convert the expression to a string and use Regex, then convert back.
this hurts when you know the magic of Expression handling : )

The best solution up to now - via expression handling:
Instead of replacing the head, extract all the arguments and insert them into the new head.

var = {1,2,{3,4}};
MyExpr = Expr(Show());

for(i=1, i<=NArg(var), i++,
	InsertInto(MyExpr, Arg(var, i))
);
NameExpr(MyExpr);

Re: Replace Head() ?

jthi — Thu, 19 Sep 2024 11:20:54 GMT

If you don't have lists it is a bit easier to replace just the head. With lists it gets more complicated and I would go with option of just rebuilding the expression.

I was writing wish list request inspired by Python's str.replace when I came across this item . Substituting just the first occurrence has already been suggested and it would cover the most "needed" occurrence counts (1 and all).

Re: Replace Head() ?

hogi — Tue, 24 Sep 2024 05:17:15 GMT

Ok, thanks.

convertToList=
		Function( {myExpr},{myList,i},
			myList = {};
			For( i = 1, i <= N Arg( Name Expr( myExpr ) ), i++,
				Insert Into( myList, Arg( Name Expr( myExpr ), i ) )
			);
			Return( Name Expr( myList ) );
		),

edit:
[I just found "i" in my HERE namespace - didn't expect that:
I use for each most of the time.
--> "i" added as local variable of the function

edit2:
don't use this code !!! can lead to wrong results:
-> use @jthi 's solution below!

convertToList = Function( {myExpr},
	{tmp},
	tmp = Name Expr( myExpr );
	Remove From( tmp, 1, N Arg( tmp ) );
)

Re: Replace Head() ?

jthi — Sun, 22 Sep 2024 12:14:05 GMT

There all sorts of options (good, bad, easy to understand, difficult to understand and everything in between and mixed).

These will modify the original expressions, so copies of the expressions (myexpr1_copy = Name Expr(myexpr1); for example) should be used if that is not desired

Names Default To Here(1);

// Replace outmost Max with Min
myexpr1 = Expr(Max(1, Max(1,2)));
args = Remove From(myexpr1, 1, N Arg(myexpr1));
myexpr_new = Substitute(args, Head(List()), Expr(Min()));
Show(myexpr_new);


// Change outmost List into Max
myexpr2 = {1, {1,2}};
var = Head(myexpr);
Substitute Into(var, Expr(List()), Expr(Show()));
While(N Items(arg = Remove From(myexpr2, 1)), Insert Into(var, arg[1]));
show(var);


// "Change" outmost Max into list
myexpr3 = Expr(Max(1, Max(1,2)));
mylist = Remove From(myexpr3, 1, N Arg(myexpr3));
Show(mylist);

Re: Replace Head() ?

hogi — Sun, 22 Sep 2024 12:44:03 GMT

wow, this is very clever!
look into the recycle bin of Remove From()

cool!

Re: Replace Head() ?

hogi — Fri, 03 Jan 2025 20:34:11 GMT

I just found another solution - it's based on the superpowers of For Each : )

myexpr1 = Expr(Max(1, Max(1,2)));
myexpr_new = Expr (min());
For each({arg},Name Expr(myExpr1),
	Insert Into(myexpr_new, Name Expr(arg))
);
show(myexpr_new )

Re: Replace Head() ?

hogi — Fri, 03 Jan 2025 22:42:39 GMT

I am happy to announce - a quite universal Replace Head():

Add Custom Functions(
	New Custom Function(
		"hogi",
		"replace head",
		Function( {orig, new Head},
			{Default Local},
			mydummy = Expr( dummy() );
			For Each( {arg}, Name Expr( orig ), Insert Into( mydummy, arg ) );
	
			x = Substitute( Name Expr( mydummy ), Expr( dummy() ), Name Expr( new Head ) );
			//Eval(Substitute(Expr(Print(Expr(_x_))), Expr(_x_), Name Expr(x)));
			Eval(Substitute(Expr(return(Expr(Expr(_x_)))), Expr(_x_), Name Expr(x))); // *)
		),
		<< description("takes the first argument and replaces its head with the second argument"),
		<< example(Expr(
			hogi:replace head({1,2,{3,4}}, Expr(Show()));
			
			orig = Expr(Max(1,2,3));
			hogi:replace head(Name Expr(orig), Expr(Show()));			
		))
	)
);

added to

*) like in
https://community.jmp.com/t5/JMP-Wish-List/Substitute-First-Occurrence/idc-p/825822/highlight/true#M6863
but + 1x Expr() - due to the custom function ?!?

Re: Replace Head() ?

hogi — Sat, 18 Jan 2025 09:39:36 GMT

@jthi just mentioned Transfrom Each + Output

https://community.jmp.com/t5/Discussions/Slicing-Associative-Arrays/m-p/828081/highlight/true#M100979

There is an option to replace the head:

which works like this:

ex = Transform Each( {value},{10, 20, 30}, Output( "Expression", "My Values" ),	value + 1);

and it also works for expressions : )

myexpr = Expr(Max(1, Max(1,2)));

Transform Each({entry},Name Expr(myExpr), Output( "Expression", "List"),Name Expr(entry))

Re: Replace Head() ?

hogi — Sat, 18 Jan 2025 09:45:53 GMT

This reduces the function to:

Add Custom Functions(
	New Custom Function(
		"hogi",
		"replace head",
		Function( {orig, new Head},
			{Default Local},
			Transform Each( {arg}, Name Expr( orig ),  Output("Expression", new Head), Name expr(arg ) );
		),
		<< description("takes the first argument and replaces its head with the second argument - secnd argument: String!!"),
		<< example(Expr(
			hogi:replace head({1,2,{3,4}}, "Show");
			
			orig = myexpr = Expr(Max(1, Max(1,2)));
			hogi:replace head(Name Expr(orig), "List");			
		))
	)
);

Please note that the new Head has to be provided as String, not as an expression !