topic Re: How to start Multiple File Import () vis JSL with Keep Dialog Open unchecked? in Discussions

How to start Multiple File Import () vis JSL with Keep Dialog Open unchecked?

Neo — Fri, 09 Jun 2023 16:10:36 GMT

As the tile says - I have tried the following but does not work

Names Default To Here( 1 );
// use the save-script-to-script-window button 
// in the MFI dialog to see more messages
// for filtering files and controlling the import
Multiple File Import( Keep Dialog Open (0),
	<<Set Folder( "$DESKTOP" ),
	<<Set Name Filter( "*.csv;" ),
	<<Set Name Enable( 1 )
) << Create Window;

Where am I going wrong?

Re: How to start Multiple File Import () vis JSL with Keep Dialog Open unchecked?

jthi — Wed, 24 May 2023 12:29:11 GMT

You could navigate to the check box and control it that way

Names Default To Here(1);

mfi = Multiple File Import(
	<<Set Folder("$DESKTOP"),
	<<Set Name Filter("*.csv;"),
	<<Set Name Enable(1)
) << Create Window;

// Check box with text box saying 'Keep dialog open' is last checkbox
checkboxes = (mfi << XPath("//CheckBoxBox")); 
checkboxes[N Items(checkboxes)] << Set(0);

Re: How to start Multiple File Import () vis JSL with Keep Dialog Open unchecked?

Neo — Wed, 24 May 2023 13:35:44 GMT

@jthi Thanks but does not work in JMP 16.2.0 (on Windows 10)

Re: How to start Multiple File Import () vis JSL with Keep Dialog Open unchecked?

jthi — Wed, 24 May 2023 12:53:08 GMT

Slight modification is needed (and is better for JMP17 also) as JMP17 has different default value change << Set to << Set All

Names Default To Here(1);

mfi = Multiple File Import(
	<<Set Folder("$DESKTOP"),
	<<Set Name Filter("*.csv;"),
	<<Set Name Enable(1)
) << Create Window;

// Check box with text box saying 'Keep dialog open' is last checkbox
checkboxes = (mfi << XPath("//CheckBoxBox"));
checkboxes[N Items(checkboxes)] << Set All(0);

Re: How to start Multiple File Import () vis JSL with Keep Dialog Open unchecked?

txnelson — Wed, 24 May 2023 13:01:47 GMT

I ran Jarmo's code on JMP 16.2 on Windows 11 and it ran correctly. I was able to set the Keep Dialog Open checkbox to off or on using

checkboxes = (mfi << XPath("//CheckBoxBox")); 
checkboxes[N Items(checkboxes)] << Set(0);

checkboxes = (mfi << XPath("//CheckBoxBox")); 
checkboxes[N Items(checkboxes)] << Set(1);

Re: How to start Multiple File Import () vis JSL with Keep Dialog Open unchecked?

Neo — Wed, 24 May 2023 13:39:35 GMT

@jthi Your code works for me but I have a connected problem. It appears that the code proceeds without the user pressing the import button. In my case (JMP 16.2 on Win10), the window tilte is shown and the journal window pops up. How to hold progress until the user has pressed the import button.

Names Default To Here(1);

mfi = Multiple File Import(
	<<Set Folder("$DESKTOP"),
	<<Set Name Filter("*.csv;"),
	<<Set Name Enable(1)
) << Create Window;

// Check box with text box saying 'Keep dialog open' is last checkbox
checkboxes = (mfi << XPath("//CheckBoxBox"));
checkboxes[N Items(checkboxes)] << Set All(0);

mfi<< Get Window Title(); show (mfi);
jrnW  = New Window( "Report", << journal);

Re: How to start Multiple File Import () vis JSL with Keep Dialog Open unchecked?

jthi — Wed, 24 May 2023 13:49:57 GMT

You might be able to get Multiple File Import inside modal window somehow or you could try using << On Close

Names Default To Here(1);

mfi = Multiple File Import(
	<<Set Folder("$DESKTOP"),
	<<Set Name Filter("*.csv;"),
	<<Set Name Enable(1)
);
w = mfi << Create Window;

w << on close(
	jrnW  = New Window( "Report", << journal);
);

