For loop

ParametricStudy — Wed, 26 Jul 2023 18:51:01 GMT

I would like to generate all these plots in one tab, rather than generating 50 different pages, can anyone help ? thank you

dt = Current Data Table();
For( i = 1, i <= 50, i++,
	dt << Bivariate(
		Y( Column( dt, "u" || Char( i ) ) ),
		X( Column( dt, "oven.T" ) ),
		Fit Line( {Line Color( {212, 73, 88} )} )
	)
);

Re: For loop

txnelson — Wed, 26 Jul 2023 18:54:54 GMT

Here is one way to do what you want

Names Default To Here( 1 );
dt = 
// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
colListY = {};
For( i = 1, i <= 10, i++,
	Insert Into( colListY, "NPN" || Char( i ) )
);

dt << Bivariate(
	Y( Eval( colListY ) ),
	X( Column( dt, "PNP1" ) ),
	Fit Line( {Line Color( {212, 73, 88} )} )
);

Here is another way

Names Default To Here( 1 );
dt = 
// Open Data Table: semiconductor capability.jmp
// → Data Table( "semiconductor capability" )
Open( "$SAMPLE_DATA/semiconductor capability.jmp" );
colListY = {};
For( i = 1, i <= 10, i++,
	Insert Into( colListY, "NPN" || Char( i ) )
);
New Window( "My Output",
	H List Box(
		For( i = 1, i <= 10, i++,
			dt << Bivariate(
				Y( Column( dt, colListY[i] ) ),
				X( Column( dt, "PNP1" ) ),
				Fit Line( {Line Color( {212, 73, 88} )} )
			)
		)
	)
);

Re: For loop

ParametricStudy — Wed, 26 Jul 2023 22:11:02 GMT

Thank you!

topic For loop in Discussions

For loop

Re: For loop

Re: For loop