topic Re: Import multiple CSV files, but some title format error need to modify by JSL in Discussions

Import multiple CSV files, but some title format error need to modify by JSL

BayesRabbit7133 — Wed, 20 Dec 2023 08:12:38 GMT

I'm trying to import multiple CSV files, the "import multiple files" function doesn't work well because original data column name format has two problems that will cause title and data don't match

1. The data column name looks like this: Date time name ( A B C ) (D E F ) height weight ......etc

2. The dilim I need are space and ( and )

3. However, there is additional space or tab before "Date", so the first column name becomes Column 1 rather than Date, and title right shift one column compare to data

4. second error is (D, there in no space between this two for the title, so they are treated as one title, but the data are separated into ( and D two columns because there is space in between, so title will left shift one column compare to data

5. The first error always exist before first column name "Date", but the second error "(D" may appear at different order based on source tool

I would like to wirte a JSL so that it can automatically match all title and columns, but not sure how to do this:

I guess the first step is to use Get Column Names() then parse the names, but parse() and word() seems don't work.

I' m stucked here, really raw at coding, thank you for your help in advance

Re: Import multiple CSV files, but some title format error need to modify by JSL

jthi — Wed, 20 Dec 2023 07:18:57 GMT

If it is possible to provide one example (or few if there are different kinds of) .csv file it would make this easier. If not, could you provide one "broken" data table?

Re: Import multiple CSV files, but some title format error need to modify by JSL

BayesRabbit7133 — Wed, 20 Dec 2023 07:40:41 GMT

I attached sample table for your reference

Re: Import multiple CSV files, but some title format error need to modify by JSL

jthi — Wed, 20 Dec 2023 10:26:59 GMT

Based on the two line example I would most likely go by cleaning the .csv file (remove () and collapse whitespaces) and then use Open with Char to Blob() to convert that "fixed" string into a data table

Names Default To Here(1);

str = Load Text File("$DOWNLOADS/sample CSV.csv");

lines = Words(str, "\!N");

data = Transform Each({line}, lines, 
	str = Collapse Whitespace(Substitute(line, {"(", ")"}, ""))	
);

str = Concat Items(data, "\!N");

dt = Open(Char To Blob(str),
	Import Settings(
		End Of Line(CRLF, CR, LF),
		End Of Field(Spaces, Space, CSV(0)),
		Strip Quotes(1),
		Use Apostrophe as Quotation Mark(0),
		Use Regional Settings(0),
		Scan Whole File(1),
		Treat empty columns as numeric(0),
		CompressNumericColumns(0),
		CompressCharacterColumns(0),
		CompressAllowListCheck(0),
		Labels(1),
		Column Names Start(1),
		First Named Column(1),
		Data Starts(2),
		Lines To Read("All"),
		Year Rule("20xx")
	)
);

Re: Import multiple CSV files, but some title format error need to modify by JSL

txnelson — Wed, 20 Dec 2023 14:12:06 GMT

@jthi

Your solution is awesome!

One question. Your line where you are removing the parentheses from each line, you specify

str = Collapse Whitespace(Substitute(line, {"(", ")"}, ""))

where you substitute all "(" to ")" and then substitute all ")" to "".

My old school approach would be:

str = Collapse Whitespace(Substitute(line, "(", "", ")", ""))

where the "(" are substituted with "" and then the ")" are substituted to "".

Is there an advantage to your syntax or is it just a personal choice?

Re: Import multiple CSV files, but some title format error need to modify by JSL

jthi — Wed, 20 Dec 2023 14:53:48 GMT

It is just my personal choice. Generally when I want to replace multiple things with same thing, I provide Substitute a list of the values to replace and then the value once. If I want to replace them with different things I use the approach you did show OR if I have to build it dynamically/have configuration file I will use two lists

Names Default To Here(1);

str = "AA BB CC DD";

a = Substitute(str, {"AA", "BB"}, "11"); // a = "11 11 CC DD";
b = Substitute(str, "AA", "11", "BB", "22"); // b = "11 22 CC DD";

subs = ["AA" => "33", "BB" => "44"];
c = Substitute(str, subs << get keys, subs << Get Values); // c = "33 44 CC DD";

show(a, b, c);

Re: Import multiple CSV files, but some title format error need to modify by JSL

BayesRabbit7133 — Wed, 20 Dec 2023 15:39:13 GMT

Thank you for your support, this method works well for single file

But I still have one question left, I have a lot of files with same format that needs to be imported as one JMP file.

So it seems this method requires me to open them one by one then do cocatenate into one file

This is why my original thought was:

1. use multiple import function

2. get column names

3. then use recode column name function to modify each column name

Re: Import multiple CSV files, but some title format error need to modify by JSL

jthi — Wed, 20 Dec 2023 15:52:33 GMT

Is there some specific reason why you couldn't do the following

Get list of files you are interested in
Use For Each to loop over them
Inside the loop parse the files and concatenate them to a table which you open first

You could try to also fix the columns but based on your example it was much easier to just fix the csv file than start messing with column names and/or shifting values after importing the values

Re: Import multiple CSV files, but some title format error need to modify by JSL

Craige_Hales — Wed, 20 Dec 2023 19:07:39 GMT

Fixing the program that generates the file might also be a good option. That is not a standard CSV and I don't think any other program is going to parse it correctly either.

Re: Import multiple CSV files, but some title format error need to modify by JSL

BayesRabbit7133 — Thu, 21 Dec 2023 10:42:56 GMT

I tried to use for loop to loop over files, but it doesn't work, looks like something goes wrong when I tried to concat them

Names Default To Here(1);
dir = Pick Directory("Select a directory");
filelist = Files In Directory(dir);
strings = {};
 
For(i = 1, i <= N Items(filelist), i++,
	file = dir || Eval(Parse(filelist[i]));
	str = Load Text File(file);
	lines = Words(str, "\!N");
	data = Transform Each({line}, lines,
		str = Collapse Whitespace(Substitute(line, {"(", ")"}, ""))
	);
	str = Concat Items(data, "\!N");
	strings = strings || str;
);
 
 
 
dt = Open(
	Char To Blob(str),
	Import Settings(
		End Of Line(CRLF, CR, LF),
		End Of Field(Spaces, Space, CSV(0)),
		Strip Quotes(1),
		Use Apostrophe as Quotation Mark(0),
		Use Regional Settings(0),
		Scan Whole File(1),
		Treat empty columns as numeric(0),
		CompressNumericColumns(0),
		CompressCharacterColumns(0),
		CompressAllowListCheck(0),
		Labels(1),
		Column Names Start(2),
		First Named Column(1),
		Data Starts(3),
		Lines To Read("All"),
		Year Rule("20xx")
	)
);

Re: Import multiple CSV files, but some title format error need to modify by JSL

Craige_Hales — Thu, 21 Dec 2023 10:22:40 GMT

shows one way to do it

Re: Import multiple CSV files, but some title format error need to modify by JSL

BayesRabbit7133 — Thu, 21 Dec 2023 13:46:45 GMT

After several trial, below code sucessfully import multiple CSVs through loop, and the format are correct.

But I still have two remain issue:

1. starting from second file, the headers are not exclude as column title, they are treated as data in the table, there are two rows of headers, first row is file name, second row are titles separted by space

2. I would like to add filename column so that i can analyze different files, but this is not like import mutiple file function that I can easily achieve it?

Names Default To Here( 1 );

dir = Pick Directory( "Select a directory" );

filelist = Files In Directory( dir );

mylist = {};

For( i = 1, i <= N Items( filelist ), i++,
file = dir || "/" || filelist[i];
str = Load Text File( file );
lines = Words(str, "\!N");
data = Transform Each({line}, lines,
line = Collapse Whitespace(Substitute(line, {"(", ")"}, ""))
);
modifiedstr = Concat Items(data, "\!N");
mylist[i] = modifiedstr;
);

dt = Open(
Char To Blob( Concat Items( mylist, "\!N" ) ),
Import Settings(
End Of Line( CRLF, CR, LF ),
End Of Field( Spaces, Space, CSV( 0 ) ),
Strip Quotes( 1 ),
Use Apostrophe as Quotation Mark( 0 ),
Use Regional Settings( 0 ),
Treat empty columns as numeric( 0 ),
Compress Numeric Columns( 0 ),
Compress Character Columns( 0 ),
Compress Allow List Check( 0 ),
Labels( 1 ),
Column Names Start( 2 ),
First Named Column( 1 ),
Data Starts( 3 ),
Lines To Read( "All" ),
Year Rule( "20xx" )
)
);

Re: Import multiple CSV files, but some title format error need to modify by JSL

jthi — Thu, 21 Dec 2023 14:01:26 GMT

Don't create one massive string, but rather create data tables one by one and concatenate those as you go. Also when posting JSL scripts please use "Insert JSL Script" as it makes it much easier to read.

Names Default To Here(1);

dir = "$DOWNLOADS/New Folder (7)";

filelist = Files In Directory(dir);
mylist = {};

dt_collector = Empty();

For(i = 1, i <= N Items(filelist), i++,
	file = dir || "/" || filelist[i];
	str = Load Text File(file);
	lines = Words(str, "\!N");
	data = Transform Each({line}, lines,
		line = Collapse Whitespace(Substitute(line, {"(", ")"}, ""))
	);
	modifiedstr = Concat Items(data, "\!N");

	dt = Open(
		Char To Blob(modifiedstr),
		Import Settings(
			End Of Line(CRLF, CR, LF),
			End Of Field(Spaces, Space, CSV(0)),
			Strip Quotes(1),
			Use Apostrophe as Quotation Mark(0),
			Use Regional Settings(0),
			Treat empty columns as numeric(0),
			Compress Numeric Columns(0),
			Compress Character Columns(0),
			Compress Allow List Check(0),
			Labels(1),
			Column Names Start(1),
			First Named Column(1),
			Data Starts(2),
			Lines To Read("All"),
			Year Rule("20xx")
		),
		invisible
	);
	
	dt << Set Name(filelist[i]);
	dt << New Column("Source", Character, Nominal, << Set Each Value((dt << get name)));
	
	If(!Is Empty(dt_collector),
		dt_collector << Concatenate(
			dt,
			Append to first table
		);
		Close(dt, no save);
	,
		dt_collector = dt;
	);
);

Re: Import multiple CSV files, but some title format error need to modify by JSL

Craige_Hales — Thu, 21 Dec 2023 14:24:31 GMT

@jthi is right, but if you want to keep concatenating the strings, you'll need a few changes. This will fail if the concatenation is >2GB characters because that is the longest string JMP can handle.

idea:


For( i = 1, i <= N Items( filelist ), i++,
    file = dir || "/" || filelist[i];
    str = Load Text File( file );
    lines = Words(str, "\!N");
    header1 = RemoveFrom(lines, 1); // remove the first line, two times.
    header2 = RemoveFrom(lines, 1); // (removes both header lines.)
    data = Transform Each({line}, lines,
        // prepend the file name to each data line
        filelist[i] || " " || Collapse Whitespace(Substitute(line, {"(", ")"}, ""));
    );
    modifiedstr = Concat Items(data, "\!N");
    mylist[i] = modifiedstr;
);
header2 = "filename" || header2; // add the column name "filename"
insertInto(mylist,header2,1); // check the order of the arguments, the goal
insertInto(mylist,header1,1); // is to push these onto the front of the list
// now do the import...

untested, but about right. look up InsertInto() and RemoveFrom(); I don't have JMP open at the moment. The idea is to remove (and capture) the first two lines, every time, and after all is captured and stacked, put the first two lines at the front, with the extra column name tacked on. And inside, tack on the filename for every line.

Re: Import multiple CSV files, but some title format error need to modify by JSL

BayesRabbit7133 — Thu, 21 Dec 2023 15:46:22 GMT

Thank you for your support, really learned a lot in this jsl project.