topic Re: How to make JMP home window invisible ? in Discussions

How to make JMP home window invisible ?

mati — Mon, 22 Jul 2024 04:19:05 GMT

Hi all,

I's using JMP 18 and I have a Python script that runs several tests, queries data from SQL, and saves the results with different names. I then execute JSL scripts for plotting the data. However, each time a JSL script runs, it opens the JMP Home window. If I run 10 tests simultaneously, it opens 10 JMP Home windows, which blocks my screen view. Although I'm making the data tables invisible, I still want to find a way to make the JMP Home window invisible as well. Is there any way to achieve this?

This is my sample code for one test.

// Load the selected CSV file
dt = Open("C:\Users\Documents\Workspace\Projects\BanffC\Experiments\sanity.csv", invisible);

// Create the Graph Builder
graph = dt << Graph Builder(
    Size( 1002, 693 ),
    Variables(
        X( :rf_frequency_hz ),
        Y( :evm_db ),
        Group X( :mcs ),
        Group Y( :board_id ),
        Overlay( :run_tag )
    ),
    Elements( Points( X, Y, Legend( 13 ) ), Line( X, Y, Legend( 15 ) ) ),
    Local Data Filter(
        Add Filter(
            columns( :bw_mhz ),
            Modeling Type( :bw_mhz, Nominal ),
            Where( :bw_mhz == 8 ),
            Display( :bw_mhz, N Items( 4 ) )
        )
    )
);

Re: How to make JMP home window invisible ?

mmarchandFSLR — Wed, 24 Jul 2024 17:07:44 GMT

Try adding this to your script:

Main Menu( "Hide", "JMP Home Window" )

Re: How to make JMP home window invisible ?

mati — Thu, 25 Jul 2024 04:00:09 GMT

It works if JMP is already open and you're running a script—the script will hide the home window. However, if you're running a .jsl script that opens JMP and creates plots, the home window remains active with each plot.

Re: How to make JMP home window invisible ?

mmarchandFSLR — Thu, 25 Jul 2024 12:06:48 GMT

Interestingly, this works:

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA\Big Class.jmp" );
Wait( 0 );
Main Menu( "Hide", "JMP Home Window" );
dst = dt << Run Script( "Distribution" );

But it leaves your data table visible. This gives you an invisible table but leaves the home window visible:

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA\Big Class.jmp", invisible );
Wait( 0 );
Main Menu( "Hide", "JMP Home Window" );
dst = dt << Run Script( "Distribution" );

After testing a few different possibilities, this is the best option I found that works to hide both the data table you open and the home window:

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA\Big Class.jmp" );
Wait( 0 );
Main Menu( "Hide", "JMP Home Window" );
dt << Show Window( 0 );
dst = dt << Run Script( "Distribution" );

Without the Wait(), it fails. If you hide the data table first, the home window stays visible. Interesting quirks.

Re: How to make JMP home window invisible ?

MathStatChem — Thu, 25 Jul 2024 14:40:59 GMT

Are you running an external Python environment and launching JMP with command line tools from Python? Is so, you might try using the new Python Integration in JMP 18, with comes with it's own Python environment and is more directly connected with JMP. See https://community.jmp.com/t5/JMPer-Cable/Getting-started-with-Python-integration-in-JMP-18/ba-p/768700 and JMP is Pythonic! Enhanced Python Integration in JMP 18 - JMP User Community

Re: How to make JMP home window invisible ?

mati — Fri, 26 Jul 2024 01:32:21 GMT

This worked - Thanks