// Check box with text box saying 'Keep dialog open' is last checkbox
checkboxes = (w << XPath("//CheckBoxBox"));
checkboxes[N Items(checkboxes)] << Set All(0);

Re: How to start Multiple File Import () vis JSL with Keep Dialog Open unchecked?

Neo — Wed, 24 May 2023 14:45:51 GMT

@jthi . Thanks. On Close only appear to work in case of the journal window. Does not work for the following for example.

Names Default To Here(1);
mfi = Multiple File Import(
	<<Set Folder("$DESKTOP"),
	<<Set Name Filter("*.csv;"),
	<<Set Name Enable(1)
);
w = mfi << Create Window;
w << on close(
	mfi<< Get Window Title(); show (mfi);
);
// Check box with text box saying 'Keep dialog open' is last checkbox
checkboxes = (w << XPath("//CheckBoxBox"));
checkboxes[N Items(checkboxes)] << Set All(0);

I need a run a large script after the user selects the files using the Multiple File Import function. The script operates on the selected files. Could I please have the example with Multiple File Import function inside a Modal Window? In this case, how to reference he files opened by Multiple File Import (in my case two files) for further use?

Re: How to start Multiple File Import () vis JSL with Keep Dialog Open unchecked?

jthi — Wed, 24 May 2023 15:01:53 GMT

Most likely it won't work in your case as the mfi has been closed. I would go with On Close route because modal window will most likely mess up the buttons of Multiple File Import

Names Default To Here(1);

aa_olddt = Associative Array(Get Data Table List() << get name);

mfi = Multiple File Import(
	<<Set Folder("$SAMPLE_DATA"),
	<<Set Name Filter("*.csv;"),
	<<Set Name Enable(1)
);

w = mfi << Create Window();

checkboxes = (w << XPath("//CheckBoxBox"));
checkboxes[N Items(checkboxes)] << Set All(0);

w << On Close(
	aa_newdt = Associative Array(Get Data Table List() << get name);
	aa_newdt << Remove(aa_olddt);
	dt_list = aa_newdt << get keys;
	Caption(dt_list);
);

Re: How to start Multiple File Import () vis JSL with Keep Dialog Open unchecked?

Neo — Wed, 24 May 2023 16:06:24 GMT

@jthi Thanks, but how does one call further scripts (e.g to plot etc) to operate on the data tables imported. The first one below works, but this is not what I need.

Names Default To Here(1);
//clear log ();

aa_olddt = Associative Array(Get Data Table List() << get name);

mfi = Multiple File Import(
	<<Set Folder("$SAMPLE_DATA"),
	<<Set Name Filter("Big*"),
	<<Set Name Enable(1)
);

w = mfi << Create Window();

checkboxes = (w << XPath("//CheckBoxBox"));
checkboxes[N Items(checkboxes)] << Set All(0);

w << On Close(
	aa_newdt = Associative Array(Get Data Table List() << get name);
	aa_newdt << Remove(aa_olddt);
	dt_list = aa_newdt << get keys;
	show (dt_list);
	dt = dt_list[1]; 
	dt = data table (dt);
	dt<<Distribution( Column( :Age, :Weight ) );
	//include ("plotDist.jsl");
	);

I need to be able to call scripts to operate on the imported data files. One below does not work (gives attached error)

Names Default To Here(1);
//clear log ();

aa_olddt = Associative Array(Get Data Table List() << get name);

mfi = Multiple File Import(
	<<Set Folder("$SAMPLE_DATA"),
	<<Set Name Filter("Big*"),
	<<Set Name Enable(1)
);

w = mfi << Create Window();

checkboxes = (w << XPath("//CheckBoxBox"));
checkboxes[N Items(checkboxes)] << Set All(0);

w << On Close(
	aa_newdt = Associative Array(Get Data Table List() << get name);
	aa_newdt << Remove(aa_olddt);
	dt_list = aa_newdt << get keys;
	show (dt_list);
	dt = dt_list[1]; 
	dt = data table (dt);
	//dt<<Distribution( Column( :Age, :Weight ) );
	include ("plotDist.jsl");
	);
	
	//include ("plotDist.jsl");

where plotDist.jsl (saved in the same directory) is

