topic Re: how to make cumulative probability plots in JMP? in Discussions

how to make cumulative probability plots in JMP?

r30363 — Sun, 11 Jun 2023 11:25:51 GMT

How can I make cumulative probability plot like the one below? Appreciate your help.

Re: how to make cumulative probability plots in JMP?

jthi — Mon, 18 Jul 2022 13:58:20 GMT

Below are three different options

Use CDF Matrix function JSL Syntax Reference > JSL Functions > Matrix Functions > CDF(Y)

Use Distribution platform and enable CDF Plot Basic Analysis > Distributions > Options for Continuous Variables > CDF Plot

Use Fit Y by X and enable CDF Plot Basic Analysis > Oneway Analysis > Additional Examples of the Oneway Platform > Example of a CDF Plot

Re: how to make cumulative probability plots in JMP?

hogi — Wed, 04 Sep 2024 05:30:18 GMT

There is also a nice way via Graph Builder:

First select the grouping parameter

then use the (right click) context menu/Distributional/ cumulative probability function to generate the ColRank/ColNumber equation and put it on the y axis (the value itself on the x axis).

that's it:

Open( "$SAMPLE_DATA/Big Class.jmp" );


Data Table( "Big Class" ) << Graph Builder(
	Size( 534, 464 ),
	Show Control Panel( 0 ),
	Variables(
		X( :height ),
		Y(
			Transform Column(
				"Cumulative Prob...ty[height][sex]",
				Formula(
					Col Rank( :height, :sex ) / (Col Number( :height, :sex ) + 1)
				)
			)
		),
		Overlay( :sex )
	),
	Elements( Points( X, Y, Legend( 11 ) ), Smoother( X, Y, Legend( 12 ) ) )
);

Re: how to make cumulative probability plots in JMP?

Georg — Tue, 19 Jul 2022 18:05:25 GMT

As I'm using this quite often, I've implemented a simple script in custom menue (view --> customize --> menues and toolbars),

running it with a table open it makes the CDF Plot quite easily.

Oneway( all graphs( 0 ), CDF Plot( 1 ) );

Re: how to make cumulative probability plots in JMP?

r30363 — Thu, 28 Jul 2022 15:35:09 GMT

Holger, thanks for the instruction, that is a new analysis skill which I am completely unaware. further question, if I want to do Left side Y-axis with standard deviation, right side Y-axis with cumulative probability, how to add a right Y in graph builder?

Re: how to make cumulative probability plots in JMP?

hogi — Wed, 03 Aug 2022 14:57:31 GMT

is this what you mean?

Open( "$SAMPLE_DATA/Big Class.jmp" );
Graph Builder(
	Size( 688, 430 ),
	Show Control Panel( 0 ),
	Graph Spacing( 5 ),
	Variables(
		X(
			Transform Column(
				"Normal Quantile [sigma]",
				Formula(
					Normal Quantile(
						Col Rank( :height, :sex ) / (Col Number( :height, :sex ) + 1),
						0,
						1
					)
				)
			)
		),
		X(
			Transform Column(
				"Cumulative Prob [1=100%]",
				Formula( Col Rank( :height, :sex ) / (Col Number( :height, :sex ) + 1) )
			)
		),
		X( :sex ),
		Y( :height ),
		Overlay( :sex )
	),
	Elements( Position( 1, 1 ), Points( X, Y, Legend( 17 ) ), Smoother( X, Y, Legend( 18 ) ) ),
	Elements( Position( 2, 1 ), Points( X, Y, Legend( 11 ) ), Smoother( X, Y, Legend( 12 ) ) ),
	Elements( Position( 3, 1 ), Box Plot( X, Y, Legend( 16 ) ) )
);

Re: how to make cumulative probability plots in JMP?

hogi — Wed, 03 Aug 2022 07:40:39 GMT

I really like Georg's approach to add a shortcut to the main menu.

My new universal plot button (best: with normal prob. scale :)

On the other hand, the GraphBuilder version with the individual data points provides more interactivity.

How would you adjust such graphbuilder code such that it can be used dynamically for any table like Georg's one:
The user should have the possibility to dynamically choose the variable to plot and the grouping variable.

For X, Y and Overlay, I can just use the Application Builder - but how to implement it for the Transform Column inline Formula?

Re: how to make cumulative probability plots in JMP?

txnelson — Wed, 03 Aug 2022 16:18:59 GMT

Here is a crude example that should provide you a good start on what your idea is

