topic Re: How to save the benchmarks window to the data table ? in Discussions

How to save the benchmarks window to the data table ?

PercentileBat71 — Mon, 12 Aug 2024 15:23:50 GMT

Hi !

Thanks to this script I generate à window of BenchMarks on jmp and I would like to save it to the data table ( like if I was doing "save script to data table") The problem is that the end of my script doesn't work !!

// Ouvrir la table de données
dt = Open(fichier1);

// Initialiser une liste pour stocker les noms des colonnes avec la note "INGOT CHARACTERISTICS"
cols_with_note = {};

// Parcourir chaque colonne de la table par index
For(i = 1, i <= N Cols(dt), i++,
	col = Column(dt, i);
// Vérifier si la colonne a une note "INGOT CHARACTERISTICS"
	If(col << Get Property("Notes") == "INGOT CHARACTERISTICS", 
// Ajouter le nom de la colonne à la liste
		Insert Into(cols_with_note, col << Get Name)
	);
);

Print(
	"Colonnes avec notes trouvées pour la famille " || "INGOT CHARACTERISTICS" || " : " ||
	Char(cols_with_note) || "\n"
);

// Créer une nouvelle fenêtre pour regrouper tous les graphiques
report_window = New Window("BenchMarks_Ingot_Characteristics",
	V List Box(
		Fit Group(
			For(i = 1, i <= N Items(cols_with_note), i++,
				col_name = cols_with_note[i];
// Ajouter le graphique Oneway au Fit Group
				Oneway(
					Y(Column(dt, col_name)),
					X(Column(dt, selection)),
					Quantiles(1),
					Means and Std Dev(1),
					Box Plots(1),
					Mean Error Bars(1),
					Std Dev Lines(1),
					X Axis Proportional(0),
					Grand Mean(0),
					SendToReport(
						Dispatch({}, "Oneway Plot", FrameBox,
							{DispatchSeg(
								Box Plot Seg(1),
								{Confidence Diamond(0), Shortest Half Bracket(0),
								Line Color("Red")}
							)}
						)
					)
				);
			)
		)
	)
);
// Enregistrer la fenêtre dans le fichier de données
report_window << Save Script to Data Table(
	dt, // Spécifie la table de données
	"BenchMarks_Ingot_Characteristics", // Nom de la fenêtre pour enregistrer

);

Edit 2024-08-12 jthi, Added JSL formatting

Re: How to save the benchmarks window to the data table ?

jthi — Mon, 12 Aug 2024 15:31:47 GMT

When you post JSL code to JMP Community, please utilize JSL formatting. You can add it with
.

On your question, which JMP version are you using?

Re: How to save the benchmarks window to the data table ?

jthi — Mon, 12 Aug 2024 16:22:13 GMT

Here are two options which might work for you. Option 2 is usually easier to use but the script it creates is more difficult to modify in the table

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Semiconductor Capability.jmp");

sel = "SITE";

cols = Left(dt << Get Column Names("Continuous", "String"), 10);


// Option1
ow_expr = EvalExpr(dt << Oneway(
	Y(Eval(Expr(cols))),
	X(Eval(Expr(sel))),
	Quantiles(1),
	Means and Std Dev(1),
	Box Plots(1),
	Mean Error Bars(1),
	Std Dev Lines(1),
	X Axis Proportional(0),
	Grand Mean(0),
	SendToReport(
		Dispatch({}, "Oneway Plot", FrameBox,
			{DispatchSeg(
				Box Plot Seg(1),
				{Confidence Diamond(0), Shortest Half Bracket(0),
				Line Color("Red")}
			)}
		)
	)
));

Eval(EvalExpr(
	dt << New Script("Plots", Expr(Name Expr(ow_expr)));
));
dt << Run Script("Plots"); // if you want to leave it open



// Option2
ows = dt << Oneway(
	Y(Eval(cols)),
	X(Eval(sel)),
	Quantiles(1),
	Means and Std Dev(1),
	Box Plots(1),
	Mean Error Bars(1),
	Std Dev Lines(1),
	X Axis Proportional(0),
	Grand Mean(0),
	SendToReport(
		Dispatch({}, "Oneway Plot", FrameBox,
			{DispatchSeg(
				Box Plot Seg(1),
				{Confidence Diamond(0), Shortest Half Bracket(0),
				Line Color("Red")}
			)}
		)
	)
);

