topic Re: Resizing Data Box in Discussions

Resizing Data Box

tom_abramov — Sun, 14 Jul 2024 15:34:47 GMT

Is there a way to fix/resize by user the size of the data box?
Currently the size of the box is set automatically due to the objects in the window.

dt = Open("$SAMPLE_DATA/Big Class.jmp");
New Window("A",
	H List Box(
		V List Box(dt << New Data Box(), obj = dt << Bivariate(Y(:Weight), X(:Height))),
		Spacer Box(<<size(30, 0))
	)
);

Re: Resizing Data Box

txnelson — Sun, 14 Jul 2024 11:11:21 GMT

The window size can be changed by passing the Set Window Size message to the New Window

Names Default to Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
nw = New Window( "A",
	H List Box(
		V List Box(
			dt << New Data Box(),
			obj = dt <<
			Bivariate( Y( :Weight ), X( :Height ) )
		),
		Spacer Box( <<size( 30, 0 ) )
	)
);

nw << set window size( 600, 800 );

P.S. Please use the JSL icon at the top of the Preview Window to enter JSL. It provides the user with an easier form of the code to read and understand.

Re: Resizing Data Box

tom_abramov — Sun, 14 Jul 2024 11:19:07 GMT

Thank you,

I am aware of this solution.

However, I have a full-screen dashboard with a data box inside, meaning the main window is fixed in size (full-screen). I would like to adjust the size of the data box independently of the parent window.

Re: Resizing Data Box

txnelson — Sun, 14 Jul 2024 11:51:10 GMT

I am not aware of a reliable way to do that. Others more experienced in creating Dashboards may have an answer.

Re: Resizing Data Box

jthi — Sun, 14 Jul 2024 15:36:36 GMT

You can for example place the data box inside Scroll Box

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
nw = New Window("A",
	H List Box(
		V List Box(
			Scroll Box(size(100, 100), dt << New Data Box()),
			obj = dt << Bivariate(Y(:Weight), X(:Height))
		),
		Spacer Box(<<size(30, 0))
	)
);

nw << set window size(600, 800);

Re: Resizing Data Box

hogi — Sun, 14 Jul 2024 17:02:09 GMT

makes the data view smaller, but definitely no fun to work with 2 stacked scroll bars ...

Re: Resizing Data Box

tom_abramov — Mon, 15 Jul 2024 05:46:26 GMT

Thank you,

Tried this solution as well :)

Resizing scroll box does not resize the data box.

Re: Resizing Data Box

jthi — Mon, 15 Jul 2024 05:52:32 GMT

If that scroll box option isn't what you want, then you can try directly resizing the DataBrowserBox (disable auto stretching)

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
nw = New Window("A",
	H List Box(
		V List Box(
			db = dt << New Data Box(), 
			obj = dt << Bivariate(Y(:Weight), X(:Height))),
			Spacer Box(<<size(30, 0))
	)
);
wait(2); // demo purposes
db << Set Auto Stretching({0, 0});
db << Set Width(300);
db << Set Height(200);

Re: Resizing Data Box

hogi — Mon, 15 Jul 2024 07:13:39 GMT

the minimum height is given by the side panel, so maybe close it?

- and reduce the size of the header:

db << close side panels( 1 ) << close summary panels( 1 ) << Set Header Height( 20 );

Re: Resizing Data Box

tom_abramov — Mon, 15 Jul 2024 08:06:51 GMT

Thank you. Adding slicers for both Width and Height might offer the functionality the user needs.

Although it is not the best user experience.
The best is to drag the corner of the data box to resize.

May be there is some container in JSL that could be resized by dragging the corner?
So the data box will auto stretch due to the container?

Thanks again.

Re: Resizing Data Box

tom_abramov — Mon, 15 Jul 2024 08:07:33 GMT

Thanks! Was looking for "close side panels". Very helpful.

Re: Resizing Data Box

mmarchandFSLR — Tue, 16 Jul 2024 13:38:49 GMT