Names Default To Here( 1 );
dt = // Open Data Table: big class.jmp
// → Data Table( "big class" )
Open( "$SAMPLE_DATA/big class.jmp" );

New Window( "Select column",
	hlb = H List Box(
		clb = Col List Box(
			dt << get name,
			all,
			max selected( 1 ),
			Try( vlb << delete );
			hlb << append(
				vlb = V List Box(
					var = (clb << get selected)[1];
					Eval(
						Substitute(
								Expr(
									cp = Graph Builder(
										Size( 688, 430 ),
										Show Control Panel( 0 ),
										Graph Spacing( 5 ),
										Variables(
											X(
												Transform Column(
													"Normal Quantile [sigma]",
													Formula(
														Normal Quantile(
															Col Rank( __var__, :sex ) / (Col Number( __var__, :sex ) + 1),
															0,
															1
														)
													)
												)
											),
											X(
												Transform Column(
													"Cumulative Prob [1=100%]",
													Formula( Col Rank( __var__, :sex ) / (Col Number( __var__, :sex ) + 1) )
												)
											),
											X( :sex ),
											Y( __var__ ),
											Overlay( :sex )
										),
										Elements( Position( 1, 1 ), Points( X, Y, Legend( 17 ) ), Smoother( X, Y, Legend( 18 ) ) ),
										Elements( Position( 2, 1 ), Points( X, Y, Legend( 11 ) ), Smoother( X, Y, Legend( 12 ) ) ),
										Elements( Position( 3, 1 ), Box Plot( X, Y, Legend( 16 ) ) )
									)
								),
							Expr( __var__ ), Parse( var )
						)
					);
				)
			);
		)
	)
);

Re: how to make cumulative probability plots in JMP?

hogi — Thu, 04 Aug 2022 17:32:20 GMT

wow, that's very cool :)
I added a second ColListBox for the grouping variable.

Names Default To Here( 1 );
dt=Open( "$SAMPLE_DATA/big class.jmp" );

dt << Clear Column Selection();

updatePlot = Function( {},
	If( Length( clb << get selected ) == 0 | Length( clb2 << get selected ) == 0,
		Print( "value missing" ),
		var = (clb << get selected)[1];
		groupByvar = (clb2 << get selected)[1];

		Try( vlb << delete );
		hlb << append(
			vlb = V List Box(

				Eval(
					Eval Expr(
						cp = Graph Builder(
							Size( 724, 560 ),
							Show Control Panel( 0 ),
							Variables(
								X( Expr( Name Expr( As Column( var ) ) ) ),
								Y(
									Transform Column(
										"Cumulative Probability[1=100%]",
										Formula(
											Col Rank( Expr( Name Expr( As Column( var ) ) ), Expr( Name Expr( As Column( groupByvar ) ) ) ) / (
											Col Number( Expr( Name Expr( As Column( var ) ) ), Expr( Name Expr( As Column( groupByvar ) ) ) ) + 1)
										)
									)
								),
								Overlay( Expr( Name Expr( As Column( groupByvar ) ) ) )
							),
							Elements( Points( X, Y, Legend( 7 ) ), Smoother( X, Y, Legend( 8 ), Method( "Savitzky-Golay" ), Lambda( 2 ) ) ),
							SendToReport(
								Dispatch( {}, "Cumulative Probability[1=100%]", ScaleBox, {Scale( "Normal Probability" ), Format( "Best", 12 )} )
							)
						)
					)
					
				)
			)
		);	
	
	)
);

New Window( "grouped Comulative Probability",
	hlb = H List Box(
		V List Box(
			clb = Col List Box( all, <<Set Data Type( "numeric" ), max selected( 1 ), updatePlot() ),
			clb2 = Col List Box( all, max selected( 1 ), updatePlot() )
		)
	)
);

Re: how to make cumulative probability plots in JMP?

hogi — Fri, 23 Sep 2022 15:15:40 GMT

The approach "delete the plot and replace the plot" makes it really easy to generate reports with complicated interactions :)

The only disadvantage:
By overwriting the old plot, I also reset all changes that I made to the original plot in the meantime (axis scaling, local data filter, ...)

As an interim solution, I searched for the changes and applied them to the new plot, e.g.:

dt =Open( "$SAMPLE_DATA/Big Class.jmp" );
gb = dt << Graph Builder(
	Graph Spacing( 5 ),
	Variables( X( :sex ), Y( :height ) ),
	Elements( Points( X, Y, Legend( 5 ) ) )
);

// manal change like :
Report( gb )[Axisbox( 2 )] << Min(-100)


