topic Re: How to send messages to global data filter? in Discussions

How to send messages to global data filter?

Djtjhin — Sat, 10 Jun 2023 23:55:26 GMT

Is there a way to send messages to global filter to show different filters through scripting ?

Sometimes I'd like to review/ recall several filter settings or "where clauses" that were previously saved.

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Cities.jmp" );
obj = dt << Data Filter(conditional);
obj << Add Filter( columns( :POP ) );
obj << Add Filter( columns( :Region, :State, :City ), Where( :Region == "S" ), Where( :State == {"SC", "NC"} ) );

wait(1);

//This works
obj << clear;
obj << ( filter column( :Region, :State, :City )<< Where( :Region == "S" ) );

//Unable to work once multiple clauses are perscribed
obj << clear;
obj << ( filter column( :Region, :State, :City )<< Where( :Region == "S" & State == "LA") );

Appreciate the help!

Re: How to send messages to global data filter?

txnelson — Mon, 17 Oct 2022 14:55:25 GMT

Could it be as simple as adding the missing ":" in front of

State == "LA"

Re: How to send messages to global data filter?

jthi — Mon, 17 Oct 2022 15:07:47 GMT

You might have to divide it into two separate Wheres (no idea why).

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Cities.jmp");
obj = dt << Data Filter(conditional);
obj << Add Filter(columns(:POP));
obj << Add Filter(columns(:Region, :State, :City), Where(:Region == "S"), Where(:State == {"SC", "NC"}));

Wait(1);

obj << clear;
obj << (filter column(:Region, :State, :City) << Where(:Region == "S"));

obj << clear;
obj << (filter column(:Region) << Where(:Region == "S"));
obj << (filter column(:State) << Where(:State == "LA"));

Re: How to send messages to global data filter?

danschikore — Mon, 17 Oct 2022 15:11:02 GMT

Data Filter where clauses cannot be combined (or changed in many other ways), because the expression is not executed, it is parsed to set the state of the each filter item. If you separate the state into two commands, it should work as expected:

obj << clear;
obj << ( filter column( :Region ) << Where( :Region == "S" ) );
obj << ( filter column( :State ) << Where( :State == "LA") );

Re: How to send messages to global data filter?

Djtjhin — Tue, 18 Oct 2022 12:53:20 GMT

Thanks @danschikore. I was hoping for a more robust functionality but seems like this is the limitation that I have to work around.