topic Re: 如何编JSL语句让分布分析自动把变化 in Discussions

如何编JSL语句让分布分析自动把变化

lehaofeng — Thu, 08 Jun 2023 16:41:03 GMT

我写了一个程序，但并没有随着我选择单选框的价值，自动改变。

Names Default To Here( 1 );

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

cc={"身高", "体重"};

New Window( "Example",
aa=1;

rb = Radio Box( {"身高", "体重"},

     aa= rb<<get();

     bb<<inval;
     bb<<update window

),



bb=Distribution(

Stack( 1 ),

Continuous Distribution(

Column( cc[aa] ),

Horizontal Layout( 1 ),

Vertical( 0 )

),
Histograms Only,

))
  ;

Re: 如何编JSL语句让分布分析自动把变化

txnelson — Thu, 26 Jan 2023 03:56:21 GMT

This may be what you are looking for

Names Default To Here( 1 );

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

cc = {"height","weight"};

nw = new window("Chooser",
	rb= radio box(cc,
		theColumn = rb << get;
		Distribution( Continuous Distribution( Column( cc[theColumn] ) ) )
	)
);

Re: 如何编JSL语句让分布分析自动把变化

lehaofeng — Thu, 26 Jan 2023 04:35:05 GMT

我是想让窗口内容随着radio box的选择，自动更新。之前的窗口关闭，更新为新的。

Re: 如何编JSL语句让分布分析自动把变化

txnelson — Thu, 26 Jan 2023 07:15:40 GMT

See if this is what you want

Names Default To Here( 1 );

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

cc = {"height", "weight"};

nw = New Window( "Chooser",
	rb = Radio Box(
		cc,
		theColumn = rb << get;
		Try( dis << delete );
		vlb << append( dis = Distribution( Continuous Distribution( Column( cc[theColumn] ) ) ) );
	),
	vlb = V List Box(
		dis = Distribution( Continuous Distribution( Column( cc[1] ) ) )
		
	)
);

But what I really think you should use, is the builtin Column Switcher

Names Default To Here( 1 );

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

Distribution(
Continuous Distribution( Column( :height ), Always use column properties( 1 ) ),
Column Switcher( :height, {:height, :weight} )
);

Re: 如何编JSL语句让分布分析自动把变化

lehaofeng — Thu, 26 Jan 2023 09:03:53 GMT

非常感谢，太棒了！