topic Re: How to minimize a floating global filter window in Discussions

How to minimize a floating global filter window

shampton82 — Thu, 14 Mar 2024 16:32:48 GMT

Hey everyone,

I am having an issue trying to find a way to minimize a floating global data filter window. I have tried <<show window(0) and <<minimize window(1) and neither seem to work.

Any ideas on what syntax to use?

Thanks for any input!

Steve

Re: How to minimize a floating global filter window

jthi — Thu, 14 Mar 2024 16:40:05 GMT

Show Window(0) works for me

Names Default To Here(1); 

dt = open("$SAMPLE_DATA/Big Class.jmp");
dt << Data Filter();

wait(1);

windows = Get Window List() << get window title;
For Each({window}, windows,
	If(Starts With(window, "Data Filter for"),
		Window(window) << Show Window(0);
		break();
	);
);

Re: How to minimize a floating global filter window

shampton82 — Thu, 14 Mar 2024 16:52:27 GMT

@jthi So weird! I'm using this script in a work flow:

Current Data Table() << Data Filter(
	Location( {780, 189} ),
	Conditional,
	Add Filter(
		columns( :Date Time Quarter, :Date Time Period, :Date Time ),
		Display( :Date Time Quarter, N Items( 5 ) ),
		Display( :Date Time Period, N Items( 5 ) )
	)
)<<show window(0);

This creates the filter but won't hide it.

Re: How to minimize a floating global filter window

jthi — Thu, 14 Mar 2024 17:01:11 GMT

Maybe you just need extra pair of brackets

Names Default To Here(1); 

dt = open("$SAMPLE_DATA/Big Class.jmp");
(dt << Data Filter()) << Show Window(0);

or if you want to get a reference something like this

Names Default To Here(1); 

dt = open("$SAMPLE_DATA/Big Class.jmp");
Local({filter_ref},
	filter_ref = dt << Data Filter();
	filter_ref << Show Window(0);
);

Re: How to minimize a floating global filter window

mmarchandTSI — Thu, 14 Mar 2024 17:06:08 GMT

You can do it this way.

Current Data Table() << Data Filter(
	Location( {780, 189} ),
	Conditional,
	Add Filter(
		columns( :Date Time Quarter, :Date Time Period, :Date Time ),
		Display( :Date Time Quarter, N Items( 5 ) ),
		Display( :Date Time Period, N Items( 5 ) )
	),
	Show Window( 0 )
)

Re: How to minimize a floating global filter window

shampton82 — Thu, 14 Mar 2024 18:14:40 GMT

Hey @jthi , I don't know why but the top method did not work when I tired it in my script but it works just fine when I run the provide script on its own. I haven't had a chance to try out the second method in my script but I'll give an update when I can. For some reason the proposed solution by @mmarchandTSI worked......