topic Re: Filter By - disabled by a Local Data Filter in Discussions

Filter By - disabled by a Local Data Filter

hogi — Wed, 05 Jul 2023 06:19:45 GMT

A nice feature in Jmp:

One (main) graph can be used to restrict the data that is displayed in another graph - or tabulate list.
This feature is activated by a checkbox "Filter By":

Surprisingly, activating a Local Data Filter in the (main) Graph disables this functionality.
The respective data points are just highlighted, the display is not restricted to the selected data points:

Same effect in Jmp 16 and 17.1.

Why is the functionality disabled by activating a Local Data Filter.

How can I enable the functionality?

Workaround:

Add another Data Filter (outside of the main graph).
how?

table1 = Open( "$SAMPLE_DATA/Big Class.jmp" );
New Window( "Big Class - Dashboard",
	Data Filter Context Box(
		Tab Page Box(
			"Dashboard",
			H Splitter Box(
				Tab Page Box(
					"Tabulate",
					Scroll Box( V List Box( table1 << Tabulate( Show Control Panel( 0 ), Add Table( Row Table( Grouping Columns( :name ) ) ) ) ) )
				),
				Data Filter Source Box(
					Tab Page Box(
						"Graph Builder",
						Scroll Box(
							V List Box(
								table1 << Graph Builder(
									Show Control Panel( 0 ),
									Variables( X( :height ), Y( :weight ) ),
									Elements( Points( X, Y, Legend( 9 ) ) ),
									Local Data Filter( Conditional, Add Filter( columns( :age ), Where( :age == 14 ) ) )
								)
							)
						)
					)
				)
			)
		)
	)
);

Re: Filter By - disabled by a Local Data Filter

yuichi_katsumur — Fri, 07 Jul 2023 01:27:44 GMT

Hello @hogi ,

This is a possible workaround using JSL. I hope it works.

table1 = Open( "$SAMPLE_DATA/Big Class.jmp" );
New Window( "Big Class - Dashboard",
	Data Filter Context Box(
		H List Box(
			Data Filter Source Box(
				table1 << Data Filter( Local, Add Filter( columns( :age ) ) )
			),
			Data Filter Context Box(
				H List Box(
					Data Filter Source Box(
						Data Filter Source Box(
							table1 << Graph Builder(
								Show Control Panel( 0 ),
								Variables( X( :height ), Y( :weight ) ),
								Elements( Points( X, Y, Legend( 9 ) ) )
							)
						)
					),
					table1 << Tabulate(
						Show Control Panel( 0 ),
						Add Table( Row Table( Grouping Columns( :name ) ) )
					)
				)
			)
		)
	)
);

Re: Filter By - disabled by a Local Data Filter

hogi — Sat, 08 Jul 2023 20:12:26 GMT

Hi @yuichi_katsumur ,thanks a lot for the solution.

So, the trick is to add a level with a second Data Filter Context Boxes ...

Are the nested data filter source boxes necessary. It seems that a single one is also fine:

table1 = Open( "$SAMPLE_DATA/Big Class.jmp" );
New Window( "Big Class - Dashboard",
	Data Filter Context Box(
		H List Box(
			Data Filter Source Box(
				table1 << Data Filter( Local, Add Filter( columns( :age ) ) )
			),
			Data Filter Context Box(
				H List Box(
						Data Filter Source Box(
							table1 << Graph Builder(
								Show Control Panel( 0 ),
								Variables( X( :height ), Y( :weight ) ),
								Elements( Points( X, Y, Legend( 9 ) ) )
							)
					),
					table1 << Tabulate(
						Show Control Panel( 0 ),
						Add Table( Row Table( Grouping Columns( :name ) ) )
					)
				)
			)
		)
	)
);

Re: Filter By - disabled by a Local Data Filter

yuichi_katsumur — Mon, 10 Jul 2023 23:55:26 GMT

Hi @hogi ,

Thank you for correcting my error.

Re: Filter By - disabled by a Local Data Filter

hogi — Fri, 14 Jul 2023 07:01:48 GMT

Jmp support just confirmed:
In Dashboard mode, there is no possibility to generate the hierarchical structure which is needed to make this Dashboard work :(

(Case 00045639)

Re: Filter By - disabled by a Local Data Filter

hogi — Mon, 30 Oct 2023 22:17:33 GMT

A warning like this one could help:

Dear user, I noticed that you activated a Local Data Filter in a graph that is used as Filter By.
Please be aware that this is NOT supported in Jmp. Therefore the Filter By functionality *) will be disabled.

*) just the functionality of Filter By is disabled, not the icon: