topic Re: A Better Way to Do a For Loop with Two Lists? in Discussions

A Better Way to Do a For Loop with Two Lists?

Pertussic — Fri, 09 Jun 2023 16:09:20 GMT

Noob here. I have a nested for loop that uses two lists that selects specific diagnostic codes from multiple diagnosis columns. It works, but I was wondering if there's a better way to code it.

ColumnList = {"DIAGNOSIS_1", "DIAGNOSIS_2", "DIAGNOSIS_3"};
ValueList = {"E871","O480","J449"};*/
For( i = 1, i <= N Items( ColumnList ), i++, 
	ColumnItem = ColumnList[i];
	Eval(
		Eval Expr(
			As Constant( col = As Name( Expr( ColumnItem ) ) );
			For( j = 1, j <= N Items( ValueList ), j++, 
				ValueItem = ValueList[j];
				all_ip << select where( As Column( col ) == ValueItem, Current Selection( "extend" ) );
			);
		)
	);
);

Re: A Better Way to Do a For Loop with Two Lists?

Craige_Hales — Fri, 05 May 2023 01:01:01 GMT

Maybe this is what you are trying to do.

dt = Open( "$sample_data/big class.jmp" );
ColumnList = {"height", "weight", "age"};
ValueList = {13, 128, 60};
For Each( {col}, ColumnList,
	For Each( {ValueItem}, ValueList,
		dt << select where( As Column( dt, col ) == ValueItem, Current Selection( "extend" ) )
	)
);

or even this

dt = Open( "$sample_data/big class.jmp" );
ColumnList = {:height, :weight, :age};
ValueList = {13, 128, 60};
For Each( {col}, ColumnList,
	For Each( {ValueItem}, ValueList, dt << select where( col == ValueItem, Current Selection( "extend" ) ) )
);

(It might make sense with your data, but with big class it doesn't make a lot of sense to select rows where height or weight or age are 13, or where height or weight or age are 128, or where height or weight or age are 60. Just using it to try to match what I think you mean.)

Re: A Better Way to Do a For Loop with Two Lists?

Craige_Hales — Fri, 05 May 2023 01:45:04 GMT

Or even this

dt = Open( "$sample_data/big class.jmp" );
ValueList = {13, 128, 60};
dt << select where( Contains( ValueList, :height ) | Contains( ValueList, :weight ) | Contains( ValueList, :age ) );

Just imagine that height, weight, and age were all the same units, similar to the diagnosis columns. I think this is what you want if the number of diagnosis columns will always be three.

Re: A Better Way to Do a For Loop with Two Lists?

Pertussic — Fri, 05 May 2023 21:13:45 GMT

Is For Each() only available in Pro? I just have Basic and it doesn't work. Or did I miss an update somewhere?

Re: A Better Way to Do a For Loop with Two Lists?

Craige_Hales — Fri, 05 May 2023 23:55:41 GMT

regular JMP, since 16.

Re: A Better Way to Do a For Loop with Two Lists?

Mark_Bailey — Mon, 08 May 2023 10:05:35 GMT

Per Scripting Index in JMP 17: added in JMP 16 (JMP or JMP Pro)

Re: A Better Way to Do a For Loop with Two Lists?

Pertussic — Mon, 08 May 2023 16:58:32 GMT

And that'd do it. I'm still at 15. I could have sworn I updated. COVID's kept me busy.

Re: A Better Way to Do a For Loop with Two Lists?

vince_faller — Tue, 09 May 2023 18:58:04 GMT

I'd guess you're right about that is what they want to do. Adding onto it, even if it were dynamic you could do something like.

Names default to here( 1 );
dt = open("$SAMPLE_DATA\Big Class.jmp");
col_dict = ["height"=>{13, 128, 60}, 
	"weight"=>{95, 123, 79, 105}, 
	"age"=>{17}
];
//create an orexpression 
or_expr = Expr(OR());
for(key = col_dict<<First, !isempty(key), key = col_dict<<next(key), 
	// for each column just add another contains(values, col) statement
	insert into(or_expr, EvalExpr(Contains(Expr(col_dict[key]), Column(Expr(key))[])));
);

final_expr = EvalExpr(dt << SelectWhere(Expr(nameexpr(or_expr))));
print(nameexpr(final_expr)); // just to show the final output it's actually running
Eval(final_expr);

Re: A Better Way to Do a For Loop with Two Lists?

Pertussic — Tue, 16 May 2023 20:47:20 GMT

Sorry for the delay; I had to update to 17. And your code works perfectly! Thank you.