topic Re: How to close associated data table with a warning, when chart window is closed ? in Discussions

How to close associated data table with a warning, when chart window is closed ?

Neo — Tue, 13 Jun 2023 12:16:42 GMT

I want to show a warning dialog to the user when a chart window is closed and close the associated data table (without saving) if the user selects OK and keep both the data table and the chart, if the user selects "Cancel".

The script below is for the dialog box I want, but where do I need to put the statement for closing [if OK] or keeping [if Cancel] the data table?

gb << On Close(
	New Window( "Are you sure?",
		<<modal,
		V List Box(
			Text Box( "This will close the associated data table" ), 
			H List Box( Button Box( "OK" ), Button Box( "Cancel" ) )
		)
	)["button"] == 1
);

Re: How to close associated data table with a warning, when chart window is closed ?

hogi — Tue, 13 Jun 2023 16:15:21 GMT

<< on close()

is the right place.
Return 0 if the window should not be closed.

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
gb = dt << Graph Builder(
	<<on close(
		ex = New Window( "message",
			<<Type( "Modal Dialog" ),
			V List Box( 
				Text Box( "close?" ),
				H List Box( Button Box( "OK" ), Button Box( "Cancel" ) ) )
		);
		If( ex["button"] == 1,
			Close( (gb << Get Data Table), noSave )
		);
		ex["button"] == 1 // don't close the window if the user doesn't press OK
		;
	),
	Variables( X( :height ), Y( :weight ), Overlay( :sex ) ),
	Elements( Points( X, Y, Legend( 1 ) ), Smoother( X, Y, Legend( 2 ) ) )
);

Re: How to close associated data table with a warning, when chart window is closed ?

Neo — Tue, 13 Jun 2023 16:07:11 GMT

@hogi . I get the following on JMP 16.2.0.

Cannot subscript Display Box in access or evaluation of 'ex[ /*###*/"button"]' , ex[/*###*/"button"]Cannot subscript Display Box in access or evaluation of 'ex[ /*###*/"button"]' , ex[/*###*/"button"]

Re: How to close associated data table with a warning, when chart window is closed ?

hogi — Tue, 13 Jun 2023 16:21:15 GMT

Any reason why you don't use the free upgrade to jmp17?

The new Workflow Builder is really great :)

Here a version with

<<Modal

which should work on Jmp 16.2

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
gb = dt << Graph Builder(
	<<on close(
		ex = New Window( "message",
			<<Modal,
			V List Box( 
				Text Box( "close?" ),
				H List Box( Button Box( "OK" ), Button Box( "Cancel" ) ) )
		);
		If( ex["button"] == 1,
			Close( (gb << Get Data Table), noSave )
		);
		ex["button"] == 1 // don't close the window if the user doesn't press OK
		;
	),
	Variables( X( :height ), Y( :weight ), Overlay( :sex ) ),
	Elements( Points( X, Y, Legend( 1 ) ), Smoother( X, Y, Legend( 2 ) ) )
);

Re: How to close associated data table with a warning, when chart window is closed ?

Neo — Wed, 14 Jun 2023 10:22:22 GMT

@hogi Thanks, it works with << modal.

Any reason why you don't use the free upgrade to jmp17?

We normally test a newer JMP version (for a set duration) on existing JMP scripts before deploying it more widely.

There have been had several backward compatibility issues in the past some of which have not yet been resolved yet.

(I am still learning JMP but there are others who do the testing)

So, the upshot is we will move to v17 but it wont happen anytime soon so I only have v16.2 at my disposal at the moment :).