//read the oldvalues
mymin=((report(gb)<< xpath( "//AxisBox" ))[2] << getscript())["Min"]

//replace the plot ....

//apply the settings to the new plot
Report( gb )[Axisbox( 1 )] << Min( Eval(myMin ))

Further thinking in this direction:
Is there a possibility to send a message to change the content of the plot?
Seems so ...

gb << Variables( X( :sex ), Y( :height ) )

is almost what I need, but it adds a plot instead of replacing it.
Is there an option for the "variables" messages to tell GraphBuilder to replace the old variables with new ones?

Re: how to make cumulative probability plots in JMP?

jthi — Fri, 23 Sep 2022 15:29:24 GMT

These two topics might be helpful:

You might be able to use similar methods with Variables (search Graph Builder Box from Scripting Index).

Re: how to make cumulative probability plots in JMP?

hogi — Wed, 22 Feb 2023 21:16:37 GMT

"remove variable" - just in front of my eyes, but I did not see it.

Many thanks :)

Names Default To Here( 1 );


dt = Current Data Table();


updatePlot2 = Function( {},
	If( Length( clb << get selected ) == 0 | Length( clb2 << get selected ) == 0,
		Print( "value missing" ),
		gbr = Report( gb );
		gbb = gbr[Graph Builder Box( 1 )];
		var = (clb << get selected)[1];
		groupByvar = (clb2 << get selected)[1];

		allVariables = (gbb << get variables);
		For Each( {var, idx}, Reverse( allVariables ),
			gbb << remove variable( {var[1] , Role(  Arg( var[2] ) )} )
		);

		gbb << add variable( {Column( var ), Role( "X" )} );
		
		Eval(
			Eval Expr(
				gbb << add variable(
					{Transform Column(
						"Cumulative Probability[1=100%]",
						Formula(
							Col Rank( Expr( Name Expr( As Column( var ) ) ), Expr( Name Expr( As Column( groupByvar ) ) ),Excluded() ) / (
							Col Number( Expr( Name Expr( As Column( var ) ) ), Expr( Name Expr( As Column( groupByvar ) ) ),Excluded() ) + 1)
						)
					), Role( "Y" )}
				)
			)
		);
		
		gbb << add variable( {Column( groupByvar ) , Role( "Overlay" )} ) ;
		
// SendToReport( Dispatch( {}, "Cumulative Probability[1=100%]", ScaleBox, {Scale( "Normal Probability" ), Format( "Best", 12 )} ) )
		yAxis = ((gb << xpath( "//ScaleBox" ))[2]);
		yAxis << {Scale( "Normal Probability" ), Format( "Best", 12 ), Title};
		
		gb << getXML();
		

		
		
	)
);


gbWindow = New Window( "Grouped Cumulative Probability",
	hlb = H List Box(
		V List Box(
			Panel Box( "Value", clb = Col List Box( all, <<Set Data Type( "numeric" ), max selected( 1 ), updatePlot2() ) ),
			Panel Box( "group by", clb2 = Col List Box( all, max selected( 1 ), updatePlot2() ) )
		),
		gb = dt << Graph Builder(
			Size( 724, 560 ),
			Show Control Panel( 0 ),
			Elements( Points( X, Y, Legend( 7 ) ), Smoother( X, Y, Legend( 8 ), Method( "Savitzky-Golay" ), Lambda( 2 ) ) ),
			SendToReport( Dispatch( {}, "Cumulative Probability[1=100%]", ScaleBox, {Scale( "Normal Probability" ), Format( "Best", 12 )} ) )
		)
	)
);

updates:
- remove & add variable (Y) deletes the normal probability setting on this axis
-> send the normal probability command again

- new problem: when running the "transform column" a second time and more often, jmp adds a counter to the name on the y axis: Cumulative Probability[1=100%] XX -> Y axis no longer accessible by its original name
-> get the y axis title via xPath

- Excluded() added in the Col... functions to force jmp to ignore excluded() rows in the calculation.

Re: how to make cumulative probability plots in JMP?

hogi — Mon, 09 Sep 2024 13:19:08 GMT

edit: unfortunately, this code is wrong - see below
... but can be fixed - see further below

I just detected the Cumulative Percent entry in the Summary settings:

This way it gets very easy to generate a grouped CDF Plot - even with the possibility to use a column switcher:

Names Default To Here( 1 );

dt = Current Data Table();

myCols = {};

