topic 回复： When drawing bubbles, how can I set the background color to different colors according to the number of rows? in Discussions

When drawing bubbles, how can I set the background color to different colors according to the number of rows?

lala — Fri, 09 Jun 2023 16:04:28 GMT

Hello!

For example, set lines 1-20 and 21-40 to different background colors.

dt=Open("$SAMPLE_DATA/Big Class.jmp");

p1=dt<<Bubble Plot(
	X( Transform Column( "Row", Formula( Row() ) ) ),
	Y( :height ),
	Sizes( :weight ),
	Coloring( :sex ),
	Title Position( 0, 0 ),
	SendToReport(
		Dispatch(
			{},
			"1",
			ScaleBox,
			{Min( 0 ), Max( 45 ), Inc( 5 ), Minor Ticks( 0 )}
		),
		Dispatch(
			{},
			"2",
			ScaleBox,
			{Min( 50 ), Max( 72.5 ), Inc( 5 ), Minor Ticks( 1 )}
		),
		Dispatch(
			{},
			"Bubble Plot",
			FrameBox,
			{Frame Size( 565, 360 ), Background Color( 76 )}
		)
	)
);

回复： When drawing bubbles, how can I set the background color to different colors according to the number of rows?

lala — Sat, 10 Dec 2022 09:04:35 GMT

Not work.

Fill Color("blue"); Rect( 1, 80 , 20 ,50,  1);,

回复： When drawing bubbles, how can I set the background color to different colors according to the number of rows?

jthi — Sun, 11 Dec 2022 11:38:20 GMT

You could use reference lines with allow range enabled

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

bp = dt << Bubble Plot(
	X(Transform Column("Row", Formula(Row()))),
	Y(:height),
	Sizes(:weight),
	Coloring(:sex),
	Title Position(0, 0)
);

wait(1);

axisbox = Report(bp)[axis box(2)];
axisbox << Add Ref Line({0, 20}, "Solid", "Red", "", 1, 0.25);
axisbox << Add Ref Line({20, 40}, "Solid", "Medium Light Blue", "", 1, 0.25);

Or then graphic scripts but I think reference lines with range are easier in this case.

回复： When drawing bubbles, how can I set the background color to different colors according to the number of rows?

lala — Sun, 11 Dec 2022 14:11:43 GMT

Thank you for your help!

dt=Open("$SAMPLE_DATA/Big Class.jmp");
bp = dt <<Graph Builder(
	Size( 532, 453 ),
	Show Control Panel( 0 ),
	Variables(
		X( Transform Column( "Row", Formula( Row() ) ) ),
		Y( :height ),
		Color( :sex ),
		Size( :height )
	),
	Elements( Points( X, Y, Legend( 17 ) ) )
);

axisbox = Report(bp)[axis box(1)];
axisbox << Add Ref Line({0, 20}, "Solid", "Red", "", 1, 0.25);
axisbox << Add Ref Line({20, 40}, "Solid", "Medium Light Blue", "", 1, 0.25);