topic Re: influence of local data filter on graph height in Discussions

influence of local data filter on graph height

hogi — Sun, 11 Jun 2023 11:26:39 GMT

The size of a graph automatically adapts to the size of the window and the size of additinoal objects in the window.

With this auto-adjust, the local data filter has an influence on the minimum height of an image.

Please check the JSL code:

The graph opens with the desired size.

But when you open the local data filter with the grey triangle, the height of the graph increases.

Is there an option that prevents a graph from auto-adjusting to the height of the Local Data Filter?

How do I enable this option for all graphs that I create?

Open( "$SAMPLE_DATA/Big Class.jmp" );
Graph Builder(
	Size( 329, 254 ),
	Show Control Panel( 0 ),
	Variables( X( :weight ), Y( :height ) ),
	Elements( Points( X, Y, Legend( 4 ) ), Smoother( X, Y, Legend( 5 ) ) ),
	Local Data Filter(
		Close Outline( 1 ),
		Add Filter(
			columns( :name ),
			Display( :name, N Items( 15 ), Find( Set Text( "" ) ) )
		)
	)
)

Re: influence of local data filter on graph height

hogi — Wed, 03 Aug 2022 08:04:19 GMT

<< Fit to Window( "Off" );

is kind of a solution.

Then the local Data filter doesn't have an effect anymore.

But as it says, then I loose the "fit to window" functionality.

Re: influence of local data filter on graph height

danschikore — Wed, 03 Aug 2022 12:11:25 GMT

If you are scripting a solution, you could consider a scrolling layout for the data filter component.

dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
New Window( "Report",
	Data Filter Context Box(
		H List Box(
			V Scroll Box(
				Size( 100 ),
				<<Set Stretch( "Off", "Fill" ),
				<<Set Show Empty( 0 ),
				dt << Data Filter(
					Local,
					Close Outline( 1 ),
					Add Filter( columns( :name ), Display( :name, N Items( 15 ), Find( Set Text( "" ) ) ) )
				)
			),
			Graph Builder(
				Size( 329, 254 ),
				Show Control Panel( 0 ),
				Variables( X( :weight ), Y( :height ) ),
				Elements( Points( X, Y, Legend( 4 ) ), Smoother( X, Y, Legend( 5 ) ) )
			)
		)
	)
);

Re: influence of local data filter on graph height

hogi — Wed, 03 Aug 2022 14:55:14 GMT

wonderful :)