topic Re: script avec graphs et splitter box in Discussions

script avec graphs et splitter box

Françoise — Thu, 08 Jun 2023 16:42:38 GMT

bonjour,

j'aimerais refaire ce script (source= index des scripts JMP) mais avec des graphiques dans chaque case. j'ai essayé mais les graphiques ne s'affichent pas. est-ce quelqu'un a un exemple?

Names Default To Here( 1 );
New Window( "Splitter Example",
	box =
	V Splitter Box(
		Size( 640, 480 ),
		H Splitter Box(
			Spacer Box(
				<<Set Fill( 1 );
				<<Color( RGB Color( 9, 112, 84 ) );
			),
			Spacer Box(
				<<Set Fill( 1 );
				<<Color( RGB Color( 255, 222, 0 ) );
			)
		),
		H Splitter Box(
			Spacer Box(
				<<Set Fill( 1 );
				<<
				Color( RGB Color( 101, 153, 255 ) );
			),
			Spacer Box(
				<<Set Fill( 1 );
				<<Color( RGB Color( 255, 153, 0 ) );
			)
		)
	)
);

cordialement

Re: script avec graphs et splitter box

jthi — Tue, 17 Jan 2023 19:00:28 GMT

Without seeing any examples what you have tried it is difficult to give advice. Below is example with Graph Builder and splitter boxes

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

New Window("Splitter Example",
	box = V Splitter Box(
		Size(640, 480),
		H Splitter Box(
			dt << Graph Builder(
				Show Control Panel(0),
				Variables(X(:weight), Y(:height)),
				Elements(Points(X, Y), Smoother(X, Y))
			),
			dt << Graph Builder(
				Show Control Panel(0),
				Variables(X(:height), Y(:weight)),
				Elements(Points(X, Y), Smoother(X, Y))
			)
		),
		H Splitter Box(
			dt << Graph Builder(
				Show Control Panel(0),
				Variables(X(:sex), Y(:weight)),
				Elements(Points(X, Y), Smoother(X, Y))
			),
			dt << Graph Builder(
				Show Control Panel(0),
				Variables(X(:age), Y(:weight)),
				Elements(Points(X, Y), Smoother(X, Y))
			)
		)
	)
);

Re: script avec graphs et splitter box

Françoise — Tue, 17 Jan 2023 21:11:24 GMT

bonjour,

merci pour votre solution que j'ai utilisé dans un Tab page Box.

mais je n'arrive pas à avoir les 4 graphiques dans mon écran. Comment faire pour avoir les bonnes dimensions automatiquement?

Re: script avec graphs et splitter box

txnelson — Tue, 17 Jan 2023 22:30:05 GMT

The

Size(640, 480),

is what is changing the overall size of the outside V Splitter Box. Are you specifying a size for the overall or for the individual graphs. That should allow you to adjust what is displayed on the screen.