topic 回复： How does JSL implement a click-to-get variable value in such a graph? in Discussions

How does JSL implement a click-to-get variable value in such a graph?

lala — Fri, 29 Mar 2024 05:43:48 GMT

Follow the script below.

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
p1 = dt << Graph Builder(
	Variables( X( :weight ), Y( :height ), Group X( :age ), Color( :sex ) ),
	Elements( Bar( X, Y, Legend( 5 ), Response Axis( "X" ), Summary Statistic( "Sum" ) ) )
);

How to write JSL How to achieve in the graph by clicking on a certain age bar, get this age value?And use this value to perform subsequent operations.

Thanks!

回复： How does JSL implement a click-to-get variable value in such a graph?

lala — Fri, 29 Mar 2024 05:44:37 GMT

If click on the space indicated by this arrow, can get the age value =14?
It's a left mouse click, not Hover Labels.

回复： How does JSL implement a click-to-get variable value in such a graph?

lala — Fri, 29 Mar 2024 14:18:48 GMT

？？

frame = (p1 << report)[FrameBox( 1 )];
frame << Set Graphlet(
	Picture(
		dataage = Parse( age:_where );//??
		d2 = Open( "$SAMPLE_DATA/Big Class Families.jmp" );
		d2 << Select Where( age == dataage );
		d3 = d2 << Subset( Output Table( "test" ), Selected Rows( 1 ), selected columns( 0 ) );
		Try( d3 << Delete Table Property( "Source" ) );
	
	),
	Reapply( 1 )
);

回复： How does JSL implement a click-to-get variable value in such a graph?

lala — Fri, 29 Mar 2024 06:03:45 GMT

How to execute this JSL with a mouse click?

回复： How does JSL implement a click-to-get variable value in such a graph?

lala — Fri, 29 Mar 2024 14:25:26 GMT

If it is triggered with Hover Labels, why can it only be triggered to open Big Class Families.jmp at age ==12?

How can I make other age columns trigger as well?

Thanks!

txt = "a";
Set Clipboard( txt );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
p1 = dt << Graph Builder(
	Variables( X( :weight ), Y( :height ), Group X( :age ), Color( :sex ) ),
	Elements( Bar( X, Y, Legend( 5 ), Response Axis( "X" ), Summary Statistic( "Sum" ) ) )

,
	SendToReport(
		Dispatch(
			{},
			"Graph Builder",
			FrameBox,
			Set Textlet(
				Setup(
					expr = Parse( local:_where );
					a = local:_dataTable << Get Rows Where( expr );
					Set Clipboard( a[1] );
					local:r = local:_dataTable << Get Rows Where( expr );
				),
				Markup( "{local:r}rows" )
			)
		)
	)
);
txt = Get Clipboard();
frame = (p1 << report)[FrameBox( 1 )];
frame << Set Graphlet(
	Picture(
		dataage = txt; //Parse( age:_where );//??
		d2 = Open( "$SAMPLE_DATA/Big Class Families.jmp" );
		d2 << Select Where( age == dataage );
		d3 = d2 << Subset( Output Table( "test" ), Selected Rows( 1 ), selected columns( 0 ) );
		Try( d3 << Delete Table Property( "Source" ) );
	),
	Reapply( 1 )
);

回复： How does JSL implement a click-to-get variable value in such a graph?

Craige_Hales — Fri, 29 Mar 2024 14:46:02 GMT

