topic Re: Side by side distribution plots in Discussions

Side by side distribution plots for Tall table

Jackie_ — Thu, 17 Aug 2023 16:58:04 GMT

Hi,

Is it possible to plot side by distribution plots in one graph with tall table? something like Graph Builder?

Something like this?

BR,

Jackie

Re: Side by side distribution plots

Jed_Campbell — Thu, 17 Aug 2023 14:27:51 GMT

Yes, Graph Builder can do that. I've attached the example below.

Re: Side by side distribution plots

Jackie_ — Thu, 17 Aug 2023 14:31:28 GMT

@Jed_Campbell yes I am aware, but how to plot distribution histogram side by side in the same graph?

Re: Side by side distribution plots

Jed_Campbell — Thu, 17 Aug 2023 14:45:44 GMT

Sorry, @Jackie_, I must be misunderstanding what you're looking for. Or, perhaps I chose a bad data set with not enough data to make the shape of a histogram. Here's another example of side by side histograms in the Graph Builder. If this isn't what you're looking for, can you please clarify?

Re: Side by side distribution plots

txnelson — Thu, 17 Aug 2023 15:07:07 GMT

Here is another way to do it

Names Default To Here( 1 );
// Open Data Table: big class.jmp
// → Data Table( "big class" )
Open( "/C:/Program Files/SAS/JMPPRO/16/Samples/Data/big class.jmp" );
nw = New Window( "",
	H List Box(
		Distribution(
			uniform scaling( 1 ),
			Continuous Distribution(
				Column( :height ),
				Quantiles( 0 ),
				Summary Statistics( 0 ),
				Outlier Box Plot( 0 )
			),
			by( :age )
		)
	)
);

Re: Side by side distribution plots

Jordan_Hiller — Thu, 17 Aug 2023 15:56:10 GMT

You can also do this via the Oneway flavor of Fit Y By X:

// Open Data Table: Semiconductor Capability.jmp
// → Data Table( "Semiconductor Capability" )
Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );

// Report snapshot: Semiconductor Capability - Fit Y by X of NPN1 by lot_id
Data Table( "Semiconductor Capability" ) << Oneway(
	Y( :NPN1 ),
	X( :lot_id ),
	Histograms( 1 )
);

Re: Side by side distribution plots

Jackie_ — Thu, 17 Aug 2023 15:57:56 GMT

@Jed_Campbell

I think the data table I have is in tall format. So the tests are grouped in columns. Is there a way to plot side by side in graph builder with tall table? I have attached below

Re: Side by side distribution plots

txnelson — Thu, 17 Aug 2023 16:15:38 GMT

If you want a histogram for specific columns to be placed side by side, just drag all of them to the X axis and change the display to be a Histogram

Re: Side by side distribution plots

Jed_Campbell — Thu, 17 Aug 2023 16:20:08 GMT

@Jackie_

You can use the Tables...Stack command to change the orientation/format of your data. The attached workflow (assuming you have JMP 17 or greater) walks through how. I also added a local data filter, since the stacked data made the graph have very wide limits otherwise.

Re: Side by side distribution plots

Jackie_ — Thu, 17 Aug 2023 17:03:49 GMT

Thanks @Jed_Campbell , I see you transposed the table. I think this approach works but wondering what if there's tall data table with >1M Rows?. I think transposing into Data columns wouldn't be best.

For ex: I stacked 252k rows and the final data table resulted 56M rows

Re: Side by side distribution plots

Jackie_ — Thu, 17 Aug 2023 16:57:10 GMT

The problem is you cannot plots all the processes in the same oneway plot

Re: Side by side distribution plots

txnelson — Thu, 17 Aug 2023 17:11:06 GMT

It is a very simple to stack the data into a new table, and then to run the Oneway's from it.

Re: Side by side distribution plots

Jackie_ — Thu, 17 Aug 2023 17:28:44 GMT

Hi Jim @txnelson , Stack() will essentially transpose the table. I think this approach works but wondering what if there's a tall data table with >1M Rows?. I think transposing into Data columns wouldn't be best.

