topic Re: Capability in Graph Builder in Discussions

Capability in Graph Builder

lisamaley — Fri, 09 Jun 2023 00:47:48 GMT

I have been asked this question multiple times, but is there a way to show capability analysis in the Graph Builder? I found where it can show a 5 number summary, but no where can I figure out how to get it to show the capability. Even have the Cpk or Ppk as an option to show? I cannot seem to find this, is it possible?

I am using JMP Pro 16.0.

Re: Capability in Graph Builder

txnelson — Fri, 08 Apr 2022 06:46:30 GMT

Here are 2 different ways to add th capability to the Graph Builder

Names Default To Here( 1 );

// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

nw = New Window( "Capability", hlb = H List Box() );
hlb << append(
	Graph Builder(
		Size( 528, 454 ),
		Show Control Panel( 0 ),
		Variables( X( :NPN1 ) ),
		Elements( Histogram( X, Legend( 7 ) ) )
	)
);
dis = Distribution(
	invisible,
	Continuous Distribution(
		Column( :NPN1 ),
		Process Capability( Use Column Property Specs )
	)
);
hlb << append(
	Outline Box( "Within Sigma Capability", tb = Table Box() )
);
tb << append(
	String Col Box( "",
		Eval(
			Report( dis )["Within Sigma Capability"][
			String Col Box( 1 )] << get
		)
	)
);
tb << append(
	Number Col Box( "",
		Eval(
			Report( dis )["Within Sigma Capability"][
			Number Col Box( 1 )] << get
		)
	)
);

Names Default To Here( 1 );

// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
dis = Distribution(
	invisible,
	Continuous Distribution(
		Column( :NPN1 ),
		Process Capability( Use Column Property Specs )
	)
);
gb = Graph Builder(
	Size( 528, 454 ),
	Show Control Panel( 0 ),
	Variables( X( :NPN1 ) ),
	Elements( Histogram( X, Legend( 7 ) ) )
);


textlist = (Report( dis )["Within Sigma Capability"][String Col Box( 1 )] << get
);
statlist = (Report( dis )["Within Sigma Capability"][Number Col Box( 1 )] << get
);

Report( gb )[framebox( 1 )] <<
add graphics script(
	Text( Center Justified, {120, 275}, textlist[1] );
	Text(
		Center Justified,
		{122, 275},
		Format( statlist[1], "Fixed Dec", 4, 2 )
	);
	Text( Center Justified, {120, 265}, textlist[2] );
	Text(
		Center Justified,
		{122, 265},
		Format( statlist[2], "Fixed Dec", 4, 2 )
	);
	Text( Center Justified, {120, 255}, textlist[3] );
	Text(
		Center Justified,
		{122, 255},
		Format( statlist[3], "Fixed Dec", 4, 2 )
	);
	Text( Center Justified, {120, 245}, textlist[4] );
	Text(
		Center Justified,
		{122, 245},
		Format( statlist[4], "Fixed Dec", 4, 2 )
	);
);

Re: Capability in Graph Builder

lisamaley — Mon, 11 Apr 2022 01:10:19 GMT

Thank you! I will try this.

Re: Capability in Graph Builder

RA899 — Thu, 21 Sep 2023 17:57:58 GMT

Hi,

is there are a way to import this to power point? I would like to have a graph builder and cpk and then import it to ppt. Thanks.

Re: Capability in Graph Builder

jthi — Thu, 21 Sep 2023 18:16:23 GMT

Few options below

You can use select tool and then copy paste it to Powerpoint
you can right click and use Copy Graph
You can use use File menu and save it as Powerpoint

Re: Capability in Graph Builder

RA899 — Fri, 29 Sep 2023 16:42:35 GMT

Hi,

I'm trying to have the cpk and the GB on the same window and the way you have provided does exactly that. The problem is when I try to export it to ppt, it prints the cpk and GBin two different slides. Would you know a way to make them both in the same slide? Thanks.

Re: Capability in Graph Builder

txnelson — Fri, 29 Sep 2023 17:09:06 GMT

When you save to a .ppt, JMP automatically creates a separate slide for the 2 Outline boxes, "Graph Builder" and "Within Sigma Capability".

I think you can group the 2 together under a new Outline box. I have not tested this, but it is worth a try.

Change the New Window line to

nw = New Window( "Capability", outline box( "Capability Output", hlb = H List Box() ) );

Re: Capability in Graph Builder

RA899 — Wed, 04 Oct 2023 00:30:19 GMT

Thank you Jim. Unfortunately its not working as intended. It still spits out two windows. The difference now is that there are a line at the bottom with the graph builder title. Do you have any recommendations? thanks.

Re: Capability in Graph Builder

txnelson — Wed, 04 Oct 2023 02:32:42 GMT

I tried several techniques and failed with all of them. I then reverted to a method that I have used several time. Basically the display is organized as desired, and then it is made into a picture object, and that object is added to an output box() in a new window. Because the picture object is a single object, it is displayed on one slide

Names Default To Here( 1 );

// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
dt = Open( "$SAMPLE_DATA/semiconductor capability.jmp" );

nw = New Window( "Capability", hlb = H List Box() );
hlb << append(
	gb = Graph Builder(
		Size( 528, 454 ),
		Show Control Panel( 0 ),
		Variables( X( :NPN1 ) ),
		Elements( Histogram( X, Legend( 7 ) ) )
	)
);
dis = Distribution(
	invisible,
	Continuous Distribution(
		Column( :NPN1 ),
		Process Capability( Use Column Property Specs )
	)
);

nw2 = New Window( "Graph", vlb = V List Box() );
ob = Outline Box( "Capability Report", hlb2 = H List Box() );
hlb2 << append( Report( gb )["Graph Builder", List Box( 1 )] );
hlb2 << append(
	Lineup Box( N Col( 1 ),
		Spacer Box( size( 1, 15 ) ),
		txb = Text Box( "Within Sigma Capability" ),
		tb = Table Box()
	)
);
txb << set font style( "Bold" );
tb << append(
	String Col Box( "",
		Eval(
			Report( dis )["Within Sigma Capability"][String Col Box( 1 )] << get
		)
	)
);
tb << append(
	Number Col Box( "",
		Eval(
			Report( dis )["Within Sigma Capability"][Number Col Box( 1 )] << get
		)
	)
);
vlb << append( ob << get picture );
nw2 << Save Presentation( "$TEMP/jmp_example.pptx" );
Open( "$TEMP/jmp_example.pptx" );

Re: Capability in Graph Builder

RA899 — Thu, 26 Oct 2023 17:42:47 GMT

Thank you very much Jim! I appreciate your help. My notification is off, so I just saw your reply.

I will try it and let you know how it goes.