dt = Open( "$SAMPLE_DATA/Big Class.jmp", invisible );
p1 = dt << Graph Builder(
	Show Control Panel( 0 ),
	Variables( X( :weight ), Y( :height ), Group X( :age ), Color( :sex ) ),
	Elements( Bar( X, Y, Legend( 5 ), Response Axis( "X" ), Summary Statistic( "Sum" ) ) )
);
// this graphbuilder chart has multiple FrameBoxes. Get a list of them.
framelist = Report( p1 ) << XPath( "(//OutlineBox[text()='Graph Builder']//FrameBox)" );
// each framebox needs a graphis script with a Mousetrap to detect clicks.
For( iFrame = 1, iFrame <= N Items( framelist ), iFrame += 1,
	frame = framelist[iFrame];
	// the mousetrap needs to capture the iFrame value when it is
	// built so it can report it later; use eval(evalexpr(...expr()...))
	Eval(
		Eval Expr(
			frame << Addgraphicsscript(
				Mousetrap(
					{/*nothing on mouse drag, it happens a lot*/}//
				, // but on mouse up, do something. MouseUp only happens once per click.
					xx = x;
					yy = y;
					Show( xx, yy, Expr( iFrame ) );
					// run your script here
				)
			)
		)
	);
);

回复： How does JSL implement a click-to-get variable value in such a graph?

lala — Fri, 29 Mar 2024 23:42:05 GMT

Thanks Experts!

Very amazing, have seen xx, yy and Expr(iFrame) changes.

回复： How does JSL implement a click-to-get variable value in such a graph?

lala — Fri, 29 Mar 2024 23:50:51 GMT

But why doesn't this script work in the Chinese version of JMP Pro 17.0?

win10

Thanks!

回复： How does JSL implement a click-to-get variable value in such a graph?

lala — Fri, 29 Mar 2024 23:58:54 GMT

Set my version 17 of JMP to English.

It works, but there will be Chinese in the log?

Thanks!

回复： How does JSL implement a click-to-get variable value in such a graph?

Craige_Hales — Sat, 30 Mar 2024 03:14:33 GMT

I grabbed this

"(//OutlineBox[text()='Graph Builder']//FrameBox)"

from here

right-click the outline triangle, choose Show Properties. Click one of the graphs.

you might simplify it to

framelist = Report( p1 ) << XPath( "(//FrameBox)" );

回复： How does JSL implement a click-to-get variable value in such a graph?

lala — Sat, 30 Mar 2024 03:44:01 GMT

Thank Craige!
You taught me how to solve problems so that I didn't just copy code.
Thanks Experts!

回复： How does JSL implement a click-to-get variable value in such a graph?

hogi — Sat, 30 Mar 2024 19:33:02 GMT

For those who are too lazy to click - or too lazy to use Expression Handling: use the Picture part of the Hover label.

The reaction is immediate (much faster than the time it takes till the hover label appears).

(view in My Videos)

dt = Open( "$SAMPLE_DATA/Big Class.jmp", invisible );
gb = dt << Graph Builder(
	Show Control Panel( 0 ),
	Variables( X( :weight ), Y( :height ), Group X( :age ), Color( :sex ) ),
	Elements( Bar( X, Y, Legend( 5 ), Response Axis( "X" ), Summary Statistic( "Sum" ) ) )
);
fbs = Report( gb ) << XPath( "//FrameBox" );

For Each( {fb}, fbs,
	fb << Set Graphlet( Picture( Caption( Char( myAge = :age[local:_firstRow] ) ) ) )
);

回复： How does JSL implement a click-to-get variable value in such a graph?

lala — Sun, 31 Mar 2024 02:11:22 GMT

I can only click.
Because some columns have small graphics (other columns have large data), it is difficult to point to hover.

回复： How does JSL implement a click-to-get variable value in such a graph?

lala — Thu, 18 Apr 2024 12:56:49 GMT

Still want to trigger scripts by clicking on graphics, not by Hover Labels

But this graphic changes form, and I don't know how to change to write JSL.

I had to go back to the experts.

Thanks!

I can only write a script like this, but cannot execute it:

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
p1 = dt << Graph Builder(
	Size( 632, 1152 ),
	Show Control Panel( 0 ),
	Show Legend( 0 ),
	Variables( X( :weight ), Y( :height ) ),
	Elements(
		Bar( X, Y, Legend( 5 ), Bar Style( "Stacked" ), Response Axis( "X" ), Summary Statistic( "Sum" ) )
	)
);
gp = Report(p1)["Graph Builder",FrameBox(1)]
Eval(
	Eval Expr(
		gp << Addgraphicsscript(
			Mousetrap(
				{},
				a0 = Expr( iFrame );
				dt << Select Where( :height == a0 );
				dt << Select Columns( "height" );
				d3 = dt << Subset( Output Table( "test" ), Selected Rows( 1 ), columns( height ) );
			)
		)
	)
);