ows[1] << Save Script for All Objects To Data Table("Plot2");

Re: How to save the benchmarks window to the data table ?

PercentileBat71 — Mon, 12 Aug 2024 17:11:21 GMT

I made a loop to have all my benchmarks in one Fit Group and I would like to save all this Fit Group in one window, the script you sent me did not works for me :(

Re: How to save the benchmarks window to the data table ?

jthi — Tue, 13 Aug 2024 16:02:40 GMT

What is wrong with the script I provided you with? You didn't tell me which JMP version you are using so that might not work for all JMP version (I have only access top JMP17 and JMP18).

Re: How to save the benchmarks window to the data table ?

PercentileBat71 — Tue, 13 Aug 2024 16:28:46 GMT

It didn’t register the benchmarks in my fichier1 don’t know why

Re: How to save the benchmarks window to the data table ?

PercentileBat71 — Tue, 13 Aug 2024 16:29:03 GMT

I use jmp 16

Re: How to save the benchmarks window to the data table ?

PercentileBat71 — Tue, 13 Aug 2024 16:34:15 GMT

Moreover the script you send me doesn’t incluse the loop

Re: How to save the benchmarks window to the data table ?

jthi — Tue, 13 Aug 2024 16:39:59 GMT

If loop isn't necessary (might be with JMP16) why would you use one? For with my previous scripts you get results like this (in JMP18)

Re: How to save the benchmarks window to the data table ?

txnelson — Tue, 13 Aug 2024 16:47:47 GMT

Jarmo,

I ran your script in JMP 16 and both options worked as expected, saving the scripts to the original data table.

Re: How to save the benchmarks window to the data table ?

PercentileBat71 — Tue, 13 Aug 2024 16:53:02 GMT

I don’t get how loop isn’t necessary when I need to generate benchmarks for each values of the list cols_with_note as Y

Re: How to save the benchmarks window to the data table ?

jthi — Tue, 13 Aug 2024 16:58:58 GMT

Some JMP platforms let you use multiple columns as inputs. After you have your list of columns, you might just be able to directly use it as an input in a platform. So you need one loop to collect columns (or some other method, I don't have your data so I cannot know) and second loop might be unnecessary depending on the final result you wish to have.

My example doesn't have any loops, because it is unnecessary for my example script to loop over any columns to create an example list. I can just pick some columns to demonstrate what you can do, especially as you seem to have already solved the column collection part.

Re: How to save the benchmarks window to the data table ?

PercentileBat71 — Tue, 13 Aug 2024 17:15:51 GMT

Okay I get it but I don't know why when I click on the button to lauch it it doesnt work ? So know it did save it but I can't launch the benchmarks from the green button

Re: How to save the benchmarks window to the data table ?

jthi — Tue, 13 Aug 2024 17:51:23 GMT

Right click on the script and select Edit

You can then view the script which is in the table, most likely there is something wrong with it. Sometimes it can be a bit difficult to get them saved correctly to data table.

Re: How to save the benchmarks window to the data table ?

PercentileBat71 — Tue, 13 Aug 2024 17:56:41 GMT

Ok ty very much, you really saved me !! I have another question, I'm making this for several study and sometimes the list cols (or cols_with_note) might be empty but the script you send me doesn't work if cols is empty (which is normal actually) I'm making this script to add them to a workflow form jump. Is there any way to say like "if cols is empty then stop the script and pass to the next one" ?

Re: How to save the benchmarks window to the data table ?

PercentileBat71 — Tue, 13 Aug 2024 18:03:11 GMT

or rather an if the list is not empty we generate the benchmarks and otherwise we do nothing

Re: How to save the benchmarks window to the data table ?

jthi — Tue, 13 Aug 2024 18:06:06 GMT

You can use if statement and N Items() to check if list has any items. And then either stop if it is empty or do something else

mylist = {};
If(N Items(mylist) == 0,
	stop();
);
show(1);

Re: How to save the benchmarks window to the data table ?

txnelson — Tue, 13 Aug 2024 18:15:14 GMT

I strongly suggest that you take the time to read the Scripting Guide available under the Help pull down menu.

Re: How to save the benchmarks window to the data table ?

PercentileBat71 — Tue, 13 Aug 2024 19:45:57 GMT

I have noticed that when my list contain only one column name or column that are empty the script say : send expects scriptable objects how to correct this ??