For eg: I have a DT with 229 Columns and 252k Rows (Tall table). If I stacked 252k rows then the final data table will result 56M rows

Stack => 56M rows (not robust)

Re: Side by side distribution plots

txnelson — Thu, 17 Aug 2023 18:50:09 GMT

A table with 229 columns and 250k rows takes about the same amount of memory as 1 column and 56M rows. The issue is can you take advantage of the built in features of JMP. Not all Platforms support data laid out in multiple columns as well as they do with tall data tables. Dealing with the amount of data you are projecting will have other issues. Power of statistical tests, hardware's precision limitations are just a couple of them.

Re: Side by side distribution plots

ron_horne — Thu, 17 Aug 2023 23:22:29 GMT

Hi @Jackie_ ,
@Jordan_Hiller offers a practical solution, i would only add the Compare Densities option as follows:

// Open Data Table: Semiconductor Capability.jmp
// → Data Table( "Semiconductor Capability" )
Open( "$SAMPLE_DATA/Semiconductor Capability.jmp" );

// Report snapshot: Semiconductor Capability - Fit Y by X of NPN1 by lot_id
Data Table( "Semiconductor Capability" ) << Oneway(
	Y( :NPN1 ),
	X( :lot_id ),
	Compare Densities( 1 ),
	Histograms( 1 )
);

it will give you a graph like this:

let us know if it worked ?

Re: Side by side distribution plots

Jackie_ — Fri, 18 Aug 2023 13:27:45 GMT

Stack() works

Re: Side by side distribution plots

Jackie_ — Wed, 23 Aug 2023 12:22:43 GMT

Hi @ron_horne @txnelson @Jordan_Hiller,

Is there a way to get the Spec limits (USL and LSL) from the Column properties of the datatable in the stack table and add in the graph builder?
For instance, if I make a plot with a X group, and I want to put different reference lines for each group/panel only. Is that possible?

Thanks,

Jackie

Re: Side by side distribution plots

Jordan_Hiller — Wed, 23 Aug 2023 18:43:58 GMT

Here's an approach:

1) Get the limits from the original data table using the "Manage Limits" utility, save as tall limits table.

2) Use a virtual join to link the stacked data with the limits table

3) Make your graph, you'll need to use the "variables" panel in the graph element options.

Names Default To Here( 1 );

//Open Data Table: Stacked table.jmp
stk = Open( "$DOWNLOADS/Stacked table.jmp" );

//Open Data Table: datatable.jmp
dt = Open( "$DOWNLOADS/datatable.jmp" );

//Report snapshot: datatable - Manage Limits
obj = dt <<
Manage Limits( Process Variables( Column Group( "Tests" ) ) );
lim = obj << Save to Tall Limits Table;
r= obj << Report;
r << Close Window;

//Change column link ID: Variable
lim:Variable << Set Property( "Link ID", 1 );

//Change column link reference: Label
stk:Label <<
Set Property(
	"Link Reference",
	{Reference Table( lim ),
	Options( "Use Linked Column Name" )}
);

//Report snapshot: Stacked table - Graph Builder
stk << Graph Builder(
	Size( 518, 543 ),
	Show Control Panel( 0 ),
	Variables(
		X( :wafer ID ),
		Y( :Data ),
		Y(
			Referenced Column(
				"LSL",
				Reference( Column( :Label ), Reference( Column( :LSL ) ) )
			),
			Position( 1 )
		),
		Y(
			Referenced Column(
				"USL",
				Reference( Column( :Label ), Reference( Column( :USL ) ) )
			),
			Position( 1 )
		),
		Group X( :Label )
	),
	Elements(
		Points( X, Y( 1 ), Legend( 8 ) ),
		Line( X, Y( 2 ), Y( 3 ), Legend( 9 ) )
	),
	Local Data Filter(
		Add Filter(
			columns( :Label ),
			Where( :Label == {"Currents A1", "Currents A3", "Currents A9"} ),
			Display( :Label, N Items( 15 ), Find( Set Text( "" ) ) )
		)
	)
);

Re: Side by side distribution plots

Jackie_ — Wed, 23 Aug 2023 23:56:44 GMT

Thanks Jordan