Names Default To Here(1);
dt<<Distribution( Column( :Age, :Weight ) );

Putting

include ("plotDist.jsl");

outside On Close also does not work. Where am I going wrong?

Re: How to start Multiple File Import () vis JSL with Keep Dialog Open unchecked?

jthi — Wed, 24 May 2023 15:50:40 GMT

Names (strings) of datatables are stored to dt_list so you have to convert them to data table references when using.

Names Default To Here(1);
//clear log ();

aa_olddt = Associative Array(Get Data Table List() << get name);

mfi = Multiple File Import(
	<<Set Folder("$SAMPLE_DATA"),
	<<Set Name Filter("Big*"),
	<<Set Name Enable(1)
);

w = mfi << Create Window();

checkboxes = (w << XPath("//CheckBoxBox"));
checkboxes[N Items(checkboxes)] << Set All(0);

w << On Close(
	aa_newdt = Associative Array(Get Data Table List() << get name);
	aa_newdt << Remove(aa_olddt);
	dt_list = aa_newdt << get keys;
	Datatable(dt_list[1]) << Distribution(Column(:Age, :Weight));
);

Depending on your application it might be a good idea to loop over the dt_list (maybe rename it to dtname_list) and create a list of datatable references

Re: How to start Multiple File Import () vis JSL with Keep Dialog Open unchecked?

Neo — Wed, 24 May 2023 16:09:15 GMT

@jthi Thanks, but as I have indicated above (posted incorrect code first which I have edited now), how does one include scripts inside On Close() which call on one of more of the imported data tables?

Re: How to start Multiple File Import () vis JSL with Keep Dialog Open unchecked?

jthi — Wed, 24 May 2023 16:10:26 GMT

You would loop over your list of data tables and perform the actions. Depending on what you are doing you could build expressions or functions which could then be called inside the loop.

Re: How to start Multiple File Import () vis JSL with Keep Dialog Open unchecked?

Neo — Wed, 24 May 2023 16:37:09 GMT

@jthi Ok I will try to loop, but where does the loop go - inside On Close () or outside On Close (). Also what does the attached error message mean?

Re: How to start Multiple File Import () vis JSL with Keep Dialog Open unchecked?

jthi — Wed, 24 May 2023 16:52:15 GMT

Whatever you want to happen after Multiple File Import has been closed, should happen inside On Close. You can make it a bit cleaner by creating functions and expressions outside the On close but then call them inside.

It might be a good idea to accept solution to this post as it has already been solved and post a new one with additional information on what you wish to do after.

Re: How to start Multiple File Import () vis JSL with Keep Dialog Open unchecked?

Craige_Hales — Thu, 25 May 2023 00:37:26 GMT

Example for the Import Callback script

x=Multiple File Import(
	<<Set Folder( "C:\Users\v1\Documents\" ),
	<<Set Name Filter( "*.csv; *.txt; " ),
	<<Set Name Enable( 1 ),
	<<Set Import Callback( function({mfi,list},show(list, mfi<<GetFolder);x<<closewindow) )
) << createwindow;

This script runs when the import button finishes; you might need the list of data tables.

You might send MFI a command to <<get a parameter the user specified.

x<<closewindow will force the window to close, ignoring the check box.

Extra info:

<<createwindow starts the mfi platform interactively with the setup provided; the <<CreateWindow message puts the created window in the X variable. If you use the <<ImportData message instead, x will hold the data table list. If you don't use a message, x will hold the scriptable platform, which you can send messages like <<SetFolder and <<CreateWindow to.

The setup messages are inside the parens for the mfi launch and happen before the window opens; the launch returns an MFI object which the CreateWindow message is sent to; the result from CreateWindow is assigned to x.

Re: How to start Multiple File Import () vis JSL with Keep Dialog Open unchecked?

jthi — Thu, 25 May 2023 06:00:39 GMT

Nice info @Craige_Hales !

Scripting index (or rather JMP/JSL documentation) strikes again :(

Re: How to start Multiple File Import () vis JSL with Keep Dialog Open unchecked?

Craige_Hales — Thu, 25 May 2023 09:49:58 GMT

My fault, I'm afraid. I already sent a note to the technical team. It was added after the initial release, for exactly this purpose.