topic Re: Save Journal overwrites graphs of Fit Group in Discussions

Save Journal overwrites graphs of Fit Group

robot — Fri, 19 Jul 2024 19:04:52 GMT

Sending Save Journal command to Fit Group appears to overwrite each row of graphs rather than saving the entire journal. Is this a bug or am I doing something wrong?

JMP 17.2.0

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
biv = dt << Fit Group( Bivariate( Y( :height ), X( :weight ) ), Bivariate( Y( :weight ), X( :height ) ), <<{Arrange in Rows( 2 )}, By( :Age ) );
journ = biv << Journal;
save_dir = Pick Directory( "Select a directory" );
journ << Save Journal( Concat( save_dir, "Big Class.jrn" ) );

Re: Save Journal overwrites graphs of Fit Group

jthi — Fri, 19 Jul 2024 19:13:09 GMT

Few options

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
biv = new windoW("",dt << Fit Group(
	Bivariate(Y(:height), X(:weight)),
	Bivariate(Y(:weight), X(:height)),
	<<{Arrange in Rows(2)},
	By(:Age)
));
biv << Save Journal("$TEMP/test.jrn");
Open("$TEMP/test.jrn");

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
biv = dt << Fit Group(
	Bivariate(Y(:height), X(:weight)),
	Bivariate(Y(:weight), X(:height)),
	<<{Arrange in Rows(2)},
	By(:Age)
);
biv << Journal;
Current Journal() << Save Journal("$TEMP/test2.jrn");
Open("$TEMP/test2.jrn");

If you print what you have in biv and journ, you will see that those are lists of references

biv = {Fit Group[], Fit Group[], Fit Group[], Fit Group[], Fit Group[], Fit Group[]};
journ = {Fit Group[], Fit Group[], Fit Group[], Fit Group[], Fit Group[], Fit Group[]};

Re: Save Journal overwrites graphs of Fit Group

robot — Fri, 19 Jul 2024 20:05:38 GMT

Thanks Jarmo.