Remove Upper and Lower 95% from means and std plot

UserID16644 — Sun, 11 Jun 2023 00:01:11 GMT

Hi all,

I have this function for making a bivariate plot, with means and std. However, I need to remove the Lower 95% and Upper 95% from the table. I tried making it manually but I don't know how to incorporate it with the function. Please help

This is the function:

New Window( "Tmp Window",
													vc = Oneway(
														Y( :Param ),
														X( :Param1 ),
														Means and Std Dev( 1 ),
														Mean Diamonds( 1 ),
														X Axis Proportional( 0 ),
														Box Plots( 1 ),
														Grand Mean( 0 ),
														CDF Plot( 0 ),
														Connect Means( 0 ),
														Points Jittered( 0 )
													);
													rvc = vc << Report;
													ymax = rvc[Axis Box( 1 )] << Get Max;
													ymin = rvc[Axis Box( 1 )] << Get Min;
													rvc[FrameBox( 1 )] << {Marker Size( 2 )};
													Try( rvc[Axis Box( 1 )] << Max( paxis["Max"] ) << Min( paxis["Min"] ) << Inc( paxis["Inc"] ) << Minor Ticks( paxis["Ntick"] ) );
													rvc[Axis Box( 1 )] << Format( "Best", 12 ) << Tick Font( style( 1 ), size( 9 ) ) << Show Major Grid( 1 ) << Show Minor Grid( 1 ) <<
													Show Minor Ticks( 1 );
													rvc[Text Edit Box( 1 )] << Set Font Size( 10 ) << Set Font Style( "Bold" );
													vb = V List Box( rvc[Picture Box( 1 )], rvc[Outline Box( 2 )] << Get Picture );
												);

This is the code from the script window:

Oneway(
Y( :Param ),
X( :Param1 ),
Means and Std Dev( 1 ),
Mean Error Bars( 1 ),
Std Dev Lines( 1 ),
SendToReport(
Dispatch(
{"Means and Std Deviations"},
"Lower 95%",
NumberColBox,
{Visibility( "Collapse" )}
),
Dispatch(
{"Means and Std Deviations"},
"Upper 95%",
NumberColBox,
{Visibility( "Collapse" )}
)
)
);

Re: Remove Upper and Lower 95% from means and std plot

jthi — Mon, 15 May 2023 13:30:53 GMT

One option

tb = Report(vc)["Means and Std Deviations", Table Box(1)];
headers = tb << get names;
tb[Contains(headers, "Lower 95%")] << Visibility("Collapse");
tb[Contains(headers, "Upper 95%")] << Visibility("Collapse");

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

nw = New Window("Tmp Window",
	vlb = V List Box(
		vc = Oneway(
			Y(:height),
			X(:age),
			Means and Std Dev(1),
			Mean Diamonds(1),
			X Axis Proportional(0),
			Box Plots(1),
			Grand Mean(0),
			CDF Plot(0),
			Connect Means(0),
			Points Jittered(0)
		);
		rvc = vc << Report;
		ymax = rvc[Axis Box(1)] << Get Max;
		ymin = rvc[Axis Box(1)] << Get Min;
		rvc[FrameBox(1)] << {Marker Size(2)};
		Try(
			rvc[Axis Box(1)] << Max(paxis["Max"]) << Min(paxis["Min"]) << Inc(paxis["Inc"]) <<
			Minor Ticks(paxis["Ntick"])
		);
		rvc[Axis Box(1)] << Format("Best", 12) << Tick Font(style(1), size(9)) << Show Major Grid(1) <<
		Show Minor Grid(1) << Show Minor Ticks(1);
		rvc[Text Edit Box(1)] << Set Font Size(10) << Set Font Style("Bold");
	);
);

tb = Report(vc)["Means and Std Deviations", Table Box(1)];
headers = tb << get names;
tb[Contains(headers, "Lower 95%")] << Visibility("Collapse");
tb[Contains(headers, "Upper 95%")] << Visibility("Collapse");

vlb << Append(
	vb = V List Box(rvc[Picture Box(1)], rvc[Outline Box(2)] << Get Picture);
);

topic Remove Upper and Lower 95% from means and std plot in Discussions

Remove Upper and Lower 95% from means and std plot

Re: Remove Upper and Lower 95% from means and std plot