topic Re: Ho to send messages to a local data filter inside a graph builder window in Discussions

How to send messages to an already existing local data filter inside a graph builder window

hogi — Sat, 09 Sep 2023 10:38:53 GMT

Is it possible to send messages to a local data filter inside a graphbuilder object?

Unfortunately, it's not possible to define a varaible "ldf" inside the graphbuilder code - to send the messages to "ldf".

Do I have to "pipe" the message "through the gb object"?

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
dt << Graph Builder(
	Size( 534, 464 ),
	Show Control Panel( 0 ),
	Graph Spacing( 5 ),
	Variables( X( :weight ), Y( :height ) ),
	Elements( Points( X, Y, Legend( 5 ) ), Smoother( X, Y, Legend( 6 ) ) ),
	Local Data Filter( Add Filter( columns( :sex ), Where( :sex == "F" ) ) )
);

df = dt << Data Filter(
	Location( {696, 15} ),
	Mode( Include( 1 ) ),
	Add Filter( columns( :sex ), Where( :sex == "F" ) )
);
ldf = (report(gb) << Parent)["Local Data Filter"];

df << Clear ();
//same for ldf:
ldf[buttonBox(1)] << click();

df << Add Filter( columns( :name) );
// same for ldf?

Re: Ho to send messages to a local data filter inside a graph builder window

jthi — Tue, 11 Oct 2022 10:37:42 GMT

You could add local data filter after graph builder has been created, this will let you have a reference

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
gb = dt << Graph Builder(
	Size(534, 464),
	Show Control Panel(0),
	Graph Spacing(5),
	Variables(X(:weight), Y(:height)),
	Elements(Points(X, Y, Legend(5)), Smoother(X, Y, Legend(6)))
);

ldf = gb << Local Data Filter(Add Filter(columns(:sex), Where(:sex == "F")));
wait(1);
ldf << Clear();
ldf << Add Filter( columns( :name) );// same for ldf?

Re: Ho to send messages to a local data filter inside a graph builder window

txnelson — Tue, 11 Oct 2022 10:43:44 GMT

Here is an example taken from the Scripting Index

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Time Series/Air.jmp" );
gb = dt << Graph Builder(
	Size( 522, 492 ),
	Show Control Panel( 0 ),
	Variables(
		X( :month ),
		Y( :Ozone Concentration ),
		Group X( :Summer Months Intervention )
	),
	Elements( Points( X, Y, Legend( 10 ) ), Smoother( X, Y, Legend( 11 ) ) ), 

);
ldf = gb << Local Data Filter(
	Add Filter( columns( :date ), Where( :date >= 16Oct1965 & :date <= 31Aug1968 ) )
);
fc = ldf << Get Filter Column( :date );
fc << Zoom to Selection;
Wait( 1 );
fc << Reset Zoom;

Re: Ho to send messages to a local data filter inside a graph builder window

hogi — Tue, 11 Oct 2022 10:44:29 GMT

Oh, sure.
Like always:

enter the room through another door - and the wall is gone.

Thanks Jarmo.

Re: Ho to send messages to a local data filter inside a graph builder window

hogi — Sat, 12 Nov 2022 10:32:33 GMT

And if the Graph is already there and I want to get the settings of the (existing) local data filter?

Any chance?

Re: Ho to send messages to a local data filter inside a graph builder window

txnelson — Sat, 12 Nov 2022 11:09:17 GMT

ldf = current report()["Local Data Filter"]<<get scriptable object;

Re: Ho to send messages to a local data filter inside a graph builder window

hogi — Sat, 12 Nov 2022 16:31:14 GMT

Ah, via the report layer!
thanks.

<<get scriptable object;

is the best invention!