ex = New Window( "Modal Dialog example",
	"Modal",
	V List Box(
		Lineup Box( N Col( 2 ),
			Panel Box( "", fcs = Filter Col Selector() ),
			Panel Box( "",
				Lineup Box( N Col( 2 ),
					Button Box( "variables", variableColsLB << append( fcs << get selected ) ),
					variableColsLB = Col List Box(Continuous, width( 200 ), min items( 1 ), nlines( 10 ) ),
					Button Box( "group by", groupColLB << append( fcs << get selected ) ),
					groupColLB = Col List Box( Nominal, width( 200 ), max items( 1 ), min items( 1 ), nlines( 1 ) )
				)
			)
		),
		H List Box(
			Button Box( "OK",
				For Each( {col, idx}, variableColsLB << get items(), Insert Into( myCols, Name Expr( As Column( dt, col ) ) ) );
				groupColName = (groupColLB << get items)[1];
				groupCol = Name Expr( As Column( dt, groupColName ) );
			),
			Button Box( "cancel" )
		)
	)
);

If(
	Not( ex["button"] == 1 ), Stop(),
	N Items( myCols ) == 0,
		Stop()
	
);

col1 = myCols[1];

Eval(
	Substitute(
			Expr(
				dt << Graph Builder(
					Show Control Panel( 0 ),
					Show Title( 0 ),
					Size( 500, 300 ),
					Variables( X( __col1__ ), 
					Y( __col1__ ), // here is the error: use a column with "1"s instead to make it right
					Overlay( __groupCol__ ) ),
					Elements( Points( X, Y, Summary Statistic( "Cumulative Percent" ) ) ),
					Column Switcher( __col1__, __myCols__ ),
					SendToReport(
						Dispatch( {}, "Graph Builder", OutlineBox, {Set Title( "Cumulative Distribution Plot" ), Image Export Display( Normal )} )
					)
				)
			),
		Expr( __col1__ ), Name Expr( col1 ),
		Expr( __myCols__ ), Name Expr( myCols ),
		Expr( __groupCol__ ), Name Expr( groupCol ), 

	)
);

Re: how to make cumulative probability plots in JMP?

Mauro_Gerber — Fri, 03 Mar 2023 07:47:49 GMT

//librecall:storeRoles( "CDF", verbose );

I had to mute the librecall function since I get an error in JMP17. But it seems it works without it just fine.

Can we mark this as solved @r30363 ?

Re: how to make cumulative probability plots in JMP?

hogi — Fri, 03 Mar 2023 07:56:03 GMT

Thanks, I removed it.

Re: how to make cumulative probability plots in JMP?

Thomas1 — Mon, 06 Mar 2023 07:40:23 GMT

Thanks for this great JSL code.

Re: how to make cumulative probability plots in JMP?

hogi — Tue, 03 Sep 2024 20:06:28 GMT

Ouch - sorry, unfortunately, the code doesn't do what it should do.

Cumulative Percent sounded like Cumulative Probability [%] , but unfortunately, it doesn't sum ONES and divide by N, it sums the individual values and divides by the sum of all values:

If the values are "similar", it's a quick hack to get something similar to CDF, but e.g. if the values start from 0 - or are even negative, the plot differs significantly from a CDF.

So close - but too far to fix it, right?

dt = Open( "$SAMPLE_DATA/Airline Delays.jmp" );
dt << Graph Builder(
	Variables( X( :Arrival Delay ), Y( :Arrival Delay ), Overlay( :Airline ) ),
	Elements(
		Points( X, Y, Legend( 6 ), Summary Statistic( "Cumulative Percent" ) )
	)
);

Re: how to make cumulative probability plots in JMP?

hogi — Sun, 30 Mar 2025 10:49:21 GMT

I posted a wish to add Cumulative Probability as an additional option for summary Statistics in Graph Builder:

So, perhaps in Jmp18 it will be THAT EASY to generate a grouped Cumulative Probability Plot in Graph Builder.

The huge advantage compared to https://community.jmp.com/t5/Discussions/how-to-make-cumulative-probability-plots-in-JMP/m-p/607570/highlight/true#M80917 :It will be compatible with the Column Switcher Feature of Graph Builder. No need to generate a GUI around the plot.

Re: how to make cumulative probability plots in JMP?

Mauro_Gerber — Wed, 22 Mar 2023 06:35:58 GMT

@hogi :

Re: how to make cumulative probability plots in JMP?

hogi — Tue, 27 Jun 2023 14:53:25 GMT

@Mauro Thanks a lot for the Kudo - an also for the other 3.
With 4 Kudos this feature should be kind of save to appear in a future Jmp version :)