topic Re: How to remove graph builder label in Discussions

How to remove graph builder label

conroyco — Fri, 20 Jul 2018 09:54:09 GMT

Hi,

I want to append a report file with a graph. When I save it as a pdf it has the graph but the grey box saying graph builder. I want to change this to a different label - for example "graph of area 1". Is it possible to do this? I know you can do it from the report and save it but I can't seem to find jsl code that does this.

Re: How to remove graph builder label

Craige_Hales — Fri, 20 Jul 2018 10:20:56 GMT

dt = Open( "$sample_data/big class.jmp" );
gb = dt << Graph Builder(
  Size( 518, 448 ),
  Show Control Panel( 0 ),
  Variables( X( :weight ), Y( :height ) ),
  Elements( Points( X, Y, Legend( 6 ) ), Smoother( X, Y, Legend( 7 ) ) )
);

gb << showtitle( 1 );
gb << title( "area 1" );

Graph Builder sets the outline title

<<showTitle(0) turns off the Height vs Weight text.

Re: How to remove graph builder label

txnelson — Fri, 20 Jul 2018 10:30:35 GMT

Below are a couple ways to do this. The first one was created by just clicking on the Outline Box titled "Graph Builder" and typing in the new title you specified you wanted to have. After the change I clicked on the red triangle==>Save Script, and the first script below is what it gave me. The second example below uses the JMP feature where within JSL one can change pretty much anything within the output of a platform.

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/big class.jmp" );

gb = Graph Builder(
	Size( 528, 454 ),
	Show Control Panel( 0 ),
	Variables( X( :weight ), Y( :height ) ),
	Elements(
		Points( X, Y, Legend( 3 ) ),
		Smoother( X, Y, Legend( 4 ) )
	),
	SendToReport(
		Dispatch(
			{},
			"Graph Builder",
			OutlineBox,
			{Set Title( "Graph of Area 1" )}
		)
	)
);

// or

gb = Graph Builder(
	Size( 528, 454 ),
	Show Control Panel( 0 ),
	Variables( X( :weight ), Y( :height ) ),
	Elements(
		Points( X, Y, Legend( 3 ) ),
		Smoother( X, Y, Legend( 4 ) )
	)
);

report(gb)["Graph Builder"] << set title("This is the new title");

Re: How to remove graph builder label

Santo — Sat, 01 Oct 2022 19:54:59 GMT

If you are looking to remove the "Outline box" title, go to Edit > Properties and manually delete the Outline Box title. Tricky to find but useful if you are saving your graphs as PDF.