回复： How does JSL implement a click-to-get variable value in such a graph?

Craige_Hales — Thu, 18 Apr 2024 13:57:59 GMT

Check the log, there is a missing ; and undefined variable iFrame which you don't need because there is only one frame. The original example embedded the frame number into each script. You don't need the eval(evalexpr(...expr(...)...)) because you no longer have the iFrame to embed in the expr(...)

MouseTrap is the strangest function in all of JMP. When it is called, it does nothing at all. And you don't have to place it where it will be called, but you DO have to place it in the body of the script, not in a user function outside of the script. MouseTrap is a way to supply a snippet of JSL that will run when the mouse moves. When the mouse moves over the framebox, JMP looks for handler functions in the attached graphic scripts and calls them until one handles the mouse.

回复： How does JSL implement a click-to-get variable value in such a graph?

lala — Thu, 18 Apr 2024 14:35:44 GMT

Thank Craige!

Yes, one of my code changes was deleted by mistake;

Since my actual generated graph bar graph is very small, using Hover Labels is prone to errors and raises unwanted data.So I still need to trigger the script by clicking on the bar chart.
I want to modify it by imitating the script given by the expert earlier in this post.But I studied for a long time, still do not know how to modify.You can only post again to ask the experts for help.
Thanks Experts!

回复： How does JSL implement a click-to-get variable value in such a graph?

lala — Thu, 18 Apr 2024 14:41:25 GMT

Interesting example.

回复： How does JSL implement a click-to-get variable value in such a graph?

lala — Tue, 23 Apr 2024 02:43:20 GMT

frame = (gp << report)[FrameBox( 1 )];
frame << Set Graphlet(
	Picture(
		Try( Close( d3, nosave ) );
		Current Data Table( dt );
		d3 = dt << Subset(
			Output Table( "tt" ),
			Selected Rows( 0 ),
			Rows( dt << Get Selected Rows() ),
			Selected columns only( 0 )
		);
	),
	Reapply( 1 )
);

This allows mouse clicks and Hover Labels to be used simultaneously.

Click can implement the selected line, Hover Labels can extract a subset of the selected line.

Thanks!

回复： How does JSL implement a click-to-get variable value in such a graph?

lala — Tue, 23 Apr 2024 04:41:26 GMT

回复： How does JSL implement a click-to-get variable value in such a graph?

hogi — Thu, 25 Apr 2024 21:54:43 GMT

and if you are too lazy to hit the bars - just

add a HeatMap plot
with disabled x and y variables
and transparency set to 0:

(view in My Videos)

dt = Open( "$SAMPLE_DATA/Big Class.jmp", invisible );
gb = dt << Graph Builder(

	Variables( X( :weight ), Y( :height ), Group X( :age ), Color( :sex ) ),
	Elements(
		Bar(
			X,
			Y,
			Response Axis( "X" ),
			Summary Statistic( "Sum" )
		),
		Heatmap( Legend( 6 ) )
	),
	SendToReport(
		Dispatch( {"Heatmap"}, "", OutlineBox, {Close( 0 )} ),
		Dispatch( {}, "400", ScaleBox,
			{Legend Model(
				6,
				Base( 0, 0, 0, Item ID( "F", 1 ) ),
				Base( 1, 0, 0, Item ID( "M", 1 ) ),
				Properties( 0, {Transparency( 0 )}, Item ID( "F", 1 ) ),
				Properties( 1, {Transparency( 0 )}, Item ID( "M", 1 ) )
			)}
		))
);
fbs = Report( gb ) << XPath( "//FrameBox" );

For Each( {fb}, fbs,
	fb << Set Graphlet( Picture( Caption( Char( myAge = :age[local:_firstRow] ) ) ) )
);